!$Id: cloud_mod.F90 104 2008-12-23 10:28:51Z acosce $
!! =========================================================================
!! INCA - INteraction with Chemistry and Aerosols
!! 
!! Copyright Laboratoire des Sciences du Climat et de l'Environnement (LSCE)
!! 	     Unite mixte CEA-CNRS-UVSQ
!! 
!! Contributors to this INCA subroutine:
!! 
!! Stacy Walters, NCAR, stacy@ucar.edu 
!! 
!! Anne Cozic, LSCE, anne.cozic@cea.fr
!! Yann Meurdesoif, LSCE, yann.meurdesoif@cea.fr
!!
!! This software is a computer program whose purpose is to simulate the 
!! atmospheric gas phase and aerosol composition. The model is designed to be
!! used within a transport model or a general circulation model. This version 
!! of INCA was designed to be coupled to the LMDz GCM. LMDz-INCA accounts
!! for emissions, transport (resolved and sub-grid scale), photochemical 
!! transformations, and scavenging (dry deposition and washout) of chemical 
!! species and aerosols interactively in the GCM. Several versions of the INCA
!! model are currently used depending on the envisaged applications with the 
!! chemistry-climate model. 
!! 
!! This software is governed by the CeCILL  license under French law and
!! abiding by the rules of distribution of free software.  You can  use, 
!! modify and/ or redistribute the software under the terms of the CeCILL
!! license as circulated by CEA, CNRS and INRIA at the following URL
!! "http://www.cecill.info". 
!! 
!! As a counterpart to the access to the source code and  rights to copy,
!! modify and redistribute granted by the license, users are provided only
!! with a limited warranty  and the software's author,  the holder of the
!! economic rights,  and the successive licensors  have only  limited
!! liability. 
!! 
!! In this respect, the user's attention is drawn to the risks associated
!! with loading,  using,  modifying and/or developing or reproducing the
!! software by the user in light of its specific status of free software,
!! that may mean  that it is complicated to manipulate,  and  that  also
!! therefore means  that it is reserved for developers  and  experienced
!! professionals having in-depth computer knowledge. Users are therefore
!! encouraged to load and test the software's suitability as regards their
!! requirements in conditions enabling the security of their systems and/or 
!! data to be ensured and,  more generally, to use and operate it in the 
!! same conditions as regards security. 
!! 
!! The fact that you are presently reading this means that you have had
!! knowledge of the CeCILL license and that you accept its terms.
!! =========================================================================


