!$Id: neutral.F90 10 2007-08-09 12:43:01Z acosce $
!! =========================================================================
!! INCA - INteraction with Chemistry and Aerosols
!! 
!! Copyright Laboratoire des Sciences du Climat et de l'Environnement (LSCE)
!! 	     Unite mixte CEA-CNRS-UVSQ
!! 
!! Contributors to this INCA subroutine:
!!
!! Didier Hauglustaine, LSCE, hauglustaine@cea.fr
!! Stacy Walters, NCAR, stacy@ucar.edu 
!! 
!! Anne Cozic, LSCE, anne.cozic@cea.fr
!! Yann Meurdesoif, LSCE, yann.meurdesoif@cea.fr
!!
!! This software is a computer program whose purpose is to simulate the 
!! atmospheric gas phase and aerosol composition. The model is designed to be
!! used within a transport model or a general circulation model. This version 
!! of INCA was designed to be coupled to the LMDz GCM. LMDz-INCA accounts
!! for emissions, transport (resolved and sub-grid scale), photochemical 
!! transformations, and scavenging (dry deposition and washout) of chemical 
!! species and aerosols interactively in the GCM. Several versions of the INCA
!! model are currently used depending on the envisaged applications with the 
!! chemistry-climate model. 
!! 
!! This software is governed by the CeCILL  license under French law and
!! abiding by the rules of distribution of free software.  You can  use, 
!! modify and/ or redistribute the software under the terms of the CeCILL
!! license as circulated by CEA, CNRS and INRIA at the following URL
!! "http://www.cecill.info". 
!! 
!! As a counterpart to the access to the source code and  rights to copy,
!! modify and redistribute granted by the license, users are provided only
!! with a limited warranty  and the software's author,  the holder of the
!! economic rights,  and the successive licensors  have only  limited
!! liability. 
!! 
!! In this respect, the user's attention is drawn to the risks associated
!! with loading,  using,  modifying and/or developing or reproducing the
!! software by the user in light of its specific status of free software,
!! that may mean  that it is complicated to manipulate,  and  that  also
!! therefore means  that it is reserved for developers  and  experienced
!! professionals having in-depth computer knowledge. Users are therefore
!! encouraged to load and test the software's suitability as regards their
!! requirements in conditions enabling the security of their systems and/or 
!! data to be ensured and,  more generally, to use and operate it in the 
!! same conditions as regards security. 
!! 
!! The fact that you are presently reading this means that you have had
!! knowledge of the CeCILL license and that you accept its terms.
!! =========================================================================

#include <inca_define.h>
  subroutine neutral(u10_mps,ustar_mps,obklen_m, u10n_mps	)
    !-----------------------------------------------------------------------	
    ! subroutine to compute u10 neutral wind speed
    ! inputs
    !        u10_mps - wind speed at 10 m (m/s)
    !        ustar_mps - friction velocity (m/s)
    !        obklen_m - monin-obukhov length scale (m)
    ! outputs
    !        u10n_mps - wind speed at 10 m under neutral conditions (m/s)
    ! following code assumes reference height Z is 10m, consistent with use
    ! of u10 and u10_neutral.  If not, code
    ! should be changed so that constants of 50. and 160. in equations
    ! below are changed to -5 * Z and -16 * Z respectively.
    ! Reference:  G. L. Geernaert.  'Bulk parameterizations for the 
    ! wind stress and heat fluxes,' in Surface Waves and Fluxes, Vol. I,
    ! Current Theory, Geernaert and W.J. Plant, editors, Kluwer Academic
    ! Publishers, Boston, MA, 1990.
    ! subroutine written Feb 2001 by eg chapman
    ! adapted to LMD-ZT by E. Cosme 310801
    ! Following Will Shaw (PNL, Seattle) the theory applied for flux
    ! calculation with the scheme of Nightingale et al. (2000) does not
    ! hold anymore when -1<obklen<20. In this case, u10n is set to 0,
    ! so that the transfer velocity  computed in nightingale.F will also
    ! be 0. The flux is then set to 0.
    !----------------------------------------------------------------------		
    
    use inca_dim
    use CONST_MOD
    IMPLICIT NONE
    
    real u10_mps(PLON),ustar_mps(PLON),obklen_m(PLON)
    real u10n_mps(PLON)
    real von_karman
    ! pour etre coherent avec vk de bl_for_dms.F
    parameter (von_karman = 0.35)	

    real phi, phi_inv, phi_inv_sq, f1, f2, f3, dum1, psi
    integer i
    
    
    psi = 0.
    do i=1,PLON
       
       if (u10_mps(i) .lt. 0.) u10_mps(i) = 0.0
       
       if  (obklen_m(i) .lt. 0.) then 
          phi = (1. - 160./obklen_m(i))**(-0.25)
          phi_inv = 1./phi
          phi_inv_sq = 1./phi * 1./phi
          f1 = (1. + phi_inv) / 2.
          f2 = (1. + phi_inv_sq)/2.
          ! following to avoid numerical overruns. recall tan(90deg)=infinity
          dum1 = min (1.e24, phi_inv)
          f3 = atan(dum1)
          psi = 2.*log(f1) + log(f2) - 2.*f3 + pi/2.   
       else if (obklen_m(i) .gt. 0.) then
          psi = -50. / obklen_m(i)
       end if
       
       u10n_mps(i) = u10_mps(i) + (ustar_mps(i) * psi /von_karman )
       ! u10n set to 0. if -1 < obklen < 20
       if ((obklen_m(i).gt.-1.).and.(obklen_m(i).lt.20.)) then
          u10n_mps(i) = 0.
       endif
       if (u10n_mps(i) .lt. 0.) u10n_mps(i) = 0.0
       
    enddo
    return
  end subroutine neutral