1 | MODULE traldf_iso_grif |
---|
2 | !!====================================================================== |
---|
3 | !! *** MODULE traldf_iso_grif *** |
---|
4 | !! Ocean tracers: horizontal component of the lateral tracer mixing trend |
---|
5 | !!====================================================================== |
---|
6 | !! History : 3.3 ! 2010-10 (G. Nurser, C. Harris, G. Madec) |
---|
7 | !! ! Griffies operator version adapted from traldf_iso.F90 |
---|
8 | !!---------------------------------------------------------------------- |
---|
9 | #if defined key_ldfslp || defined key_esopa |
---|
10 | !!---------------------------------------------------------------------- |
---|
11 | !! 'key_ldfslp' slope of the lateral diffusive direction |
---|
12 | !!---------------------------------------------------------------------- |
---|
13 | !! tra_ldf_iso_grif : update the tracer trend with the horizontal component |
---|
14 | !! of the Griffies iso-neutral laplacian operator |
---|
15 | !!---------------------------------------------------------------------- |
---|
16 | USE oce ! ocean dynamics and active tracers |
---|
17 | USE dom_oce ! ocean space and time domain |
---|
18 | USE phycst ! physical constants |
---|
19 | USE trc_oce ! share passive tracers/Ocean variables |
---|
20 | USE zdf_oce ! ocean vertical physics |
---|
21 | USE ldftra_oce ! ocean active tracers: lateral physics |
---|
22 | USE ldfslp ! iso-neutral slopes |
---|
23 | USE diaptr_oce ! poleward transport diagnostics |
---|
24 | USE in_out_manager ! I/O manager |
---|
25 | USE iom ! I/O library |
---|
26 | USE lbclnk ! ocean lateral boundary conditions (or mpp link) |
---|
27 | USE lib_mpp ! MPP library |
---|
28 | USE wrk_nemo ! Memory Allocation |
---|
29 | USE timing ! Timing |
---|
30 | |
---|
31 | |
---|
32 | IMPLICIT NONE |
---|
33 | PRIVATE |
---|
34 | |
---|
35 | PUBLIC tra_ldf_iso_grif ! routine called by traldf.F90 |
---|
36 | |
---|
37 | REAL(wp), PUBLIC, DIMENSION(:,:,:), ALLOCATABLE, SAVE :: psix_eiv, psiy_eiv !: eiv stream function (diag only) |
---|
38 | REAL(wp), PUBLIC, DIMENSION(:,:,:), ALLOCATABLE, SAVE :: ah_wslp2 !: aeiv*w-slope^2 |
---|
39 | REAL(wp), DIMENSION(:,:,:), ALLOCATABLE, SAVE :: zdkt3d !: vertical tracer gradient at 2 levels |
---|
40 | |
---|
41 | !! * Substitutions |
---|
42 | # include "domzgr_substitute.h90" |
---|
43 | # include "ldftra_substitute.h90" |
---|
44 | # include "vectopt_loop_substitute.h90" |
---|
45 | # include "ldfeiv_substitute.h90" |
---|
46 | !!---------------------------------------------------------------------- |
---|
47 | !! NEMO/OPA 3.3 , NEMO Consortium (2010) |
---|
48 | !! $Id: traldf_iso_grif.F90 3632 2012-11-22 15:28:42Z acc $ |
---|
49 | !! Software governed by the CeCILL licence (NEMOGCM/NEMO_CeCILL.txt) |
---|
50 | !!---------------------------------------------------------------------- |
---|
51 | CONTAINS |
---|
52 | |
---|
53 | SUBROUTINE tra_ldf_iso_grif( kt, kit000, cdtype, pgu, pgv, & |
---|
54 | & ptb, pta, kjpt, pahtb0 ) |
---|
55 | !!---------------------------------------------------------------------- |
---|
56 | !! *** ROUTINE tra_ldf_iso_grif *** |
---|
57 | !! |
---|
58 | !! ** Purpose : Compute the before horizontal tracer (t & s) diffusive |
---|
59 | !! trend for a laplacian tensor (ezxcept the dz[ dz[.] ] term) and |
---|
60 | !! add it to the general trend of tracer equation. |
---|
61 | !! |
---|
62 | !! ** Method : The horizontal component of the lateral diffusive trends |
---|
63 | !! is provided by a 2nd order operator rotated along neural or geopo- |
---|
64 | !! tential surfaces to which an eddy induced advection can be added |
---|
65 | !! It is computed using before fields (forward in time) and isopyc- |
---|
66 | !! nal or geopotential slopes computed in routine ldfslp. |
---|
67 | !! |
---|
68 | !! 1st part : masked horizontal derivative of T ( di[ t ] ) |
---|
69 | !! ======== with partial cell update if ln_zps=T. |
---|
70 | !! |
---|
71 | !! 2nd part : horizontal fluxes of the lateral mixing operator |
---|
72 | !! ======== |
---|
73 | !! zftu = (aht+ahtb0) e2u*e3u/e1u di[ tb ] |
---|
74 | !! - aht e2u*uslp dk[ mi(mk(tb)) ] |
---|
75 | !! zftv = (aht+ahtb0) e1v*e3v/e2v dj[ tb ] |
---|
76 | !! - aht e2u*vslp dk[ mj(mk(tb)) ] |
---|
77 | !! take the horizontal divergence of the fluxes: |
---|
78 | !! difft = 1/(e1t*e2t*e3t) { di-1[ zftu ] + dj-1[ zftv ] } |
---|
79 | !! Add this trend to the general trend (ta,sa): |
---|
80 | !! ta = ta + difft |
---|
81 | !! |
---|
82 | !! 3rd part: vertical trends of the lateral mixing operator |
---|
83 | !! ======== (excluding the vertical flux proportional to dk[t] ) |
---|
84 | !! vertical fluxes associated with the rotated lateral mixing: |
---|
85 | !! zftw =-aht { e2t*wslpi di[ mi(mk(tb)) ] |
---|
86 | !! + e1t*wslpj dj[ mj(mk(tb)) ] } |
---|
87 | !! take the horizontal divergence of the fluxes: |
---|
88 | !! difft = 1/(e1t*e2t*e3t) dk[ zftw ] |
---|
89 | !! Add this trend to the general trend (ta,sa): |
---|
90 | !! pta = pta + difft |
---|
91 | !! |
---|
92 | !! ** Action : Update pta arrays with the before rotated diffusion |
---|
93 | !!---------------------------------------------------------------------- |
---|
94 | USE oce , ONLY: zftu => ua , zftv => va ! (ua,va) used as 3D workspace |
---|
95 | ! |
---|
96 | INTEGER , INTENT(in ) :: kt ! ocean time-step index |
---|
97 | INTEGER , INTENT(in ) :: kit000 ! first time step index |
---|
98 | CHARACTER(len=3) , INTENT(in ) :: cdtype ! =TRA or TRC (tracer indicator) |
---|
99 | INTEGER , INTENT(in ) :: kjpt ! number of tracers |
---|
100 | REAL(wp), DIMENSION(jpi,jpj ,kjpt), INTENT(in ) :: pgu, pgv ! tracer gradient at pstep levels |
---|
101 | REAL(wp), DIMENSION(jpi,jpj,jpk,kjpt), INTENT(in ) :: ptb ! before and now tracer fields |
---|
102 | REAL(wp), DIMENSION(jpi,jpj,jpk,kjpt), INTENT(inout) :: pta ! tracer trend |
---|
103 | REAL(wp) , INTENT(in ) :: pahtb0 ! background diffusion coef |
---|
104 | ! |
---|
105 | INTEGER :: ji, jj, jk,jn ! dummy loop indices |
---|
106 | INTEGER :: ip,jp,kp ! dummy loop indices |
---|
107 | INTEGER :: ierr ! temporary integer |
---|
108 | REAL(wp) :: zmsku, zabe1, zcof1, zcoef3 ! local scalars |
---|
109 | REAL(wp) :: zmskv, zabe2, zcof2, zcoef4 ! - - |
---|
110 | REAL(wp) :: zcoef0, zbtr ! - - |
---|
111 | ! |
---|
112 | REAL(wp) :: zslope_skew, zslope_iso, zslope2, zbu, zbv |
---|
113 | REAL(wp) :: ze1ur, zdxt, ze2vr, ze3wr, zdyt, zdzt |
---|
114 | REAL(wp) :: zah, zah_slp, zaei_slp |
---|
115 | #if defined key_diaar5 |
---|
116 | REAL(wp) :: zztmp ! local scalar |
---|
117 | #endif |
---|
118 | REAL(wp), POINTER, DIMENSION(:,: ) :: z2d |
---|
119 | REAL(wp), POINTER, DIMENSION(:,:,:) :: zdit, zdjt, ztfw |
---|
120 | REAL(wp), POINTER, DIMENSION(:,:,:) :: zw3d ! 3D workspace |
---|
121 | !!---------------------------------------------------------------------- |
---|
122 | ! |
---|
123 | IF( nn_timing == 1 ) CALL timing_start('tra_ldf_iso_grif') |
---|
124 | ! |
---|
125 | CALL wrk_alloc( jpi, jpj, z2d ) |
---|
126 | CALL wrk_alloc( jpi, jpj, jpk, zdit, zdjt, ztfw ) |
---|
127 | ! |
---|
128 | |
---|
129 | IF( kt == kit000 .AND. .NOT.ALLOCATED(ah_wslp2) ) THEN |
---|
130 | IF(lwp) WRITE(numout,*) |
---|
131 | IF(lwp) WRITE(numout,*) 'tra_ldf_iso_grif : rotated laplacian diffusion operator on ', cdtype |
---|
132 | IF(lwp) WRITE(numout,*) '~~~~~~~~~~~' |
---|
133 | ALLOCATE( ah_wslp2(jpi,jpj,jpk) , zdkt3d(jpi,jpj,0:1), STAT=ierr ) |
---|
134 | IF( lk_mpp ) CALL mpp_sum ( ierr ) |
---|
135 | IF( ierr > 0 ) CALL ctl_stop('STOP', 'tra_ldf_iso_grif: unable to allocate arrays') |
---|
136 | IF( ln_traldf_gdia ) THEN |
---|
137 | IF (.NOT. ALLOCATED(psix_eiv))THEN |
---|
138 | ALLOCATE( psix_eiv(jpi,jpj,jpk) , psiy_eiv(jpi,jpj,jpk) , STAT=ierr ) |
---|
139 | IF( lk_mpp ) CALL mpp_sum ( ierr ) |
---|
140 | IF( ierr > 0 ) CALL ctl_stop('STOP', 'tra_ldf_iso_grif: unable to allocate diagnostics') |
---|
141 | ENDIF |
---|
142 | ENDIF |
---|
143 | ENDIF |
---|
144 | |
---|
145 | !!---------------------------------------------------------------------- |
---|
146 | !! 0 - calculate ah_wslp2, psix_eiv, psiy_eiv |
---|
147 | !!---------------------------------------------------------------------- |
---|
148 | |
---|
149 | !!gm Future development: consider using Ah defined at T-points and attached to the 4 t-point triads |
---|
150 | |
---|
151 | ah_wslp2(:,:,:) = 0._wp |
---|
152 | IF( ln_traldf_gdia ) THEN |
---|
153 | psix_eiv(:,:,:) = 0._wp |
---|
154 | psiy_eiv(:,:,:) = 0._wp |
---|
155 | ENDIF |
---|
156 | |
---|
157 | DO ip = 0, 1 |
---|
158 | DO kp = 0, 1 |
---|
159 | DO jk = 1, jpkm1 |
---|
160 | DO jj = 1, jpjm1 |
---|
161 | DO ji = 1, fs_jpim1 |
---|
162 | ze1ur = 1._wp / e1u(ji,jj) |
---|
163 | ze3wr = 1._wp / fse3w(ji+ip,jj,jk+kp) |
---|
164 | zbu = 0.25_wp * e1u(ji,jj) * e2u(ji,jj) * fse3u(ji,jj,jk) |
---|
165 | zah = fsahtu(ji,jj,jk) ! fsaht(ji+ip,jj,jk) |
---|
166 | zslope_skew = triadi_g(ji+ip,jj,jk,1-ip,kp) |
---|
167 | ! Subtract s-coordinate slope at t-points to give slope rel to s surfaces |
---|
168 | ! (do this by *adding* gradient of depth) |
---|
169 | zslope2 = zslope_skew + ( fsdept(ji+1,jj,jk) - fsdept(ji ,jj ,jk) ) * ze1ur * umask(ji,jj,jk+kp) |
---|
170 | zslope2 = zslope2 *zslope2 |
---|
171 | ah_wslp2(ji+ip,jj,jk+kp) = ah_wslp2(ji+ip,jj,jk+kp) & |
---|
172 | & + zah * ( zbu * ze3wr / ( e1t(ji+ip,jj) * e2t(ji+ip,jj) ) ) * zslope2 |
---|
173 | IF( ln_traldf_gdia ) THEN |
---|
174 | zaei_slp = fsaeiw(ji+ip,jj,jk) * zslope_skew ! fsaeit(ji+ip,jj,jk)*zslope_skew |
---|
175 | psix_eiv(ji,jj,jk+kp) = psix_eiv(ji,jj,jk+kp) + 0.25_wp * zaei_slp |
---|
176 | ENDIF |
---|
177 | END DO |
---|
178 | END DO |
---|
179 | END DO |
---|
180 | END DO |
---|
181 | END DO |
---|
182 | ! |
---|
183 | DO jp = 0, 1 |
---|
184 | DO kp = 0, 1 |
---|
185 | DO jk = 1, jpkm1 |
---|
186 | DO jj = 1, jpjm1 |
---|
187 | DO ji=1,fs_jpim1 |
---|
188 | ze2vr = 1._wp / e2v(ji,jj) |
---|
189 | ze3wr = 1.0_wp / fse3w(ji,jj+jp,jk+kp) |
---|
190 | zbv = 0.25_wp * e1v(ji,jj) * e2v(ji,jj) * fse3v(ji,jj,jk) |
---|
191 | zah = fsahtv(ji,jj,jk) ! fsaht(ji,jj+jp,jk) |
---|
192 | zslope_skew = triadj_g(ji,jj+jp,jk,1-jp,kp) |
---|
193 | ! Subtract s-coordinate slope at t-points to give slope rel to s surfaces |
---|
194 | ! (do this by *adding* gradient of depth) |
---|
195 | zslope2 = zslope_skew + ( fsdept(ji,jj+1,jk) - fsdept(ji,jj,jk) ) * ze2vr * vmask(ji,jj,jk+kp) |
---|
196 | zslope2 = zslope2 * zslope2 |
---|
197 | ah_wslp2(ji,jj+jp,jk+kp) = ah_wslp2(ji,jj+jp,jk+kp) & |
---|
198 | & + zah * ( zbv * ze3wr / ( e1t(ji,jj+jp) * e2t(ji,jj+jp) ) ) * zslope2 |
---|
199 | IF( ln_traldf_gdia ) THEN |
---|
200 | zaei_slp = fsaeiw(ji,jj+jp,jk) * zslope_skew ! fsaeit(ji,jj+jp,jk)*zslope_skew |
---|
201 | psiy_eiv(ji,jj,jk+kp) = psiy_eiv(ji,jj,jk+kp) + 0.25_wp * zaei_slp |
---|
202 | ENDIF |
---|
203 | END DO |
---|
204 | END DO |
---|
205 | END DO |
---|
206 | END DO |
---|
207 | END DO |
---|
208 | ! |
---|
209 | #if defined key_iomput |
---|
210 | IF( ln_traldf_gdia .AND. cdtype == 'TRA' ) THEN |
---|
211 | CALL wrk_alloc( jpi , jpj , jpk , zw3d ) |
---|
212 | DO jk=1,jpkm1 |
---|
213 | zw3d(:,:,jk) = (psix_eiv(:,:,jk+1) - psix_eiv(:,:,jk))/fse3u(:,:,jk) ! u_eiv = -dpsix/dz |
---|
214 | END DO |
---|
215 | zw3d(:,:,jpk) = 0._wp |
---|
216 | CALL iom_put( "uoce_eiv", zw3d ) ! i-eiv current |
---|
217 | |
---|
218 | DO jk=1,jpk-1 |
---|
219 | zw3d(:,:,jk) = (psiy_eiv(:,:,jk+1) - psiy_eiv(:,:,jk))/fse3v(:,:,jk) ! v_eiv = -dpsiy/dz |
---|
220 | END DO |
---|
221 | zw3d(:,:,jpk) = 0._wp |
---|
222 | CALL iom_put( "voce_eiv", zw3d ) ! j-eiv current |
---|
223 | |
---|
224 | DO jk=1,jpk-1 |
---|
225 | DO jj = 2, jpjm1 |
---|
226 | DO ji = fs_2, fs_jpim1 ! vector opt. |
---|
227 | zw3d(ji,jj,jk) = (psiy_eiv(ji,jj,jk) - psiy_eiv(ji,jj-1,jk))/e2t(ji,jj) + & |
---|
228 | & (psix_eiv(ji,jj,jk) - psix_eiv(ji-1,jj,jk))/e1t(ji,jj) ! w_eiv = dpsiy/dy + dpsiy/dx |
---|
229 | END DO |
---|
230 | END DO |
---|
231 | END DO |
---|
232 | zw3d(:,:,jpk) = 0._wp |
---|
233 | CALL iom_put( "woce_eiv", zw3d ) ! vert. eiv current |
---|
234 | CALL wrk_dealloc( jpi , jpj , jpk , zw3d ) |
---|
235 | ENDIF |
---|
236 | #endif |
---|
237 | ! ! =========== |
---|
238 | DO jn = 1, kjpt ! tracer loop |
---|
239 | ! ! =========== |
---|
240 | ! Zero fluxes for each tracer |
---|
241 | ztfw(:,:,:) = 0._wp |
---|
242 | zftu(:,:,:) = 0._wp |
---|
243 | zftv(:,:,:) = 0._wp |
---|
244 | ! |
---|
245 | DO jk = 1, jpkm1 !== before lateral T & S gradients at T-level jk ==! |
---|
246 | DO jj = 1, jpjm1 |
---|
247 | DO ji = 1, fs_jpim1 ! vector opt. |
---|
248 | zdit(ji,jj,jk) = ( ptb(ji+1,jj ,jk,jn) - ptb(ji,jj,jk,jn) ) * umask(ji,jj,jk) |
---|
249 | zdjt(ji,jj,jk) = ( ptb(ji ,jj+1,jk,jn) - ptb(ji,jj,jk,jn) ) * vmask(ji,jj,jk) |
---|
250 | END DO |
---|
251 | END DO |
---|
252 | END DO |
---|
253 | IF( ln_zps.and.l_grad_zps ) THEN ! partial steps: correction at the last level |
---|
254 | # if defined key_vectopt_loop |
---|
255 | DO jj = 1, 1 |
---|
256 | DO ji = 1, jpij-jpi ! vector opt. (forced unrolling) |
---|
257 | # else |
---|
258 | DO jj = 1, jpjm1 |
---|
259 | DO ji = 1, jpim1 |
---|
260 | # endif |
---|
261 | zdit(ji,jj,mbku(ji,jj)) = pgu(ji,jj,jn) |
---|
262 | zdjt(ji,jj,mbkv(ji,jj)) = pgv(ji,jj,jn) |
---|
263 | END DO |
---|
264 | END DO |
---|
265 | ENDIF |
---|
266 | |
---|
267 | !!---------------------------------------------------------------------- |
---|
268 | !! II - horizontal trend (full) |
---|
269 | !!---------------------------------------------------------------------- |
---|
270 | ! |
---|
271 | DO jk = 1, jpkm1 |
---|
272 | ! |
---|
273 | ! !== Vertical tracer gradient at level jk and jk+1 |
---|
274 | zdkt3d(:,:,1) = ( ptb(:,:,jk,jn) - ptb(:,:,jk+1,jn) ) * tmask(:,:,jk+1) |
---|
275 | ! |
---|
276 | ! ! surface boundary condition: zdkt3d(jk=0)=zdkt3d(jk=1) |
---|
277 | IF( jk == 1 ) THEN ; zdkt3d(:,:,0) = zdkt3d(:,:,1) |
---|
278 | ELSE ; zdkt3d(:,:,0) = ( ptb(:,:,jk-1,jn) - ptb(:,:,jk,jn) ) * tmask(:,:,jk) |
---|
279 | ENDIF |
---|
280 | |
---|
281 | |
---|
282 | IF (ln_botmix_grif) THEN |
---|
283 | DO ip = 0, 1 !== Horizontal & vertical fluxes |
---|
284 | DO kp = 0, 1 |
---|
285 | DO jj = 1, jpjm1 |
---|
286 | DO ji = 1, fs_jpim1 |
---|
287 | ze1ur = 1._wp / e1u(ji,jj) |
---|
288 | zdxt = zdit(ji,jj,jk) * ze1ur |
---|
289 | ze3wr = 1._wp / fse3w(ji+ip,jj,jk+kp) |
---|
290 | zdzt = zdkt3d(ji+ip,jj,kp) * ze3wr |
---|
291 | zslope_skew = triadi_g(ji+ip,jj,jk,1-ip,kp) |
---|
292 | zslope_iso = triadi(ji+ip,jj,jk,1-ip,kp) |
---|
293 | |
---|
294 | zbu = 0.25_wp * e1u(ji,jj) * e2u(ji,jj) * fse3u(ji,jj,jk) |
---|
295 | ! ln_botmix_grif is .T. don't mask zah for bottom half cells |
---|
296 | zah = fsahtu(ji,jj,jk) !*umask(ji,jj,jk+kp) !fsaht(ji+ip,jj,jk) ===>> ???? |
---|
297 | zah_slp = zah * zslope_iso |
---|
298 | zaei_slp = fsaeiw(ji+ip,jj,jk) * zslope_skew !fsaeit(ji+ip,jj,jk)*zslope_skew |
---|
299 | zftu(ji,jj,jk) = zftu(ji,jj,jk) - ( zah * zdxt + (zah_slp - zaei_slp) * zdzt ) * zbu * ze1ur |
---|
300 | ztfw(ji+ip,jj,jk+kp) = ztfw(ji+ip,jj,jk+kp) - (zah_slp + zaei_slp) * zdxt * zbu * ze3wr |
---|
301 | END DO |
---|
302 | END DO |
---|
303 | END DO |
---|
304 | END DO |
---|
305 | |
---|
306 | DO jp = 0, 1 |
---|
307 | DO kp = 0, 1 |
---|
308 | DO jj = 1, jpjm1 |
---|
309 | DO ji = 1, fs_jpim1 |
---|
310 | ze2vr = 1._wp / e2v(ji,jj) |
---|
311 | zdyt = zdjt(ji,jj,jk) * ze2vr |
---|
312 | ze3wr = 1._wp / fse3w(ji,jj+jp,jk+kp) |
---|
313 | zdzt = zdkt3d(ji,jj+jp,kp) * ze3wr |
---|
314 | zslope_skew = triadj_g(ji,jj+jp,jk,1-jp,kp) |
---|
315 | zslope_iso = triadj(ji,jj+jp,jk,1-jp,kp) |
---|
316 | zbv = 0.25_wp * e1v(ji,jj) * e2v(ji,jj) * fse3v(ji,jj,jk) |
---|
317 | ! ln_botmix_grif is .T. don't mask zah for bottom half cells |
---|
318 | zah = fsahtv(ji,jj,jk) !*vmask(ji,jj,jk+kp) ! fsaht(ji,jj+jp,jk) |
---|
319 | zah_slp = zah * zslope_iso |
---|
320 | zaei_slp = fsaeiw(ji,jj+jp,jk) * zslope_skew ! fsaeit(ji,jj+jp,jk)*zslope_skew |
---|
321 | zftv(ji,jj,jk) = zftv(ji,jj,jk) - ( zah * zdyt + (zah_slp - zaei_slp) * zdzt ) * zbv * ze2vr |
---|
322 | ztfw(ji,jj+jp,jk+kp) = ztfw(ji,jj+jp,jk+kp) - (zah_slp + zaei_slp) * zdyt * zbv * ze3wr |
---|
323 | END DO |
---|
324 | END DO |
---|
325 | END DO |
---|
326 | END DO |
---|
327 | ELSE |
---|
328 | DO ip = 0, 1 !== Horizontal & vertical fluxes |
---|
329 | DO kp = 0, 1 |
---|
330 | DO jj = 1, jpjm1 |
---|
331 | DO ji = 1, fs_jpim1 |
---|
332 | ze1ur = 1._wp / e1u(ji,jj) |
---|
333 | zdxt = zdit(ji,jj,jk) * ze1ur |
---|
334 | ze3wr = 1._wp / fse3w(ji+ip,jj,jk+kp) |
---|
335 | zdzt = zdkt3d(ji+ip,jj,kp) * ze3wr |
---|
336 | zslope_skew = triadi_g(ji+ip,jj,jk,1-ip,kp) |
---|
337 | zslope_iso = triadi(ji+ip,jj,jk,1-ip,kp) |
---|
338 | |
---|
339 | zbu = 0.25_wp * e1u(ji,jj) * e2u(ji,jj) * fse3u(ji,jj,jk) |
---|
340 | ! ln_botmix_grif is .F. mask zah for bottom half cells |
---|
341 | zah = fsahtu(ji,jj,jk) * umask(ji,jj,jk+kp) ! fsaht(ji+ip,jj,jk) ===>> ???? |
---|
342 | zah_slp = zah * zslope_iso |
---|
343 | zaei_slp = fsaeiw(ji+ip,jj,jk) * zslope_skew ! fsaeit(ji+ip,jj,jk)*zslope_skew |
---|
344 | zftu(ji,jj,jk) = zftu(ji,jj,jk) - ( zah * zdxt + (zah_slp - zaei_slp) * zdzt ) * zbu * ze1ur |
---|
345 | ztfw(ji+ip,jj,jk+kp) = ztfw(ji+ip,jj,jk+kp) - (zah_slp + zaei_slp) * zdxt * zbu * ze3wr |
---|
346 | END DO |
---|
347 | END DO |
---|
348 | END DO |
---|
349 | END DO |
---|
350 | |
---|
351 | DO jp = 0, 1 |
---|
352 | DO kp = 0, 1 |
---|
353 | DO jj = 1, jpjm1 |
---|
354 | DO ji = 1, fs_jpim1 |
---|
355 | ze2vr = 1._wp / e2v(ji,jj) |
---|
356 | zdyt = zdjt(ji,jj,jk) * ze2vr |
---|
357 | ze3wr = 1._wp / fse3w(ji,jj+jp,jk+kp) |
---|
358 | zdzt = zdkt3d(ji,jj+jp,kp) * ze3wr |
---|
359 | zslope_skew = triadj_g(ji,jj+jp,jk,1-jp,kp) |
---|
360 | zslope_iso = triadj(ji,jj+jp,jk,1-jp,kp) |
---|
361 | zbv = 0.25_wp * e1v(ji,jj) * e2v(ji,jj) * fse3v(ji,jj,jk) |
---|
362 | ! ln_botmix_grif is .F. mask zah for bottom half cells |
---|
363 | zah = fsahtv(ji,jj,jk) * vmask(ji,jj,jk+kp) ! fsaht(ji,jj+jp,jk) |
---|
364 | zah_slp = zah * zslope_iso |
---|
365 | zaei_slp = fsaeiw(ji,jj+jp,jk) * zslope_skew ! fsaeit(ji,jj+jp,jk)*zslope_skew |
---|
366 | zftv(ji,jj,jk) = zftv(ji,jj,jk) - ( zah * zdyt + (zah_slp - zaei_slp) * zdzt ) * zbv * ze2vr |
---|
367 | ztfw(ji,jj+jp,jk+kp) = ztfw(ji,jj+jp,jk+kp) - (zah_slp + zaei_slp) * zdyt * zbv * ze3wr |
---|
368 | END DO |
---|
369 | END DO |
---|
370 | END DO |
---|
371 | END DO |
---|
372 | END IF |
---|
373 | ! !== divergence and add to the general trend ==! |
---|
374 | DO jj = 2 , jpjm1 |
---|
375 | DO ji = fs_2, fs_jpim1 ! vector opt. |
---|
376 | zbtr = 1._wp / ( e1t(ji,jj) * e2t(ji,jj) * fse3t(ji,jj,jk) ) |
---|
377 | pta(ji,jj,jk,jn) = pta(ji,jj,jk,jn) + zbtr * ( zftu(ji-1,jj,jk) - zftu(ji,jj,jk) & |
---|
378 | & + zftv(ji,jj-1,jk) - zftv(ji,jj,jk) ) |
---|
379 | END DO |
---|
380 | END DO |
---|
381 | ! |
---|
382 | END DO |
---|
383 | ! |
---|
384 | DO jk = 1, jpkm1 !== Divergence of vertical fluxes added to the general tracer trend |
---|
385 | DO jj = 2, jpjm1 |
---|
386 | DO ji = fs_2, fs_jpim1 ! vector opt. |
---|
387 | pta(ji,jj,jk,jn) = pta(ji,jj,jk,jn) + ( ztfw(ji,jj,jk+1) - ztfw(ji,jj,jk) ) & |
---|
388 | & / ( e1t(ji,jj) * e2t(ji,jj) * fse3t(ji,jj,jk) ) |
---|
389 | END DO |
---|
390 | END DO |
---|
391 | END DO |
---|
392 | ! |
---|
393 | ! ! "Poleward" diffusive heat or salt transports (T-S case only) |
---|
394 | IF( cdtype == 'TRA' .AND. ln_diaptr .AND. ( MOD( kt, nn_fptr ) == 0 ) ) THEN |
---|
395 | IF( jn == jp_tem) htr_ldf(:) = ptr_vj( zftv(:,:,:) ) ! 3.3 names |
---|
396 | IF( jn == jp_sal) str_ldf(:) = ptr_vj( zftv(:,:,:) ) |
---|
397 | ENDIF |
---|
398 | |
---|
399 | #if defined key_diaar5 |
---|
400 | IF( cdtype == 'TRA' .AND. jn == jp_tem ) THEN |
---|
401 | z2d(:,:) = 0._wp |
---|
402 | zztmp = rau0 * rcp |
---|
403 | DO jk = 1, jpkm1 |
---|
404 | DO jj = 2, jpjm1 |
---|
405 | DO ji = fs_2, fs_jpim1 ! vector opt. |
---|
406 | z2d(ji,jj) = z2d(ji,jj) + zftu(ji,jj,jk) |
---|
407 | END DO |
---|
408 | END DO |
---|
409 | END DO |
---|
410 | z2d(:,:) = zztmp * z2d(:,:) |
---|
411 | CALL lbc_lnk( z2d, 'U', -1. ) |
---|
412 | CALL iom_put( "udiff_heattr", z2d ) ! heat transport in i-direction |
---|
413 | z2d(:,:) = 0._wp |
---|
414 | DO jk = 1, jpkm1 |
---|
415 | DO jj = 2, jpjm1 |
---|
416 | DO ji = fs_2, fs_jpim1 ! vector opt. |
---|
417 | z2d(ji,jj) = z2d(ji,jj) + zftv(ji,jj,jk) |
---|
418 | END DO |
---|
419 | END DO |
---|
420 | END DO |
---|
421 | z2d(:,:) = zztmp * z2d(:,:) |
---|
422 | CALL lbc_lnk( z2d, 'V', -1. ) |
---|
423 | CALL iom_put( "vdiff_heattr", z2d ) ! heat transport in j-direction |
---|
424 | END IF |
---|
425 | #endif |
---|
426 | ! |
---|
427 | END DO |
---|
428 | ! |
---|
429 | CALL wrk_dealloc( jpi, jpj, z2d ) |
---|
430 | CALL wrk_dealloc( jpi, jpj, jpk, zdit, zdjt, ztfw ) |
---|
431 | ! |
---|
432 | IF( nn_timing == 1 ) CALL timing_stop('tra_ldf_iso_grif') |
---|
433 | ! |
---|
434 | END SUBROUTINE tra_ldf_iso_grif |
---|
435 | |
---|
436 | #else |
---|
437 | !!---------------------------------------------------------------------- |
---|
438 | !! default option : Dummy code NO rotation of the diffusive tensor |
---|
439 | !!---------------------------------------------------------------------- |
---|
440 | REAL, PUBLIC, DIMENSION(:,:,:), ALLOCATABLE, SAVE :: psix_eiv, psiy_eiv !: eiv stream function (diag only) |
---|
441 | CONTAINS |
---|
442 | SUBROUTINE tra_ldf_iso_grif( kt, kit000, cdtype, pgu, pgv, & |
---|
443 | & ptb, pta, kjpt, pahtb0 ) |
---|
444 | CHARACTER(len=3) :: cdtype |
---|
445 | INTEGER :: kit000 ! first time step index |
---|
446 | REAL, DIMENSION(:,:,:) :: pgu, pgv ! tracer gradient at pstep levels |
---|
447 | REAL, DIMENSION(:,:,:,:) :: ptb, pta |
---|
448 | WRITE(*,*) 'tra_ldf_iso_grif: You should not have seen this print! error?', kt, cdtype, & |
---|
449 | & pgu(1,1,1), pgv(1,1,1), ptb(1,1,1,1), pta(1,1,1,1), kjpt, pahtb0 |
---|
450 | END SUBROUTINE tra_ldf_iso_grif |
---|
451 | #endif |
---|
452 | |
---|
453 | !!============================================================================== |
---|
454 | END MODULE traldf_iso_grif |
---|