source: CONFIG/UNIFORM/v7/ICOLMDZOR_v7/SOURCES/DYNAMICO/trunk/icosa_init.f90 @ 6362

MODULE icosa_init_mod
  
  IMPLICIT NONE
  PRIVATE

  PUBLIC :: icosa_init
  
CONTAINS
  
  SUBROUTINE icosa_init
    USE profiling_mod,        ONLY : init_profiling
    USE mpipara,              ONLY : is_mpi_master, is_mpi_root, mpi_rank, init_mpipara, finalize_mpipara
    USE signature_mod,        ONLY : print_signature
    USE trace,                ONLY : trace_off, init_trace
    USE xios_mod,             ONLY : xios_init
    USE geometry,             ONLY : geom
    USE earth_const,          ONLY : init_earth_const
    USE grid_param    ,       ONLY : grid_type, grid_ico
    USE init_grid_param_mod,  ONLY : init_grid_param
    USE omp_para,             ONLY : init_omp_para, switch_omp_no_distrib_level
    USE metric,               ONLY : init_metric
    USE domain_mod,           ONLY : compute_domain
    USE transfert_mod,        ONLY : init_transfert
    USE write_field_mod,      ONLY : init_writefield, writefield, close_files
    USE trace,                ONLY : init_trace
    USE read_metric_mod,      ONLY : read_metric
    USE sponge_mod,           ONLY : pre_init_sponge
    USE geometry,             ONLY : compute_geometry
    USE disvert_mod,          ONLY : init_disvert, write_apbp
    USE vertical_interp_mod,  ONLY : init_vertical_interp
    USE tracer_icosa_mod,     ONLY : init_tracer
    USE time_mod,             ONLY : init_time, close_time_counter
    USE restart_mod,          ONLY : init_restart
    USE etat0_mod,            ONLY : init_etat0
    USE output_field_mod,     ONLY : output_field_init, output_field_finalize
    USE timeloop_gcm_mod,     ONLY : init_timeloop, timeloop
    USE physics_mod,          ONLY : init_physics, zero_du_phys
    USE diagflux_mod,         ONLY : init_diagflux
    USE guided_mod,           ONLY : pre_init_guided
    
    CALL init_profiling
    CALL init_mpipara
    IF(is_mpi_master) CALL print_signature
    CALL trace_off
    CALL xios_init
    CALL init_earth_const 
    CALL init_grid_param(is_mpi_master, mpi_rank) ! sets max_primal_deg, etc.
    CALL init_omp_para(is_mpi_master)
    IF(grid_type == grid_ico) CALL init_metric
    CALL compute_domain ! allocates domain_glo(ndomain_glo), domain(ndomain)
    CALL init_transfert
    
    CALL init_writefield
    CALL init_trace
    
    !$OMP PARALLEL  
    CALL switch_omp_no_distrib_level

    IF(grid_type == grid_ico) CALL read_metric
    CALL compute_geometry
    
    IF(grid_type == grid_ico) CALL check_total_area
    
    CALL init_disvert 
    CALL init_vertical_interp
    CALL init_tracer
    
    CALL WriteField("Ai",geom%Ai)
    
    IF (is_mpi_root) CALL write_apbp
    CALL init_time
    CALL init_etat0
    CALL init_restart
    CALL pre_init_sponge
    CALL pre_init_guided ! must be done before closing xios context, i.e. before output_field_init
    CALL output_field_init
    CALL init_timeloop
    
    !$OMP END PARALLEL
    
    CALL init_physics
    
    !$OMP PARALLEL
    
    CALL init_diagflux
    CALL zero_du_phys
    
    CALL timeloop
    
    CALL switch_omp_no_distrib_level
    !$OMP END PARALLEL
    
    CALL output_field_finalize
    CALL close_files
    CALL close_time_counter
    CALL finalize_mpipara
    
  END SUBROUTINE icosa_init
  
  SUBROUTINE check_total_area
    USE prec,       ONLY : rstd
    USE domain_mod, ONLY : ndomain, domain
    USE geometry,   ONLY : swap_geometry, Ai, ne
    USE mpipara,    ONLY : is_mpi_root
    USE dimensions
    USE field_mod
    USE domain_param
    USE omp_para
    USE icosa
    
    TYPE(t_field), POINTER, SAVE :: sum_ne(:)
    REAL(rstd), POINTER          :: pt_sum_ne(:)
    INTEGER :: ind,i,j,k,n 
    REAL(rstd) :: tot_sum=0
    
    CALL allocate_field(sum_ne,field_T,type_real)
    
    !$OMP BARRIER
    !$OMP MASTER
    DO ind=1,ndomain
       
       pt_sum_ne=sum_ne(ind)
       
       CALL swap_dimensions(ind)
       CALL swap_geometry(ind)
       
       DO j=jj_begin,jj_end
          DO i=ii_begin,ii_end
             n=(j-1)*iim+i
             pt_sum_ne(n)=0
             DO k=1,6
                pt_sum_ne(n)=pt_sum_ne(n)+ne(n,k)
             ENDDO
             IF (domain(ind)%own(i,j)) tot_sum=tot_sum+Ai(n)
          ENDDO
       ENDDO
    ENDDO
    
    IF (is_mpi_root) PRINT *," Diff surf",1-tot_sum/(4*Pi*radius*radius)
    !$OMP END MASTER
    
  END SUBROUTINE check_total_area
  
END MODULE icosa_init_mod