source: CONFIG/publications/ICOLMDZORINCA_CO2_Transport_GMD_2023/INCA/src/INCA_SRC/wetdepst.F90 @ 6610

!$Id: wetdep.F90 10 2007-08-09 12:43:01Z acosce $
!! =========================================================================
!! INCA - INteraction with Chemistry and Aerosols
!! 
!! Copyright Laboratoire des Sciences du Climat et de l'Environnement (LSCE)
!!           Unite mixte CEA-CNRS-UVSQ
!! 
!! Contributors to this INCA subroutine:
!! 
!! Michael Schulz, LSCE, Michael.Schulz@cea.fr
!! Yves Balkanski, LSCE, Yves.Balkanski@cea.fr
!! 
!! Anne Cozic, LSCE, anne.cozic@cea.fr
!! Yann Meurdesoif, LSCE, yann.meurdesoif@cea.fr
!!
!! This software is a computer program whose purpose is to simulate the 
!! atmospheric gas phase and aerosol composition. The model is designed to be
!! used within a transport model or a general circulation model. This version 
!! of INCA was designed to be coupled to the LMDz GCM. LMDz-INCA accounts
!! for emissions, transport (resolved and sub-grid scale), photochemical 
!! transformations, and scavenging (dry deposition and washout) of chemical 
!! species and aerosols interactively in the GCM. Several versions of the INCA
!! model are currently used depending on the envisaged applications with the 
!! chemistry-climate model. 
!! 
!! This software is governed by the CeCILL  license under French law and
!! abiding by the rules of distribution of free software.  You can  use, 
!! modify and/ or redistribute the software under the terms of the CeCILL
!! license as circulated by CEA, CNRS and INRIA at the following URL
!! "http://www.cecill.info". 
!! 
!! As a counterpart to the access to the source code and  rights to copy,
!! modify and redistribute granted by the license, users are provided only
!! with a limited warranty  and the software's author,  the holder of the
!! economic rights,  and the successive licensors  have only  limited
!! liability. 
!! 
!! In this respect, the user's attention is drawn to the risks associated
!! with loading,  using,  modifying and/or developing or reproducing the
!! software by the user in light of its specific status of free software,
!! that may mean  that it is complicated to manipulate,  and  that  also
!! therefore means  that it is reserved for developers  and  experienced
!! professionals having in-depth computer knowledge. Users are therefore
!! encouraged to load and test the software's suitability as regards their
!! requirements in conditions enabling the security of their systems and/or 
!! data to be ensured and,  more generally, to use and operate it in the 
!! same conditions as regards security. 
!! 
!! The fact that you are presently reading this means that you have had
!! knowledge of the CeCILL license and that you accept its terms.
!! =========================================================================

#include <inca_define.h>

#ifdef AER

