Context Navigation

source: CONFIG/UNIFORM/v6/NEMO_v6.5/SOURCES/restart.F90 @ 6230

Last change on this file since 6230 was 6230, checked in by cetlod, 2 years ago
NEMOv6.5 : Improvment of ORCA2 PISCES run offline when using IPSL-CM5 outputs ocean dynamic
File size: 16.2 KB

Line
1	MODULE restart
2	!!======================================================================
3	!! * MODULE restart *
4	!! Ocean restart : write the ocean restart file
5	!!======================================================================
6	!! History : OPA ! 1999-11 (M. Imbard) Original code
7	!! NEMO 1.0 ! 2002-08 (G. Madec) F90: Free form
8	!! 2.0 ! 2006-07 (S. Masson) use IOM for restart
9	!! 3.3 ! 2010-04 (M. Leclair, G. Madec) modified LF-RA
10	!! - - ! 2010-10 (C. Ethe, G. Madec) TRC-TRA merge (T-S in 4D)
11	!! 3.7 ! 2014-01 (G. Madec) suppression of curl and hdiv from the restart
12	!! - ! 2014-12 (G. Madec) remove KPP scheme
13	!!----------------------------------------------------------------------
14
15	!!----------------------------------------------------------------------
16	!! rst_opn : open the ocean restart file
17	!! rst_write : write the ocean restart file
18	!! rst_read : read the ocean restart file
19	!!----------------------------------------------------------------------
20	USE oce ! ocean dynamics and tracers
21	USE dom_oce ! ocean space and time domain
22	USE sbc_ice ! only lk_si3
23	USE phycst ! physical constants
24	USE eosbn2 ! equation of state (eos bn2 routine)
25	USE trdmxl_oce ! ocean active mixed layer tracers trends variables
26	!
27	USE in_out_manager ! I/O manager
28	USE iom ! I/O module
29	USE diurnal_bulk
30	USE lib_mpp ! distribued memory computing library
31
32	IMPLICIT NONE
33	PRIVATE
34
35	PUBLIC rst_opn ! routine called by step module
36	PUBLIC rst_write ! routine called by step module
37	PUBLIC rst_read ! routine called by istate module
38	PUBLIC rst_read_open ! routine called in rst_read and (possibly) in dom_vvl_init
39
40	!! * Substitutions
41	# include "vectopt_loop_substitute.h90"
42	!!----------------------------------------------------------------------
43	!! NEMO/OCE 4.0 , NEMO Consortium (2018)
44	!! $Id: restart.F90 15596 2021-12-13 16:28:47Z acc $
45	!! Software governed by the CeCILL license (see ./LICENSE)
46	!!----------------------------------------------------------------------
47	CONTAINS
48
49	SUBROUTINE rst_opn( kt )
50	!!---------------------------------------------------------------------
51	!! * ROUTINE rst_opn *
52	!!
53	!! ** Purpose : + initialization (should be read in the namelist) of nitrst
54	!! + open the restart when we are one time step before nitrst
55	!! - restart header is defined when kt = nitrst-1
56	!! - restart data are written when kt = nitrst
57	!! + define lrst_oce to .TRUE. when we need to define or write the restart
58	!!----------------------------------------------------------------------
59	INTEGER, INTENT(in) :: kt ! ocean time-step
60	!!
61	CHARACTER(LEN=20) :: clkt ! ocean time-step deine as a character
62	CHARACTER(LEN=50) :: clname ! ocean output restart file name
63	CHARACTER(lc) :: clpath ! full path to ocean output restart file
64	CHARACTER(LEN=52) :: clpname ! ocean output restart file name including prefix for AGRIF
65	CHARACTER(LEN=256) :: clinfo ! info character
66	!!----------------------------------------------------------------------
67	!
68	IF( kt == nit000 ) THEN ! default definitions
69	lrst_oce = .FALSE.
70	IF( ln_rst_list ) THEN
71	nrst_lst = 1
72	nitrst = nn_stocklist( nrst_lst )
73	ELSE
74	nitrst = nitend
75	ENDIF
76	ENDIF
77
78	IF( .NOT. ln_rst_list .AND. nn_stock == -1 ) RETURN ! we will never do any restart
79
80	! frequency-based restart dumping (nn_stock)
81	IF( .NOT. ln_rst_list .AND. MOD( kt - 1, nn_stock ) == 0 ) THEN
82	! we use kt - 1 and not kt - nit000 to keep the same periodicity from the beginning of the experiment
83	nitrst = kt + nn_stock - 1 ! define the next value of nitrst for restart writing
84	IF( nitrst > nitend ) nitrst = nitend ! make sure we write a restart at the end of the run
85	ENDIF
86	! to get better performances with NetCDF format:
87	! we open and define the ocean restart file one time step before writing the data (-> at nitrst - 1)
88	! except if we write ocean restart files every time step or if an ocean restart file was writen at nitend - 1
89	! or if nit000 is requested in the nn_stocklist
90	IF( kt == nitrst - 1 .OR. nn_stock == 1 .OR. ( kt == nitend .AND. .NOT. lrst_oce ) &
91	& .OR. ( kt == nit000 .AND. nitrst == nit000 ) ) THEN
92	IF( nitrst <= nitend .AND. nitrst > 0 ) THEN
93	! beware of the format used to write kt (default is i8.8, that should be large enough...)
94	IF( nitrst > 999999999 ) THEN ; WRITE(clkt, * ) nitrst
95	ELSE ; WRITE(clkt, '(i8.8)') nitrst
96	ENDIF
97	! create the file
98	clname = TRIM(cexper)//"_"//TRIM(ADJUSTL(clkt))//"_"//TRIM(cn_ocerst_out)
99	clpath = TRIM(cn_ocerst_outdir)
100	IF( clpath(LEN_TRIM(clpath):) /= '/' ) clpath = TRIM(clpath) // '/'
101	IF(lwp) THEN
102	WRITE(numout,*)
103	IF(.NOT.lwxios) THEN
104	WRITE(numout,*) ' open ocean restart NetCDF file: ',TRIM(clpath)//TRIM(clname)
105	IF ( snc4set%luse ) WRITE(numout,*) ' opened for NetCDF4 chunking and compression'
106	IF( kt == nitrst - 1 ) THEN ; WRITE(numout,*) ' kt = nitrst - 1 = ', kt
107	ELSE ; WRITE(numout,*) ' kt = ' , kt
108	ENDIF
109	ENDIF
110	ENDIF
111	!
112	IF(.NOT.lwxios) THEN
113	CALL iom_open( TRIM(clpath)//TRIM(clname), numrow, ldwrt = .TRUE. )
114	ELSE
115	#if defined key_iomput
116	cwxios_context = "rstw_"//TRIM(ADJUSTL(clkt))
117	IF( TRIM(Agrif_CFixed()) == '0' ) THEN
118	clpname = clname
119	ELSE
120	clpname = TRIM(Agrif_CFixed())//"_"//clname
121	ENDIF
122	CALL iom_init( cwxios_context, TRIM(clpath)//TRIM(clpname), .false. )
123	CALL xios_update_calendar(nitrst)
124	CALL iom_swap( cxios_context )
125	#else
126	clinfo = 'Can not use XIOS in rst_opn'
127	CALL ctl_stop(TRIM(clinfo))
128	#endif
129	ENDIF
130	lrst_oce = .TRUE.
131	ENDIF
132	ENDIF
133	!
134	END SUBROUTINE rst_opn
135
136
137	SUBROUTINE rst_write( kt )
138	!!---------------------------------------------------------------------
139	!! * ROUTINE rstwrite *
140	!!
141	!! ** Purpose : Write restart fields in NetCDF format
142	!!
143	!! ** Method : Write in numrow when kt == nitrst in NetCDF
144	!! file, save fields which are necessary for restart
145	!!----------------------------------------------------------------------
146	INTEGER, INTENT(in) :: kt ! ocean time-step
147	!!----------------------------------------------------------------------
148	IF(lwxios) CALL iom_swap( cwxios_context )
149	CALL iom_rstput( kt, nitrst, numrow, 'rdt' , rdt , ldxios = lwxios) ! dynamics time step
150	CALL iom_delay_rst( 'WRITE', 'OCE', numrow ) ! save only ocean delayed global communication variables
151
152	IF ( .NOT. ln_diurnal_only ) THEN
153	CALL iom_rstput( kt, nitrst, numrow, 'ub' , ub, ldxios = lwxios ) ! before fields
154	CALL iom_rstput( kt, nitrst, numrow, 'vb' , vb, ldxios = lwxios )
155	CALL iom_rstput( kt, nitrst, numrow, 'tb' , tsb(:,:,:,jp_tem), ldxios = lwxios )
156	CALL iom_rstput( kt, nitrst, numrow, 'sb' , tsb(:,:,:,jp_sal), ldxios = lwxios )
157	CALL iom_rstput( kt, nitrst, numrow, 'sshb' , sshb, ldxios = lwxios )
158	!
159	CALL iom_rstput( kt, nitrst, numrow, 'un' , un, ldxios = lwxios ) ! now fields
160	CALL iom_rstput( kt, nitrst, numrow, 'vn' , vn, ldxios = lwxios )
161	CALL iom_rstput( kt, nitrst, numrow, 'tn' , tsn(:,:,:,jp_tem), ldxios = lwxios )
162	CALL iom_rstput( kt, nitrst, numrow, 'sn' , tsn(:,:,:,jp_sal), ldxios = lwxios )
163	CALL iom_rstput( kt, nitrst, numrow, 'sshn' , sshn, ldxios = lwxios )
164	CALL iom_rstput( kt, nitrst, numrow, 'rhop' , rhop, ldxios = lwxios )
165	! extra variable needed for the ice sheet coupling
166	IF ( ln_iscpl ) THEN
167	CALL iom_rstput( kt, nitrst, numrow, 'tmask' , tmask, ldxios = lwxios ) ! need to extrapolate T/S
168	CALL iom_rstput( kt, nitrst, numrow, 'umask' , umask, ldxios = lwxios ) ! need to correct barotropic velocity
169	CALL iom_rstput( kt, nitrst, numrow, 'vmask' , vmask, ldxios = lwxios ) ! need to correct barotropic velocity
170	CALL iom_rstput( kt, nitrst, numrow, 'smask' , ssmask, ldxios = lwxios) ! need to correct barotropic velocity
171	CALL iom_rstput( kt, nitrst, numrow, 'e3t_n', e3t_n(:,:,:), ldxios = lwxios ) ! need to compute temperature correction
172	CALL iom_rstput( kt, nitrst, numrow, 'e3u_n', e3u_n(:,:,:), ldxios = lwxios ) ! need to compute bt conservation
173	CALL iom_rstput( kt, nitrst, numrow, 'e3v_n', e3v_n(:,:,:), ldxios = lwxios ) ! need to compute bt conservation
174	CALL iom_rstput( kt, nitrst, numrow, 'gdepw_n', gdepw_n(:,:,:), ldxios = lwxios ) ! need to compute extrapolation if vvl
175	END IF
176	ENDIF
177
178	IF (ln_diurnal) CALL iom_rstput( kt, nitrst, numrow, 'Dsst', x_dsst, ldxios = lwxios )
179	IF(lwxios) CALL iom_swap( cxios_context )
180	IF( kt == nitrst ) THEN
181	IF(.NOT.lwxios) THEN
182	CALL iom_close( numrow ) ! close the restart file (only at last time step)
183	ELSE
184	CALL iom_context_finalize( cwxios_context )
185	ENDIF
186	!!gm IF( .NOT. lk_trdmld ) lrst_oce = .FALSE.
187	!!gm not sure what to do here ===>>> ask to Sebastian
188	lrst_oce = .FALSE.
189	IF( ln_rst_list ) THEN
190	nrst_lst = MIN(nrst_lst + 1, SIZE(nn_stocklist,1))
191	nitrst = nn_stocklist( nrst_lst )
192	IF( nitrst == 0 ) nitrst = nitend ! Force a restart at the end of the run
193	ENDIF
194	ENDIF
195	!
196	END SUBROUTINE rst_write
197
198
199	SUBROUTINE rst_read_open
200	!!----------------------------------------------------------------------
201	!! * ROUTINE rst_read_open *
202	!!
203	!! ** Purpose : Open read files for NetCDF restart
204	!!
205	!! ** Method : Use a non-zero, positive value of numror to assess whether or not
206	!! the file has already been opened
207	!!----------------------------------------------------------------------
208	LOGICAL :: llok
209	CHARACTER(lc) :: clpath ! full path to ocean output restart file
210	!!----------------------------------------------------------------------
211	!
212	IF( numror <= 0 ) THEN
213	IF(lwp) THEN ! Contol prints
214	WRITE(numout,*)
215	WRITE(numout,*) 'rst_read : read oce NetCDF restart file'
216	IF ( snc4set%luse ) WRITE(numout,*) 'rst_read : configured with NetCDF4 support'
217	WRITE(numout,*) '~~~~~~~~'
218	ENDIF
219	lxios_sini = .FALSE.
220	clpath = TRIM(cn_ocerst_indir)
221	IF( clpath(LEN_TRIM(clpath):) /= '/' ) clpath = TRIM(clpath) // '/'
222	CALL iom_open( TRIM(clpath)//cn_ocerst_in, numror )
223	! are we using XIOS to read the data? Part above will have to modified once XIOS
224	! can handle checking if variable is in the restart file (there will be no need to open
225	! restart)
226	IF(.NOT.lxios_set) lrxios = lrxios.AND.lxios_sini
227	IF( lrxios) THEN
228	crxios_context = 'nemo_rst'
229	IF( .NOT.lxios_set ) THEN
230	IF(lwp) WRITE(numout,*) 'Enable restart reading by XIOS'
231	CALL iom_init( crxios_context, ld_tmppatch = .false. )
232	lxios_set = .TRUE.
233	ENDIF
234	ENDIF
235	IF( TRIM(Agrif_CFixed()) /= '0' .AND. lrxios) THEN
236	CALL iom_init( crxios_context, ld_tmppatch = .false. )
237	IF(lwp) WRITE(numout,*) 'Enable restart reading by XIOS for AGRIF'
238	lxios_set = .TRUE.
239	ENDIF
240	ENDIF
241
242	END SUBROUTINE rst_read_open
243
244
245	SUBROUTINE rst_read
246	!!----------------------------------------------------------------------
247	!! * ROUTINE rst_read *
248	!!
249	!! ** Purpose : Read files for NetCDF restart
250	!!
251	!! ** Method : Read in restart.nc file fields which are necessary for restart
252	!!----------------------------------------------------------------------
253	REAL(wp) :: zrdt
254	INTEGER :: jk
255	REAL(wp), DIMENSION(jpi, jpj, jpk) :: w3d
256	!!----------------------------------------------------------------------
257
258	CALL rst_read_open ! open restart for reading (if not already opened)
259
260	! Check dynamics and tracer time-step consistency and force Euler restart if changed
261	IF( iom_varid( numror, 'rdt', ldstop = .FALSE. ) > 0 ) THEN
262	CALL iom_get( numror, 'rdt', zrdt, ldxios = lrxios )
263	IF( zrdt /= rdt ) neuler = 0
264	ENDIF
265
266	CALL iom_delay_rst( 'READ', 'OCE', numror ) ! read only ocean delayed global communication variables
267
268	! Diurnal DSST
269	IF( ln_diurnal ) CALL iom_get( numror, jpdom_autoglo, 'Dsst' , x_dsst, ldxios = lrxios )
270	IF ( ln_diurnal_only ) THEN
271	IF(lwp) WRITE( numout, * ) &
272	& "rst_read:- ln_diurnal_only set, setting rhop=rau0"
273	rhop = rau0
274	CALL iom_get( numror, jpdom_autoglo, 'tn' , w3d, ldxios = lrxios )
275	tsn(:,:,1,jp_tem) = w3d(:,:,1)
276	RETURN
277	ENDIF
278
279	IF( iom_varid( numror, 'ub', ldstop = .FALSE. ) > 0 ) THEN
280	CALL iom_get( numror, jpdom_autoglo, 'ub' , ub, ldxios = lrxios ) ! before fields
281	CALL iom_get( numror, jpdom_autoglo, 'vb' , vb, ldxios = lrxios )
282	CALL iom_get( numror, jpdom_autoglo, 'tb' , tsb(:,:,:,jp_tem), ldxios = lrxios )
283	CALL iom_get( numror, jpdom_autoglo, 'sb' , tsb(:,:,:,jp_sal), ldxios = lrxios )
284	CALL iom_get( numror, jpdom_autoglo, 'sshb' , sshb, ldxios = lrxios )
285	ELSE
286	neuler = 0
287	ENDIF
288	!
289	CALL iom_get( numror, jpdom_autoglo, 'un' , un, ldxios = lrxios ) ! now fields
290	CALL iom_get( numror, jpdom_autoglo, 'vn' , vn, ldxios = lrxios )
291	CALL iom_get( numror, jpdom_autoglo, 'tn' , tsn(:,:,:,jp_tem), ldxios = lrxios )
292	CALL iom_get( numror, jpdom_autoglo, 'sn' , tsn(:,:,:,jp_sal), ldxios = lrxios )
293	CALL iom_get( numror, jpdom_autoglo, 'sshn' , sshn, ldxios = lrxios )
294	IF( iom_varid( numror, 'rhop', ldstop = .FALSE. ) > 0 ) THEN
295	CALL iom_get( numror, jpdom_autoglo, 'rhop' , rhop, ldxios = lrxios ) ! now potential density
296	ELSE
297	CALL eos( tsn, rhd, rhop, gdept_n(:,:,:) )
298	ENDIF
299	!
300	IF( neuler == 0 ) THEN ! Euler restart (neuler=0)
301	tsb (:,:,:,:) = tsn (:,:,:,:) ! all before fields set to now values
302	ub (:,:,:) = un (:,:,:)
303	vb (:,:,:) = vn (:,:,:)
304	sshb (:,:) = sshn (:,:)
305	!
306	IF( .NOT.ln_linssh ) THEN
307	DO jk = 1, jpk
308	e3t_b(:,:,jk) = e3t_n(:,:,jk)
309	END DO
310	ENDIF
311	!
312	ENDIF
313	!
314	END SUBROUTINE rst_read
315
316	!!=====================================================================
317	END MODULE restart

Note: See TracBrowser for help on using the repository browser.

Download in other formats: