MODULE xios_inca

  USE xios
  USE PRINT_INCA
  USE MOD_GRID_INCA
  USE MOD_INCA_MPI_DATA
  USE MOD_INCA_PARA
  USE MOD_CONST_MPI_INCA
  USE CONST_LMDZ
  USE IOIPSL
  USE PARAM_CHEM
  USE SURF_CHEM_MOD
  USE RATE_INDEX_MOD
  USE CHEM_TRACNM, ONLY: solsym
  USE SPECIES_NAMES
  USE AEROSOL_DIAG, ONLY : naero_grp, mrfname,mrfname_xml, mrfname_long, las, cla
  USE AEROSOL_MOD

  IMPLICIT NONE
  PRIVATE
  PUBLIC :: xios_inca_init , xios_inca_change_context, &
       xios_inca_update_calendar, xios_inca_context_finalize, &
       xios_inca_send_field, xios_inca_recv_field, xios_inca_recv_field_glo, xios_inca_recv_field_mpi

  !
  !! Declaration of internal variables
  !
  TYPE(xios_context)              :: ctx_hdl_inca      !! Handel for INCA
!$OMP THREADPRIVATE(ctx_hdl_inca)
  TYPE(xios_fieldgroup) :: reacflux_hdl,reacrate_hdl, invoxy_hdl, phtrate_hdl, extfrc_hdl, extfrc_col_hdl, conc_spcs_hdl, emi_hdl, dryvd_hdl
  TYPE(xios_fieldgroup) :: tauinca1_hdl, pizinca1_hdl, cginca1_hdl, tauinca2_hdl, pizinca2_hdl, cginca2_hdl
  TYPE(xios_fieldgroup) :: drydep_hdl, hrate_hdl, od_hdl, od3d_hdl, source_hdl, emiNoBio_hdl,emiOrch_hdl
  TYPE(xios_fieldgroup) :: source0_hdl, source0_read_hdl, invoxy0_hdl, invoxy0_read_hdl
  TYPE(xios_fieldgroup) :: sed_hdl,wet_hdl,load_hdl,emialt_hdl,mdw_hdl,aerh2o_hdl
  TYPE(xios_fieldgroup) :: tau1_hdl, tau2_hdl,piz1_hdl,piz2_hdl,cg1_hdl,cg2_hdl
  TYPE(xios_fieldgroup) :: swtoaas_hdl,swtoacs_hdl,swsrfas_hdl,swsrfcs_hdl,fswtoaas_hdl,fswtoacs_hdl,fswsrfas_hdl,fswsrfcs_hdl, wetloss_hdl
  TYPE(xios_field) :: child
!$OMP THREADPRIVATE(reacflux_hdl, reacrate_hdl,invoxy_hdl, phtrate_hdl, extfrc_hdl, extfrc_col_hdl, conc_spcs_hdl, emi_hdl,dryvd_hdl, child) 
!$OMP THREADPRIVATE(tauinca1_hdl, pizinca1_hdl, cginca1_hdl, tauinca2_hdl, pizinca2_hdl, cginca2_hdl)
!$OMP THREADPRIVATE(drydep_hdl, hrate_hdl, od_hdl, od3d_hdl, source_hdl, emiNoBio_hdl,emiOrch_hdl) 
!$OMP THREADPRIVATE(sed_hdl,wet_hdl,load_hdl,emialt_hdl,mdw_hdl,aerh2o_hdl) 
!$OMP THREADPRIVATE(tau1_hdl, tau2_hdl,piz1_hdl,piz2_hdl,cg1_hdl,cg2_hdl)
!$OMP THREADPRIVATE(swtoaas_hdl,swtoacs_hdl,swsrfas_hdl,swsrfcs_hdl,fswtoaas_hdl,fswtoacs_hdl,fswsrfas_hdl,fswsrfcs_hdl, wetloss_hdl)
!$OMP THREADPRIVATE(source0_hdl, source0_read_hdl, invoxy0_hdl, invoxy0_read_hdl) 

  CHARACTER(len=*),PARAMETER      :: id="client"           !! Id for initialization of INCA in 1

  ! ====================================================================
  ! INTERFACE   : xios_inca_send_field
  !
  !        Send a field to 1.
  !
  ! DESCRIPTION  : Send a field to 1. The field can have 1, 2 or 3 dimensions.
  !                This interface should be called at each time-step for each output varaiables.
  !
  ! ====================================================================

  INTERFACE xios_inca_send_field
     MODULE PROCEDURE xios_inca_send_field_r2d, xios_inca_send_field_r1d,xios_inca_send_field_r0d
  END INTERFACE


  INTERFACE xios_inca_recv_field
     MODULE PROCEDURE xios_inca_recv_field_r0d, xios_inca_recv_field_r1d, xios_inca_recv_field_r2d,xios_inca_recv_field_r3d
  END INTERFACE

  INTERFACE xios_inca_recv_field_mpi
     MODULE PROCEDURE xios_inca_recv_field_mpi_r1d
  END INTERFACE

  INTERFACE xios_inca_recv_field_glo
     MODULE PROCEDURE xios_inca_recv_field_glo_r1d,xios_inca_recv_field_glo_r2d,xios_inca_recv_field_glo_r3d
  END INTERFACE