SUBROUTINE wetdepst(&
   delt,       &
   tr_seri,    &
   area,       &
   pdel,       &
   flxrst,     &
   flxsst,     &
   zma)


  USE CHEM_CONS, ONLY : gravit, uma
  !MS  for budgetting purposes introduced
  USE SFLX, ONLY : wflux,wsflux,wcflux
  USE AEROSOL_METEO
  USE AEROSOL_MOD
  USE AEROSOL_DIAG
  USE AIRPLANE_SRC
  USE INCA_DIM

  IMPLICIT NONE

  REAL, INTENT(in) ::     delt                !timestep in seconds
  REAL, INTENT(inout) ::  tr_seri(PLON,PLEV,PCNST)
  REAL, INTENT(in) ::     area(PLON)          !area of gridbox in m2
  REAL, INTENT(in) ::     pdel(PLON,PLEV)        ! delta press across midpoints
  REAL, INTENT(in) ::     flxrst(PLON,PLEV+1) !liquid water flux (stratiform)  kgH2O/m2/s
  REAL, INTENT(in) ::     flxsst(PLON,PLEV+1) !solid  water flux (stratiform)  kgH2O/m2/s
  REAL, INTENT(in) ::     zma(PLON,PLEV)      !abs geopot height at midpoi

  REAL, PARAMETER  ::     drym = 28.966
  REAL, PARAMETER  ::     RG = 9.80665
  REAL, PARAMETER  ::     xlvalst = 0.5e-3
  REAL, PARAMETER  ::     bminusst = 1.e-4
  REAL, PARAMETER  ::     alpha = 5.e-4


  INTEGER :: npr,ns, i, k, ktrop
  INTEGER :: m1x, nx, mnx, mode,JT
  REAL, DIMENSION(PLON,PLEV) :: pdiffst, pdownst
  REAL, DIMENSION(PLON,PLEV) :: pkgm3st, beta2st, fractst, decayst
  REAL, DIMENSION(PLON,PLEV) :: zrho

  REAL, DIMENSION(PLON,PLEV,PCNST) :: rrate
  REAL, DIMENSION(PLON,PLEV) :: massupd     ! MASS of air displaced vertically in updraft
  REAL, DIMENSION(PLON,PLEV) :: totmass     ! total mass in a grid box per unit area [kg/m^2]
  REAL, DIMENSION(PLON,PLEV) :: zmid        ! midpoint geopotential in km
  REAL, DIMENSION(PLON)      :: delzcld     ! Height in km of the convective column   

  !MS  for budgetting purposes introduced
  REAL ::  tr_seri0(PLON,PLEV,PCNST)
  REAL ::  dz

  wflux=0.
  wsflux=0.
  tr_seri0=tr_seri
  totmass = pdel / gravit

  ! Anne 01/04/2005 initialisations
  fractst(:,:) = 0.
  decayst(:,:) = 0.

  !MS  for budgetting purposes introduced
  !  we teat ONLY Synoptic precipitation with the scheme of Giorgi and Chameides
  !

  zmid(:,:) = 1.e-3 * zma(:PLON,:) / gravit

  DO K=PLEV,1,-1
    pdownst(:,K)=flxrst(:,K)+ flxsst(:,K)
    pdiffst(:,K) = (flxrst(:,K)+flxsst(:,K)) - &
       (flxrst(:,K+1)+flxsst(:,K+1) )
  END DO                    ! loop over layers
  

  DO i = 1, PLON
    ktrop = MAX(1,itrop(i))        ! 2D field of tropopause level indices
    pdownst(i,ktrop:PLEV) = 0.
    pdiffst(i,ktrop:PLEV) = 0.
  END DO

  !
  ! pkgm3st is the quantity of precipitable water formed in the layer (Units: kg/m3/s)
  ! st for stratiform
  !
  pkgm3st=pdiffst/zheight     ! conversion from kg/m2/s to kg/m3/s

  !MS fractst computation creates floating error during execution of job
  !MS pkg is thus taken to a miniumum value, if above zero

  WHERE(pkgm3st .GT. 0.) pkgm3st=MAX(pkgm3st,1.e-10)

  !
  ! fractst is the fraction of the grid box in which precipitation occurs based upon
  ! Giorgi and Chameides and Balkanski 1992
  !     
  WHERE (pkgm3st >0.)
      fractst=pkgm3st/(pkgm3st+xlvalst*bminusst) ! Fraction that experiences precip.
  END WHERE

  ! Next lines compute the conversion of cloud water into rainwater for stratiform precipitation
  !
  WHERE (pdiffst > 0. .AND. pdownst>0. .AND. fractst > 0.)
      !
      !  bminusst is the minimum value for beta2st, rate of conversion of cloud water to precipitation
      !
      beta2st=bminusst+(pkgm3st*delt)/(xlvalst*fractst*delt) 
      decayst = 1. - EXP(-beta2st * delt)

      !  we set beta negative for washout
  ELSEWHERE(pdiffst < 0. .AND. pdownst>0. .AND. fractst >0.)
      beta2st= - pdownst/(fractst*delt) * delt
  ELSEWHERE (pdiffst < 0. .AND. pdownst <0.)
      fractst = -1.
  END WHERE

  DO 20 mode = 1,nmodes
    IF (mass1index(mode) .EQ. 0) CYCLE 
    m1x=mass1index(mode)
    nx=numberindex(mode)
    
    DO 22 JT=m1x,nx
      WHERE (fractst*decayst  < 1.) 
          rrate(:,:,JT) = fractst * decayst 
      ELSEWHERE 
          rrate(:,:,JT) = 0.
      END WHERE
      
      !yjb Now let's treat stratiform deposition
      !yjb
      WHERE(rrate(:,:,jt) .GT. 0. .AND. rrate(:,:,jt).LT.0.95 ) 
          WHERE (pdiffst > 0. .AND. pdownst > 0.)
              !yjb We make sure not to scavenge more than is in the grid box!!!
              !new var called incldfac for interstitial vs. in liquid water.
              
              tr_seri(:,:,JT) = tr_seri(:,:,JT) * (1 -incldfac(JT)*rrate(:,:,JT))
              scavcoef_st(:,:,JT) = incldfac(JT)*rrate(:,:,JT)
          END WHERE
      END WHERE
      

22  CONTINUE                ! END loop over tracers in mode
20  CONTINUE                  ! loop over modes

  ! diagnostic of total wet stratiform flux MS JUNE 2002
  ! -> kg m-2 s-1
  DO K=1,PLON
    DO JT=trmx,trnx
      wsflux(k,JT)=SUM( (tr_seri0(k,:,JT)-tr_seri(k,:,JT))*zdp1(k,:) ) 
    ENDDO
  ENDDO
  wflux=wsflux
  
  
END SUBROUTINE wetdepst
        
#endif