SUBROUTINE CLOUD_MOD( zen_angle  ,&
   clouds        ,&
   lwc           ,&
   delp          ,&
   srf_alb       ,&
   eff_alb       ,&
   cld_mult )
  !-----------------------------------------------------------------------
  ! 	... Cloud alteration factors for photorates and albedo
  !     Stacy Walters, NCAR, 1998.
  !-----------------------------------------------------------------------
  USE PHT_TABLES, ONLY : jdim, alpha
  USE INCA_DIM
  IMPLICIT NONE


  REAL, PARAMETER :: gi = 1./9.80616

  !-----------------------------------------------------------------------
  ! 	... Dummy arguments
  !-----------------------------------------------------------------------
  REAL, INTENT(in)    ::  zen_angle         ! zenith angle
  REAL, INTENT(in)    ::  srf_alb           ! surface albedo
  REAL, INTENT(in)    ::  clouds(PLEV)       ! cloud fraction
  REAL, INTENT(in)    ::  lwc(PLEV)          ! liquid water content (mass mr)
  REAL, INTENT(in)    ::  delp(PLEV)         ! del press about midpoint in pascals
  REAL, INTENT(out)   ::  eff_alb(PLEV)      ! effective albedo
  REAL, INTENT(out)   ::  cld_mult(jdim,PLEV) !photolysis mult factor
  
  !-----------------------------------------------------------------------
  ! 	... Local variables
  !-----------------------------------------------------------------------
  INTEGER :: k, m
  REAL    :: coschi
  REAL    :: del_lwp(PLEV)
  REAL    :: del_tau(PLEV)
  REAL    :: above_tau(PLEV)
  REAL    :: below_tau(PLEV)
  REAL    :: above_cld(PLEV)
  REAL    :: below_cld(PLEV)
  REAL    :: above_tra(PLEV)
  REAL    :: below_tra(PLEV)
  REAL    :: fac1(PLEV)
  REAL    :: fac2(PLEV)
  REAL    :: fac3(PLEV)
  
  !---------------------------------------------------------
  !	... Modify lwc for cloud fraction and form
  !	    liquid water path for each layer
  !---------------------------------------------------------
  where( clouds(:) /= 0. )
     del_lwp(:) = gi * lwc(:) * delp(:) * 1.e3 / clouds(:)
  elsewhere
     del_lwp(:) = 0.
  endwhere
  !---------------------------------------------------------
  !    	... Form tau for each model layer
  !---------------------------------------------------------
  where( clouds(:) /= 0. )
     del_tau(:) = del_lwp(:) *.155 * clouds(:)**1.5
  elsewhere
     del_tau(:) = 0.
  end where
  !---------------------------------------------------------
  !    	... Form integrated tau from top down
  !---------------------------------------------------------
  above_tau(1) = 0.
  do k = 1,PLEVM
     above_tau(k+1) = del_tau(k) + above_tau(k)
  end do
  !---------------------------------------------------------
  !    	... Form integrated tau from bottom up
  !---------------------------------------------------------
  below_tau(PLEV) = 0.
  do k = PLEVM,1,-1
     below_tau(k) = del_tau(k+1) + below_tau(k+1)
  end do
  !---------------------------------------------------------
  !	... Form vertically averaged cloud cover above and below
  !---------------------------------------------------------
  above_cld(1) = 0.
  do k = 1,PLEVM
     above_cld(k+1) = clouds(k) * del_tau(k) + above_cld(k)
  end do
  do k = 2,PLEV
     if( above_tau(k) /= 0. ) then
        above_cld(k) = above_cld(k) / above_tau(k)
     else
        above_cld(k) = above_cld(k-1)
     end if
  end do
  below_cld(PLEV) = 0.
  do k = PLEVM,1,-1
     below_cld(k) = clouds(k+1) * del_tau(k+1) + below_cld(k+1)
  end do
  do k = PLEVM,1,-1
     if( below_tau(k) /= 0. ) then
        below_cld(k) = below_cld(k) / below_tau(k)
     else
        below_cld(k) = below_cld(k+1)
     end if
  end do
  !---------------------------------------------------------
  !	... Modify above_tau and below_tau
  !---------------------------------------------------------
  where( above_cld(2:PLEV) /= 0. )
     above_tau(2:PLEV) = above_tau(2:PLEV) / above_cld(2:PLEV)
  end where
  where( below_cld(:PLEVM) /= 0. )
     below_tau(:PLEVM) = below_tau(:PLEVM) / below_cld(:PLEVM)
  end where
  where( above_tau(2:PLEV) < 5. )
     above_cld(2:PLEV) = 0.
  end where
  where( below_tau(:PLEVM) < 5. )
     below_cld(:PLEVM) = 0.
  end where
  !---------------------------------------------------------
  !       ... Form transmission factors
  !---------------------------------------------------------
  above_tra(:) = (5. - EXP(-above_tau(:))) &
       /(4. + 0.42 * above_tau(:))
  below_tra(:) = (5. - EXP(-below_tau(:))) &
       /(4. + 0.42 * below_tau(:))
  !---------------------------------------------------------
  !	... Correction factors
  !---------------------------------------------------------
  eff_alb(:) = srf_alb
  coschi = MAX( COS( zen_angle ),.5 )
  where( del_lwp(:)*.155 < 5. )
     fac1(:) = 0.
  elsewhere
     fac1(:) = 1.4 * coschi - 1.
  end where
  fac2(:) = MIN( 0.,1.6*coschi*above_tra(:) - 1. )
  fac3(:) = MAX( 0.,(1.-below_tra(:))*coschi)

  DO m = 1, jdim
     cld_mult(m,:) = MAX (.05, 1. + fac1(:) * clouds(:) &
          + fac2(:) * above_cld(:)           &
          + alpha(m) * fac3(:) * below_cld(:) )
  END DO

END SUBROUTINE CLOUD_MOD