CONTAINS
  ! ====================================================================
  ! SUBROUTINE   : xios_inca_init 
  !
  !          Initialize variables needed for use of 1.
  !
  ! DESCRIPTION  : Initialization of specific varaiables needed to use 1 such as model domain and time step. 
  !
  !
  ! ====================================================================

  SUBROUTINE xios_inca_init(&
       COMM_LMDZ, timestep, year, month, day, &
       hour, ini_an, ini_mois, ini_jour, ini_heure, &
       io_lon, io_lat, presnivs)


    USE PARAM_CHEM, ONLY : use_group, LMDZ_10m_winds
    USE MOD_GEOMETRY_INCA, ONLY : longitude, latitude, boundslon, boundslat,ind_cell_glo
    USE MOD_GRID_INCA, ONLY : nvertex, plon_glo, grid_type, regular_lonlat, unstructured
    USE MOD_INCA_MPI_DATA, ONLY : ij_nb
    USE CONST_MOD, ONLY: PI 
    USE INCA_DIM
    USE PRINT_INCA
    IMPLICIT NONE

    !
    !! 0. Variable and parameter declaration
    !
    !! 0.1 Input variables
    !
    INTEGER, INTENT(in)  :: COMM_LMDZ    !! Inca MPI communicator (from module mod_inca_mpi_data)
    INTEGER, INTENT(in)  :: year, month, day, ini_an, ini_mois, ini_jour !! Current date information
    REAL, INTENT(in) :: hour, ini_heure
    REAL,INTENT(IN) :: io_lat(:) ! latitudes (of global grid)
    REAL,INTENT(IN) :: io_lon(:) ! longitudes (of global grid)
    REAL, INTENT(in) :: timestep
    REAL, INTENT(in) ::  presnivs(PLEV)
    !
    !! 0.2 Local variables
    !
    LOGICAL :: find 
    INTEGER     :: i
    INTEGER :: it,la
    CHARACTER(LEN=30) :: start_str , time_orig          !! Current date as character string

    TYPE(xios_duration)   :: dtime    = xios_duration(0, 0, 0, 0, 0, 0)

    LOGICAL :: mask(iim_glo,jj_nb)      !Masque pour les problèmes de recouvrement MPI

    REAL, DIMENSION(nbveget) :: veget
    REAL, DIMENSION(nbsurf) :: surf
    REAL, DIMENSION(PLEV+1) :: paprsniv
    REAL, DIMENSION(PLEV)  ::  klev_value
    REAL, DIMENSION(12) :: timeco2_value
    REAL, DIMENSION(2920) :: timeco2h_value
    INTEGER :: n, length, ni, nj
    CHARACTER(len=13) :: tmp_name

    ! variables pour la grille non structuree de dynamico 
    REAL :: lon_mpi(plon_mpi)
    REAL :: lat_mpi(plon_mpi)
    REAL :: boundslon_mpi(plon_mpi,nvertex)
    REAL :: boundslat_mpi(plon_mpi,nvertex)
    INTEGER :: ind_cell_glo_mpi(plon_mpi)


    ! ===================================================================

    !
    !! 1. Set date and calendar information on the format needed by 1
    !


    IF (grid_type == unstructured) THEN 

!       write(*,*) ' dans xios_inca cell = ', ind_cell_glo 
!       call flush(6)

       CALL gather_omp(longitude*180/PI,lon_mpi)
       CALL gather_omp(latitude*180/PI,lat_mpi)
       CALL gather_omp(boundslon*180/PI,boundslon_mpi)
       CALL gather_omp(boundslat*180/PI,boundslat_mpi)
       CALL gather_omp(ind_cell_glo,ind_cell_glo_mpi)
    endif


!$OMP MASTER
       !
       !! 2. Context initialization
       !
       CALL xios_context_initialize("inca",COMM_LMDZ)
       CALL xios_get_handle("inca",ctx_hdl_inca)
       CALL xios_set_current_context(ctx_hdl_inca)


       ! Groupes pour les restart 
       ! ecriture 
       CALL xios_get_handle("source"  , source_hdl   ) 
       CALL xios_get_handle("inv_oxy" , invoxy_hdl   )
       CALL xios_get_handle("tauinca1", tauinca1_hdl )
       CALL xios_get_handle("pizinca1", pizinca1_hdl )
       CALL xios_get_handle("cginca1" , cginca1_hdl  )
       CALL xios_get_handle("tauinca2", tauinca2_hdl )
       CALL xios_get_handle("pizinca2", pizinca2_hdl )
       CALL xios_get_handle("cginca2" , cginca2_hdl  )

       ! lecture 
       CALL xios_get_handle("source0" , source0_hdl   ) 
       CALL xios_get_handle("invoxy0" , invoxy0_hdl   )

       CALL xios_get_handle("source0_read" , source0_read_hdl   ) 
       CALL xios_get_handle("invoxy0_read" , invoxy0_read_hdl   )



       ! Groupes pour les output du code 
       IF(use_group)THEN

          CALL xios_get_handle("reac_flux"     , reacflux_hdl) 
          CALL xios_get_handle("reac_rate"     , reacrate_hdl) 
          CALL xios_get_handle("photo_rate"    , phtrate_hdl)
          CALL xios_get_handle("ext_forc"      , extfrc_hdl)
          CALL xios_get_handle("ext_forc_col"  , extfrc_col_hdl)
          CALL xios_get_handle("conc_species"  , conc_spcs_hdl) 
          CALL xios_get_handle("emi_species"   , emi_hdl) 
          CALL xios_get_handle("emi_noBioNat"  , emiNoBio_hdl) 
          CALL xios_get_handle("emi_FromOrch"  , emiOrch_hdl) 
          CALL xios_get_handle("dryvd_species" , dryvd_hdl) 
          CALL xios_get_handle("drydep_species", drydep_hdl)
          CALL xios_get_handle("henry_const"   , hrate_hdl) 
          CALL xios_get_handle("Opt_thick"     , od_hdl) 
          CALL xios_get_handle("Opt_thick3D"   , od3d_hdl)
          CALL xios_get_handle("sed_aero"      , sed_hdl)
          CALL xios_get_handle("wet_aero"      , wet_hdl)
          CALL xios_get_handle("load_aero"     , load_hdl)
          CALL xios_get_handle("emialt_aero"   , emialt_hdl)
          CALL xios_get_handle("mdw_aero"      , mdw_hdl)
          CALL xios_get_handle("aerh2o_aero"   , aerh2o_hdl)
          CALL xios_get_handle("oduvvis_aero", tau1_hdl) 
          CALL xios_get_handle("odvisir_aero", tau2_hdl) 
          CALL xios_get_handle("ssauvvis_aero", piz1_hdl) 
          CALL xios_get_handle("ssavisir_aero", piz2_hdl) 
          CALL xios_get_handle("asyuvvis_aero", cg1_hdl) 
          CALL xios_get_handle("asyvisir_aero", cg2_hdl) 
          CALL xios_get_handle("swtoaas_aero",swtoaas_hdl ) 
          CALL xios_get_handle("swtoacs_aero",swtoacs_hdl ) 
          CALL xios_get_handle("swsrfas_aero",swsrfas_hdl ) 
          CALL xios_get_handle("swsrfcs_aero",swsrfcs_hdl ) 
          CALL xios_get_handle("fswtoaas_aero",fswtoaas_hdl ) 
          CALL xios_get_handle("fswtoacs_aero",fswtoacs_hdl ) 
          CALL xios_get_handle("fswsrfas_aero",fswsrfas_hdl ) 
          CALL xios_get_handle("fswsrfcs_aero",fswsrfcs_hdl ) 
          CALL xios_get_handle("wetloss",wetloss_hdl ) 

       ENDIF


       !
       !! 2. Calendar and date definition
       !
       !Réglage du calendrier:
       SELECT CASE (calend)
       CASE('earth_360d')
          CALL xios_define_calendar(TYPE="D360",time_origin=xios_date(year,month,day,INT(hour),0,0),start_date=xios_date(ini_an, ini_mois, ini_jour, INT(ini_heure),0,0))
       CASE('earth_365d')
          CALL xios_define_calendar(TYPE="NoLeap",time_origin=xios_date(year,month,day,INT(hour),0,0),start_date=xios_date(ini_an, ini_mois, ini_jour, INT(ini_heure),0,0))
       CASE('gregorian')
          CALL xios_define_calendar(TYPE="Gregorian",time_origin=xios_date(year,month,day,INT(hour),0,0),start_date=xios_date(ini_an, ini_mois, ini_jour, INT(ini_heure),0,0))
       CASE DEFAULT
          CALL print_err(3, 'wxios_set_cal',' Mauvais choix de calendrier', '', '')
       END SELECT


       !! 3. Send the time-step length to 1               
       !

       dtime%second = timestep
       CALL xios_set_timestep(dtime)
       
       !
       !! 4. Domain definition
       !
       ! Global domain
       !On parametrise le domaine:
!      write(*,*) 'XIOS INCA initialisation grille ', grid_type, ' regular_lonlat = ', regular_lonlat, ' unstructured = ', unstructured

       if (grid_type == regular_lonlat) THEN 
          CALL xios_set_domain_attr("dom_chem", ni_glo=iim_glo, ibegin=0, ni=iim_glo, TYPE="rectilinear")
          CALL xios_set_domain_attr("dom_chem", nj_glo=jjm_glo, jbegin=jj_begin-1, nj=jj_nb, data_dim=2)
          CALL xios_set_domain_attr("dom_chem", lonvalue_1D=(io_lon(1:iim_glo)+1000)-1000, latvalue_1D=io_lat(jj_begin:jj_end))


          IF (.NOT.is_sequential) THEN
             mask(:,:)=.TRUE.
             IF (ii_begin>1) mask(1:ii_begin-1,1) = .FALSE.
             IF (ii_end<jj_nb) mask(ii_end+1:iim_glo,jj_nb) = .FALSE.
             ! special case for south pole
             IF ((ii_end.EQ.1).AND.(is_south_pole)) mask(1:iim_glo,jj_nb)=.TRUE.
             CALL xios_set_domain_attr("dom_chem", mask_1D=RESHAPE(mask(:,:),(/iim_glo*jj_nb/)))
          END IF
          


       ELSE IF (grid_type == unstructured) THEN 

          CALL xios_set_domain_attr("dom_chem", ni_glo=jjm_glo, type="unstructured", nvertex=nvertex)
          CALL xios_set_domain_attr("dom_chem", ibegin=ij_begin-1, ni=ij_nb)
          CALL xios_set_domain_attr("dom_chem", nvertex=nvertex, lonvalue_1d=lon_mpi, latvalue_1d=lat_mpi)
          CALL xios_set_domain_attr("dom_chem", bounds_lon_1d=TRANSPOSE(boundslon_mpi), bounds_lat_1d=TRANSPOSE(boundslat_mpi) )
          CALL xios_set_domain_attr("dom_chem", i_index=ind_cell_glo_mpi(:)-1)

          
          IF (xios_remap_output) THEN
             ! Define output grid as domain_landpoints_regular (grid specified in xml files)
             CALL xios_set_domain_attr("dom_chem_out",domain_ref="dom_chem_regular")
             
             CALL xios_set_fieldgroup_attr("remap_expr",expr="@this_ref")
             CALL xios_set_fieldgroup_attr("remap_1ts",   freq_op=xios_duration_convert_from_string("1ts"))
             CALL xios_set_fieldgroup_attr("remap_1800s", freq_op=xios_duration_convert_from_string("1800s"))
             CALL xios_set_fieldgroup_attr("remap_1h",    freq_op=xios_duration_convert_from_string("1h"))
             CALL xios_set_fieldgroup_attr("remap_3h",    freq_op=xios_duration_convert_from_string("3h"))
             CALL xios_set_fieldgroup_attr("remap_6h",    freq_op=xios_duration_convert_from_string("6h"))
             CALL xios_set_fieldgroup_attr("remap_1d",    freq_op=xios_duration_convert_from_string("1d"))
             CALL xios_set_fieldgroup_attr("remap_1mo",   freq_op=xios_duration_convert_from_string("1mo"))
 
          ENDIF

       ENDIF
    
       !! 5. Axis definition
       !
       DO i=1,nbveget
          veget(i) = i 
       END DO

       DO i=1,nbsurf
          surf(i) = i 
       END DO

       DO i=1,PLEV+1
          paprsniv(i) = real(i)  
       END DO

       DO i=1,PLEV
          klev_value(i) = real(i) 
       enddo

       CALL xios_set_axis_attr("presnivs",n_glo=PLEV,VALUE=presnivs)
       CALL xios_set_axis_attr("paprsniv",n_glo=PLEV+1,VALUE=paprsniv)
       CALL xios_set_axis_attr("veget", n_glo=nbveget, VALUE=veget) 
       CALL xios_set_axis_attr("surf", n_glo=nbsurf, VALUE=surf) 
       CALL xios_set_axis_attr("klev", n_glo=PLEV, VALUE=klev_value(1:PLEV))
       CALL xios_set_axis_attr("bnds",n_glo=2, VALUE=(/1.,2./))

       if (grid_type == regular_lonlat) THEN 
          IF (xios_is_valid_axis("axis_lat")) THEN
             CALL xios_set_axis_attr( "axis_lat", n_glo=jjm_glo, n=jj_nb, begin=jj_begin-1, value=io_lat(jj_begin:jj_end))
          ENDIF
       endif

       ! Declaration interactivement pour la definition des variables des groupes xml 
       ! au fur et a mesure le lien nom_variable / name_xml sera reproduit dans le fichier 
       ! inca_IDxml.out 

       !-----------------------------------------------------
       !-----------------------------------------------------
       ! Groupes pour les restarts 
       !-----------------------------------------------------
       !-----------------------------------------------------
       ! ecriture 
       ! Sources
       DO n=1,8
          CALL xios_add_child(source_hdl, child, "source_"//trim(tracnam(n)))
          CALL xios_set_attr(child,name="source"//TRIM(tracnam(n)), unit="kg m-2 s-1")
       ENDDO!

       ! invariants
       DO n=1, 12
          CALL xios_add_child(invoxy_hdl, child, "inv_"//TRIM(invname(n)))
          CALL xios_set_attr(child,name="inv_"//TRIM(invname(n)),  unit="cm-3" ) 
          CALL write_xml_info("inv_"//TRIM(invname(n)), "inv_"//TRIM(invname(n)),"false", "cm-3","presnivs","false")
       ENDDO

       ! lecture 
       ! Sources
       DO n=1,8
          CALL xios_add_child(source0_hdl, child, "source"//trim(tracnam(n))//"id")
          CALL xios_set_attr(child,name="source"//TRIM(tracnam(n)))

          CALL xios_add_child(source0_read_hdl, child, "source"//trim(tracnam(n))//"_read")
          CALL xios_set_attr(child,field_ref="source"//trim(tracnam(n))//"id")
       ENDDO

       ! invariants
       DO n=1, 12
          CALL xios_add_child(invoxy0_hdl, child, "inv_"//TRIM(invname(n))//"id")
          CALL xios_set_attr(child,name="inv_"//TRIM(invname(n)) ) 

          CALL xios_add_child(invoxy0_read_hdl, child, "inv_"//TRIM(invname(n))//"_read")
          CALL xios_set_attr(child,field_ref="inv_"//TRIM(invname(n))//"id") 

       ENDDO



       ! a retirer si nous ne sommes pas dans le cas aerosols 
       CALL xios_set_field_attr("ccm1", enabled=.FALSE.) 
       CALL xios_set_field_attr("ccm2", enabled=.FALSE.) 
       CALL xios_set_field_attr("h2oc", enabled=.FALSE.) 

       !-----------------------------------------------------
       !-----------------------------------------------------
       ! Groupes pour les output
       !-----------------------------------------------------
       !-----------------------------------------------------
       IF(use_group)THEN

          DO n=1,8

             !-----------------------------------------------
             ! declaration des concentrations d'especes 
             !-----------------------------------------------
             CALL xios_add_child(conc_spcs_hdl,child,tracnam(n))

             CALL xios_set_attr(child,name="vmr"//TRIM(name_xml(n)),unit="mol mol-1", long_name=TRIM(tracnam(n))//" Volume Mixing Ratio")
             CALL write_xml_info(TRIM(tracnam(n)), "vmr"//TRIM(name_xml(n)), TRIM(tracnam(n))//" Volume Mixing Ratio","mol mol-1","presnivs","false")

             !-----------------------------------------------
             ! declaration des emissions
             !-----------------------------------------------
             CALL xios_add_child(emi_hdl,child,"Emi_"//tracnam(n))
             CALL xios_set_attr(child,name="emi"//TRIM(name_xml(n)), unit="kg m-2 s-1", long_name="Total Emission Rate of "//TRIM(tracnam(n)))
             CALL write_xml_info("Emi_"//TRIM(tracnam(n)), "emi"//TRIM(name_xml(n)), "Total Emission Rate of "//TRIM(tracnam(n)),"kg m-2 s-1","false","false")

             !-----------------------------------------------
             ! declaration des vitesses de deposition seches
             !-----------------------------------------------
             CALL xios_add_child(dryvd_hdl,child,"Dep_"//tracnam(n))
             CALL xios_set_attr(child,name="dryvd"//TRIM(name_xml(n)), unit="cm s-1", long_name="Dry Deposition Velocity of "//TRIM(tracnam(n)))
             CALL write_xml_info("Dep_"//TRIM(tracnam(n)), "dryvd"//TRIM(name_xml(n)), "Dry Deposition Velocity of "//TRIM(tracnam(n)),"cm s-1","false","false")



             !-----------------------------------------------
             ! declaration des depots sec 
             !-----------------------------------------------
             CALL xios_add_child(drydep_hdl,child,"Dflux_"//tracnam(n))
             CALL xios_set_attr(child,name="dry"//TRIM(name_xml(n)), unit="kg m-2 s-1", long_name="Dry Deposition of "//TRIM(tracnam(n)))
             CALL write_xml_info("Dflux_"//TRIM(tracnam(n)), "dry"//TRIM(name_xml(n)), "Dry Deposition of "//TRIM(tracnam(n)),"kg m-2 s-1","false","false")

          ENDDO

          !-----------------------------------------------
          ! groupe reaction flux
          !-----------------------------------------------
          DO n=1, 12
             CALL xios_add_child(reacflux_hdl, child, "flux_"//TRIM(reacname(n))) 
             CALL xios_set_attr(child, name="flux_"//TRIM(reacname(n)), unit="molec.cm-3.s-1")
             CALL write_xml_info("flux_"//TRIM(reacname(n)), "flux_"//TRIM(reacname(n)), "false","molec.cm-3.s-1","presnivs","false")

             CALL xios_add_child(reacrate_hdl, child, "reacrate_"//TRIM(reacname(n))) 
             CALL xios_set_attr(child, name="reacrate_"//TRIM(reacname(n)))
          ENDDO



          !-----------------------------------------------
          ! groupe phtrate 
          !-----------------------------------------------
          DO n=1, 2
             CALL xios_add_child(phtrate_hdl, child, "phtrate_"//TRIM(reacname(n))) 
             CALL xios_set_attr(child, name="phtrate_"//TRIM(reacname(n)), long_name="photolysis rate for "//TRIM(reacname(n)), unit="s-1")
             CALL write_xml_info("phtrate_"//TRIM(reacname(n)),"phtrate_"//TRIM(reacname(n)),"photolysis rate for "//TRIM(reacname(n)),"s-1","presnivs","false") 
          ENDDO

          DO n=1, 1
          !-----------------------------------------------
          ! groupe external forcing
          !-----------------------------------------------
             CALL xios_add_child(extfrc_hdl, child, "extfrc_"//TRIM(extname(n))) 
             CALL xios_set_attr(child, name="extfrc_"//TRIM(extname(n)), unit="??")
             CALL write_xml_info("extfrc_"//TRIM(extname(n)), "extfrc_"//TRIM(extname(n)),"false","false","presnivs","false") 

          !-----------------------------------------------
          ! groupe vertically integrated external forcing
          !-----------------------------------------------
             CALL xios_add_child(extfrc_col_hdl, child, "extfrc_"//TRIM(extname(n))//"_col") 
             CALL xios_set_attr(child, name="extfrc_"//TRIM(extname(n))//"_col", unit="kg/m2/s")
             CALL write_xml_info("extfrc_"//TRIM(extname(n))//"_col", "extfrc_"//TRIM(extname(n))//"_col","Vertically integrated 3D emission","kg/m2/s","false","false") 
          ENDDO

          !-----------------------------------------------
          ! groupe constantes d'henry des reactions heterogenes 
          !-----------------------------------------------
          DO n=1, 1
             CALL xios_add_child(hrate_hdl, child, "hrate_"//TRIM(hetname(n))) 
             CALL xios_set_attr(child, name="hrate_"//TRIM(hetname(n)), unit="s-1")
             CALL write_xml_info("hrate_"//TRIM(hetname(n)),"hrate_"//TRIM(hetname(n)),"false","s-1","presnivs","false") 

             CALL xios_add_child(wetloss_hdl, child, "wetloss_"//TRIM(hetname(n))) 
             CALL xios_set_attr(child, name="wetloss_"//TRIM(hetname(n)))
             CALL write_xml_info("wetloss_"//TRIM(hetname(n)),"wetloss_"//TRIM(hetname(n)),"false","[kg m-2 s-1]","presnivs","false") 

          ENDDO

          IF (config_inca .NE. 'aeNP') THEN 
             ! forcing diagnostics
             DO la=1,naero_grp


                CALL xios_add_child(tau1_hdl, child, "ODUVVIS_"//TRIM(mrfname(la)))
                CALL xios_set_attr(child,name="oduvvis"//TRIM(mrfname_xml(la)),long_name="Optical thickness band1  "//TRIM(mrfname_long(la)))
                CALL write_xml_info("ODUVVIS_"//TRIM(mrfname(la)),"oduvvis"//TRIM(mrfname_xml(la)),"Optical thickness band1  "//TRIM(mrfname_long(la)),"false","presnivs","false") 

                CALL xios_add_child(tau2_hdl, child,"ODVISIR_"//TRIM(mrfname(la)) )
                CALL xios_set_attr(child,name="odvisir"//TRIM(mrfname_xml(la)),long_name="Optical thickness band2  "//TRIM(mrfname_long(la)))
                CALL write_xml_info("ODVISIR_"//TRIM(mrfname(la)),"odvisir"//TRIM(mrfname_xml(la)),"Optical thickness band2  "//TRIM(mrfname_long(la)),"false","presnivs","false") 

                CALL xios_add_child(piz1_hdl, child, "SSAUVVIS_"//TRIM(mrfname(la)))
                CALL xios_set_attr(child,name="ssauvvis"//TRIM(mrfname_xml(la)),long_name="Single scattering albedo band1  "//TRIM(mrfname_long(la)))
                CALL write_xml_info("SSAUVVIS_"//TRIM(mrfname(la)),"ssauvvis"//TRIM(mrfname_xml(la)),"Single scattering albedo band1  "//TRIM(mrfname_long(la)),"false","presnivs","false") 

                CALL xios_add_child(piz2_hdl, child,"SSAVISIR_"//TRIM(mrfname(la)) )
                CALL xios_set_attr(child,name="ssavisir"//TRIM(mrfname_xml(la)),long_name="Single scattering albedo band2  "//TRIM(mrfname_long(la)))
                CALL write_xml_info("SSAVISIR_"//TRIM(mrfname(la)),"ssavisir"//TRIM(mrfname_xml(la)),"Single scattering albedo band2  "//TRIM(mrfname_long(la)),"false","presnivs","false") 

                CALL xios_add_child(cg1_hdl, child, "ASYUVVIS_"//TRIM(mrfname(la)))
                CALL xios_set_attr(child,name="asyuvvis"//TRIM(mrfname_xml(la)),long_name="Asymmetry parameter band1  "//TRIM(mrfname_long(la)))
                CALL write_xml_info("ASYUVVIS_"//TRIM(mrfname(la)),"asyuvvis"//TRIM(mrfname_xml(la)),"Asymmetry parameter band1  "//TRIM(mrfname_long(la)),"false","presnivs","false") 

                CALL xios_add_child(cg2_hdl, child,"ASYVISIR_"//TRIM(mrfname(la)) )
                CALL xios_set_attr(child,name="asyvisir"//TRIM(mrfname_xml(la)),long_name="Asymmetry parameter band2  "//TRIM(mrfname_long(la)))
                CALL write_xml_info("ASYVISIR_"//TRIM(mrfname(la)),"asyvisir"//TRIM(mrfname_xml(la)),"Asymmetry parameter band2  "//TRIM(mrfname_long(la)),"false","presnivs","false") 


                CALL xios_add_child(swtoaas_hdl, child, "SWTOAAS_"//TRIM(mrfname(la)) ) 
                CALL write_xml_info("SWTOAAS_"//TRIM(mrfname(la)),"SWTOAAS_"//TRIM(mrfname(la)),"false","false","false","false" ) 

                CALL xios_add_child(swtoacs_hdl, child, "SWTOACS_"//TRIM(mrfname(la)) ) 
                CALL write_xml_info("SWTOACS_"//TRIM(mrfname(la)),"SWTOACS_"//TRIM(mrfname(la)),"false","false","false","false" ) 

                CALL xios_add_child(swsrfas_hdl, child, "SWSRFAS_"//TRIM(mrfname(la)) ) 
                CALL write_xml_info("SWSRFAS_"//TRIM(mrfname(la)),"SWSRFAS_"//TRIM(mrfname(la)),"false","false","false","false" ) 

                CALL xios_add_child(swsrfcs_hdl, child, "SWSRFCS_"//TRIM(mrfname(la)) ) 
                CALL write_xml_info("SWSRFCS_"//TRIM(mrfname(la)),"SWSRFCS_"//TRIM(mrfname(la)),"false","false","false","false" ) 

                CALL xios_add_child(fswtoaas_hdl, child, "FSWTOAAS_"//TRIM(mrfname(la)) ) 
                CALL write_xml_info("FSWTOAAS_"//TRIM(mrfname(la)),"FSWTOAAS_"//TRIM(mrfname(la)),"false","false","false","false" ) 

                CALL xios_add_child(fswtoacs_hdl, child, "FSWTOACS_"//TRIM(mrfname(la)) ) 
                CALL write_xml_info("FSWTOACS_"//TRIM(mrfname(la)),"FSWTOACS_"//TRIM(mrfname(la)),"false","false","false","false" ) 

                CALL xios_add_child(fswsrfas_hdl, child, "FSWSRFAS_"//TRIM(mrfname(la)) ) 
                CALL write_xml_info("FSWSRFAS_"//TRIM(mrfname(la)),"FSWSRFAS_"//TRIM(mrfname(la)),"false","false","false","false" ) 

                CALL xios_add_child(fswsrfcs_hdl, child, "FSWSRFCS_"//TRIM(mrfname(la)) ) 
                CALL write_xml_info("FSWSRFCS_"//TRIM(mrfname(la)),"FSWSRFCS_"//TRIM(mrfname(la)),"false","false","false","false" ) 


             ENDDO
          ENDIF
          
          IF (CoupSurfAtm) THEN    !!! couplage avec orchidee 

             ! declaration des emissions provenant du fichier non vegetales dans le cas d'un couplage avec Orchidee
             ! on traite differemment le cas des nombres ASN, AIN, SSN, CSN, CIN
             DO i=1,nb_flux
                length = len_trim(field_emi_names(i))
                tmp_name = field_emi_names(i)
                 CALL xios_add_child(emiNoBio_hdl,child,"EmiNoBio_"//TRIM(tmp_name(5:length)))
                 CALL xios_set_attr(child,name="emiNoBio"//TRIM(tmp_name(5:length)), unit="kg m-2 s-1", long_name="Total Emission Rate of "//TRIM(TRIM(tmp_name(5:length))),enabled=.TRUE.)
                 CALL write_xml_info("EmiNoBio_"//TRIM(tmp_name(5:length)), "emiNoBio_"//TRIM(tmp_name(5:length)),"Total Emission Rate of "//TRIM(TRIM(tmp_name(5:length))),"kg m-2 s-1","false",".TRUE.")
             ENDDO

             DO i=1,nb_flux
                length = len_trim(field_emi_names(i))
                tmp_name = field_emi_names(i)
                CALL xios_add_child(emiNoBio_hdl,child,"EmiBio_"//TRIM(tmp_name(5:length)))
                CALL xios_set_attr(child,name="emiBio"//TRIM(tmp_name(5:length)), unit="kg m-2 s-1", long_name="Total Emission Rate of "//TRIM(TRIM(tmp_name(5:length))),enabled=.TRUE.)
                CALL write_xml_info("EmiBio_"//TRIM(tmp_name(5:length)), "emiBio_"//TRIM(tmp_name(5:length)),"Total Emission Rate of "//TRIM(TRIM(tmp_name(5:length))),"kg m-2 s-1","false",".TRUE.")
             ENDDO

             DO i=1,nb_flux
                CALL xios_set_field_attr("EmiNoBio_"//TRIM(tmp_name(5:length)), enabled=.TRUE.) 
                CALL xios_set_field_attr("EmiBio_"//TRIM(tmp_name(5:length)), enabled=.TRUE.) 
                CALL xios_set_field_attr(field_emi_names(i),enabled=.TRUE.)
                CALL xios_set_field_attr('tot'//field_emi_names(i),enabled=.TRUE.)
             ENDDO
          ENDIF

       ENDIF! IF(use_group)THEN




       !
       !! 6. Close context
       !
       CALL xios_close_context_definition()      


       ! on interroge xios pour connaitre les dimensions de la grille vents 320x160 sur 
       ! sur chaque proc mpi 
!
       IF (.not. LMDZ_10m_winds) THEN 
          call xios_get_domain_attr("wind_file", ni=ni_winds, nj=nj_winds) 
          call xios_get_axis_attr("wind_time", n_glo=ntime_winds)
       endif

       call xios_get_axis_attr("chemLR_time", n_glo=ntime_chemLR) 
       call xios_get_axis_attr("npp_time", n_glo=ntime_npp) 
       call xios_get_axis_attr("landuse_type", n_glo=ntype_landuse) 
!
       call xios_get_axis_attr("oxyd_time", n_glo=ntime_oxyd) 
       call xios_get_axis_attr("oxyd_presnivs", n_glo=presnivs_oxyd) 
       CALL xios_get_domain_attr("oxyd_dom", ni= ni_oxyd, nj= nj_oxyd) 

       CALL xios_get_axis_attr("time_co2_h", n_glo=ntime_co2h)


!$OMP END MASTER

       IF (.not. LMDZ_10m_winds) THEN 
          CALL bcast_omp(ni_winds)
          CALL bcast_omp(nj_winds)
          CALL bcast_omp(ntime_winds)
       endif
       CALL bcast_omp(ntime_chemLR) 
       CALL bcast_omp(ntime_npp)
       CALL bcast_omp(ntype_landuse)
       CALL bcast_omp(ntime_oxyd)
       CALL bcast_omp(presnivs_oxyd)
       CALL bcast_omp(ni_oxyd)
       CALL bcast_omp(nj_oxyd)
       CALL bcast_omp(ntime_co2h)




  END SUBROUTINE xios_inca_init


  ! ======================================================================
  ! SUBROUTINE   : xios_inca_change_context
  !
  !        Use this subroutine to switch between different context.
  !               This subroutine must be called when running in 
  !               coupled mode at each time INCA is called, in the
  !               begining and end of intersurf_gathered. First call 
  !               is done after xios_inca_init is done. 
  !
  !                  
  !
  ! ======================================================================
  SUBROUTINE xios_inca_change_context(new_context)
    !
    !! 0. Variable and parameter declaration
    !
    !!    Input variable
    CHARACTER(LEN=*),INTENT(IN)              :: new_context

    !! Local variables
    TYPE(xios_context) :: ctx_hdl

!$OMP MASTER
       CALL xios_get_handle(new_context,ctx_hdl)
       CALL xios_set_current_context(ctx_hdl)
!$OMP END MASTER


  END SUBROUTINE xios_inca_change_context

  ! ====================================================================
  ! SUBROUTINE   : xios_inca_update_calendar
  !
  !          Update the calandar in 1.
  !
  ! DESCRIPTION  : Update the calendar in 1 : let 1 know that INCA
  !                avanced one time-step. This subroutine should be called 
  !                in the beginning of each time-step. The first 
  !                time-step in a new execution should always start at 1. 
  !                Therefore, first calculate an offset that is substracted 
  !                to the current time step in sechiba. 
  !
  ! 
  ! ====================================================================
  SUBROUTINE xios_inca_update_calendar(itau)
    !
    !! 0. Variable and parameter declaration
    !
    !! 0.1 Input variables
    !
    INTEGER, INTENT(IN) :: itau    !! Current time step of the model
    !

    !_ ==================================================================

!$OMP MASTER
       CALL xios_update_calendar(itau)
!$OMP END MASTER


  END SUBROUTINE xios_inca_update_calendar


  ! =====================================================================
  ! SUBROUTINE   : xios_inca_context_finalize
  !
  !         Finalize inca context.
  !
  ! DESCRIPTION  : This subroutine finalizes the inca context without 
  !                finalizing 1. In coupled mode, the atmospheric
  !                modele must finalize 1. This subroutine is 
  !                called in the end of the execution of INCA only in 
  !                coupeld mode.
  !                  
  !
  ! ======================================================================
  SUBROUTINE xios_inca_context_finalize

!$OMP MASTER
       CALL xios_context_finalize()
!$OMP END MASTER


  END SUBROUTINE xios_inca_context_finalize




  ! ======================================================================
  ! SUBROUTINE   : xios_inca_send_field_r0d
  !
  !          Subroutine for sending 1D (array) fields to 1.
  !
  ! DESCRIPTION  : Send one field to 1. This is the interface for 1D fields (array).
  !                NB! This subroutine should not be called directly.
  !                Use interface xios_inca_send_field.
  !
  ! =====================================================================
  SUBROUTINE xios_inca_send_field_r0d(field_id,field)
    !
    !! 0. Variable and parameter declaration
    !
    !! 0.1 Input variables
    !
    CHARACTER(len=*), INTENT(IN)          :: field_id
    REAL, INTENT(IN) :: field

       ! All master threads send the field to 1
!$OMP MASTER
       CALL xios_send_field(field_id,field)
!$OMP END MASTER


  END SUBROUTINE xios_inca_send_field_r0d

  ! ======================================================================
  ! SUBROUTINE   : xios_inca_send_field_r1d
  !
  !          Subroutine for sending 2D (array) fields to 1.
  !
  ! DESCRIPTION  : Send one field to 1. This is the interface for 2D fields (array).
  !                NB! This subroutine should not be called directly.
  !                Use interface xios_inca_send_field.
  !                We modify the action in fonction of the array size. 
  !                with the size(field) we will determinate if we need to 
  !                transform this field on 2d grid or not. 
  !
  ! =====================================================================
  SUBROUTINE xios_inca_send_field_r1d(field_id,field)
    USE INCA_DIM
    IMPLICIT NONE
    !
    !! 0. Variable and parameter declaration
    !
    !! 0.1 Input variables
    !
    CHARACTER(len=*), INTENT(IN)          :: field_id
    REAL, DIMENSION(:), INTENT(IN) :: field

    !! 0.2 Local variables
    REAL, DIMENSION(nbp_mpi) :: field_mpi
    REAL, DIMENSION(iim_glo,jj_nb)    :: field2d_mpi


       IF (SIZE(field) .EQ. PLON) THEN 
          ! Gather all omp domains on the mpi domains
          CALL gather_omp(field, field_mpi)

          ! All master threads send the field to 1
!$OMP MASTER
          CALL grid1dTo2d_mpi(field_mpi,field2d_mpi) 
          CALL xios_send_field(field_id,field2d_mpi)
!$OMP END MASTER

       ELSEIF ((SIZE(field) .EQ. PLEV) .or. (SIZE(field) .EQ. PLEV+1)) THEN 

!$OMP MASTER
          CALL xios_send_field(field_id,field)
!$OMP END MASTER
          
       ELSE IF (SIZE(field) .EQ. PLON_MPI) THEN ! Cas d'un appel purement mpi 

          ! Gather all omp domains on the mpi domains
          CALL grid1dTo2d_mpi(field,field2d_mpi) 
          CALL xios_send_field(field_id,field2d_mpi)

       ELSE ! le cas n'est pas prévu 


          WRITE(lunout,*)  field_id, "xios_send_field r1d cas non prevu "
          WRITE(lunout,*)  "size ", field_id, " = ", size(field) , " different de ", PLON, PLEV, PLEV+1 , PLON_MPI

          STOP "see inca output "

       ENDIF


     END SUBROUTINE xios_inca_send_field_r1d



  ! ==========================================================================
  ! SUBROUTINE   : xios_inca_send_field_r2d
  !
  !          Subroutine for sending 2D fields to 1.
  !
  ! DESCRIPTION  : Send one field to 1. This is the interface for INCA 2D fields.
  !                NB! This subroutine should not be called directly. 
  !                Use interface xios_inca_send_field.
  !                with the size(field,1) we will determinate if we need to 
  !                transform this field on 2d grid or not. 
  !
  ! ==========================================================================
  SUBROUTINE xios_inca_send_field_r2d(field_id,field)
    USE PRINT_INCA
    !
    !! 0. Variable and parameter declaration
    !
    !! 0.1 Input variables
    !
    CHARACTER(len=*), INTENT(IN)     :: field_id
    REAL, DIMENSION(:,:), INTENT(IN) :: field

    !! 0.2 Local variables
    REAL, DIMENSION(nbp_mpi,SIZE(field,2)) :: field_mpi
    REAL, DIMENSION(iim_glo,jj_nb,SIZE(field,2))    :: field2d_mpi


    IF (SIZE(field, 1) .EQ. PLON) THEN 

       ! Gather all omp domains on the mpi domains
       CALL gather_omp(field, field_mpi)
       ! All master threads send the field to 1
!$OMP MASTER
       CALL grid1dTo2d_mpi(field_mpi,field2d_mpi) 
       CALL xios_send_field(field_id,field2d_mpi)
!$OMP END MASTER

    ELSE

!$OMP MASTER
       CALL xios_send_field(field_id, field) 
!$OMP END MASTER


    ENDIF


  END SUBROUTINE xios_inca_send_field_r2d



  SUBROUTINE xios_inca_recv_field_r0d(field_id,field)
    USE PRINT_INCA
    !
    !! 0. Variable and parameter declaration
    !
    !! 0.1 Input variables
    !
    CHARACTER(len=*), INTENT(IN)              :: field_id
    
    !! 0.2 Output variables
    REAL, INTENT(OUT)  :: field

    !_ ================================================================================================================================


!$OMP MASTER
         CALL xios_recv_field(field_id,field)
!$OMP END MASTER
         call bcast_omp(field)


  END SUBROUTINE xios_inca_recv_field_r0d




  SUBROUTINE xios_inca_recv_field_r1d(field_id,field)
    USE PRINT_INCA
    !
    !! 0. Variable and parameter declaration
    !
    !! 0.1 Input variables
    !
    CHARACTER(len=*), INTENT(IN)              :: field_id
    
    !! 0.2 Output variables
    REAL, DIMENSION(:), INTENT(OUT)  :: field
    REAL, DIMENSION(iim_glo,jj_nb)    :: field2d_mpi
    REAL, DIMENSION(PLON_MPI) :: field_mpi

    !_ ================================================================================================================================

       ! All master threads recieve the field from 1
    IF (size(field) .eq. PLON) THEN  ! cas MPI_OMP


!$OMP MASTER
         CALL xios_recv_field(field_id,field2d_mpi)
         CALL grid2dTo1d_mpi(field2d_mpi, field_mpi)
!$OMP END MASTER
         call scatter_omp(field_mpi, field) 

      ELSE

         WRITE(lunout,*) field_id, 'Entering xios_inca_recv_field_r1d cas non prevu size =  ', size(field), ' PLON = ', PLON
         stop "exit see inca_output " 

      ENDIF

  END SUBROUTINE xios_inca_recv_field_r1d




  SUBROUTINE xios_inca_recv_field_r2d(field_id,field)
    !
    !! 0. Variable and parameter declaration
    !
    !! 0.1 Input variables
    !
    CHARACTER(len=*), INTENT(IN)              :: field_id
    
    !! 0.2 Output variables
    REAL, DIMENSION(:,:), INTENT(OUT)  :: field
    REAL, DIMENSION(iim_glo,jj_nb,SIZE(field,2))    :: field2d_mpi
    REAL, DIMENSION(PLON_MPI,SIZE(field,2))    :: field_mpi
    

    !_ ================================================================================================================================
    if (size(field,1) .eq. PLON) THEN 
       ! on va recevoir un champ en lon,lat et le transformer sur la grille 1d
!$OMP MASTER
       CALL xios_recv_field(field_id,field2d_mpi)
       CALL grid2dTo1d_mpi(field2d_mpi, field_mpi)
!$OMP END MASTER
       call scatter_omp(field_mpi, field) 
       
    ELSE 


       WRITE(lunout,*) field_id, 'cas non prevu xios_inca_recv_field_r2d, size = ',size(field,1), " PLON = ", PLON
       STOP "see inca output "


    ENDIF


  END SUBROUTINE xios_inca_recv_field_r2d

  SUBROUTINE xios_inca_recv_field_r3d(field_id,field)
    !
    !! 0. Variable and parameter declaration
    !
    !! 0.1 Input variables
    !
    CHARACTER(len=*), INTENT(IN)              :: field_id
    
    !! 0.2 Output variables
    REAL, DIMENSION(:,:,:), INTENT(OUT)  :: field
    REAL, DIMENSION(iim_glo,jj_nb,SIZE(field,2), size(field,3))    :: field3d_mpi
    REAL, DIMENSION(PLON_MPI,SIZE(field,2), size(field,3) )   :: field_mpi


    !_ ================================================================================================================================


       ! All master threads recieve the field from 1
    if (size(field,1) .eq. PLON) then 

       ! on va recevoir un champ en lon,lat et le transformer sur la grille 1d
!$OMP MASTER
       CALL xios_recv_field(field_id,field3d_mpi)
       CALL grid2dTo1d_mpi(field3d_mpi, field_mpi)
!$OMP END MASTER
       call scatter_omp(field_mpi, field) 

    else 

       WRITE(lunout,*) field_id, 'cas non prevu xios_inca_recv_field_r3d, size = ',size(field,1), " PLON = ", PLON
         STOP "see inca output "


    endif

  END SUBROUTINE xios_inca_recv_field_r3d



  SUBROUTINE xios_inca_recv_field_mpi_r1d(field_id,field)
    USE PRINT_INCA
    !
    !! 0. Variable and parameter declaration
    !
    !! 0.1 Input variables
    !
    CHARACTER(len=*), INTENT(IN)              :: field_id
    
    !! 0.2 Output variables
    REAL, DIMENSION(:), INTENT(OUT)  :: field
    REAL, DIMENSION(iim_glo,jj_nb)    :: field2d_mpi
    REAL, DIMENSION(PLON_MPI) :: field_mpi

    !_ ================================================================================================================================
    WRITE(lunout,*) 'Entering xios_inca_recv_field_mpi_r1d, field_id=',field_id

       ! All master threads recieve the field from 1
      IF (SIZE(field) .EQ. PLON_MPI) THEN  ! cas purement MPI 

         WRITE(lunout,*) 'Entering xios_inca_recv_field_r1d cas PLON_MPI'


         CALL xios_recv_field(field_id,field2d_mpi)
         CALL grid2dTo1d_mpi(field2d_mpi, field)

      ELSE
         
         WRITE(lunout,*)  field_id, " xios_inca_recv_field_mpi_r1d size", size(field), " is not PLON_MPI ", PLON_MPI
         STOP "see inca output "

      ENDIF

    END SUBROUTINE xios_inca_recv_field_mpi_r1d






  SUBROUTINE xios_inca_recv_field_glo_r1d(field_id,field)

    USE PRINT_INCA
    !
    !! 0. Variable and parameter declaration
    !
    !! 0.1 Input variables
    !
    CHARACTER(len=*), INTENT(IN)              :: field_id
    
    !! 0.2 Output variables
    REAL, DIMENSION(:), INTENT(OUT)  :: field


!$OMP MASTER
    CALL xios_recv_field(field_id,field)
!$OMP END MASTER
    CALL bcast_omp(field) 

  END SUBROUTINE xios_inca_recv_field_glo_r1d



  SUBROUTINE xios_inca_recv_field_glo_r2d(field_id,field)

    USE PRINT_INCA
    !
    !! 0. Variable and parameter declaration
    !
    !! 0.1 Input variables
    !
    CHARACTER(len=*), INTENT(IN)     :: field_id
    
    !! 0.2 Output variables
    REAL, DIMENSION(:,:), INTENT(OUT)  :: field


!$OMP MASTER
    CALL xios_recv_field(field_id,field)
!$OMP END MASTER
    CALL bcast_omp(field) 

  END SUBROUTINE xios_inca_recv_field_glo_r2d





  SUBROUTINE xios_inca_recv_field_glo_r3d(field_id,field)

    USE PRINT_INCA
    !
    !! 0. Variable and parameter declaration
    !
    !! 0.1 Input variables
    !
    CHARACTER(len=*), INTENT(IN)     :: field_id
    
    !! 0.2 Output variables
    REAL, DIMENSION(:,:,:), INTENT(OUT)  :: field



!$OMP MASTER
    CALL xios_recv_field(field_id,field)
!$OMP END MASTER
    CALL bcast_omp(field) 

  END SUBROUTINE xios_inca_recv_field_glo_r3d





  SUBROUTINE write_xml_info(str1, str2, str3, str4, str5, str6) 
    CHARACTER(LEN=*) , INTENT(in):: str1,str2,str3, str4, str5, str6
    CHARACTER(LEN=200) :: str3_out,str4_out,str5_out, str6_out

!$OMP MASTER
    IF (is_mpi_root) THEN
!       WRITE(outxml,*)  "ID = ", str1," / name = ", str2,"
    IF(str3=='false') THEN
    str3_out='  '
    ELSE
    str3_out='      long_name="'//TRIM(str3)//'"  '
    ENDIF

    IF(str4=='false') THEN
    str4_out='  '
    ELSE
    str4_out='      unit="'//TRIM(str4)//'"  '
    ENDIF

    IF(str5=='false') THEN
    str5_out='  '
    ELSE
    str5_out='      axis_ref="'//TRIM(str5)//'"  '
    ENDIF

    IF(str6=='false') THEN
    str6_out='  '
    ELSE
    str6_out='      enabled="'//TRIM(str6)//'"  '
    ENDIF

      WRITE(outxml,"(4x,a,a,a,a,a,a,a,/)", advance="no")  '<field id="'//TRIM(str1)//TRIM('"'),'      name="'//TRIM(str2)//TRIM('"'),TRIM(str3_out),TRIM(str4_out),TRIM(str5_out),TRIM(str6_out),TRIM('/>')

    ENDIF
!$OMP END MASTER

  END SUBROUTINE write_xml_info

END MODULE xios_inca