source: CONFIG/UNIFORM/v6/IPSLCM5A2CHT.2/SOURCES/NEMO/PALEO/ldftra_c2d.h90 @ 6032

Last change on this file since 6032 was 6032, checked in by acosce, 2 years ago

create new configuration for IPSLCM5A2CHT model :

1- this configuration will allow to done paleo experiment (need to be done)
2- compilation will be done with script like v6.2 configurations

File size: 7.0 KB
Line 
1   !!----------------------------------------------------------------------
2   !!                      ***  ldftra_c2d.h90  ***
3   !!----------------------------------------------------------------------
4
5   !!----------------------------------------------------------------------
6   !! NEMO/OPA 3.3 , NEMO Consortium (2010)
7   !! $Id: ldftra_c2d.h90 4147 2013-11-04 11:51:55Z cetlod $
8   !! Software governed by the CeCILL licence (NEMOGCM/NEMO_CeCILL.txt)
9   !!----------------------------------------------------------------------
10
11   SUBROUTINE ldf_tra_c2d( ld_print )
12      !!----------------------------------------------------------------------
13      !!                  ***  ROUTINE ldftra_c2d  ***
14      !!             
15      !! ** Purpose :   initializations of horizontally non uniform eddy
16      !!      diffusivity coefficients
17      !!
18      !! ** Method :
19      !!       biharmonic operator    : ahtt = defined at T-level
20      !!                                ahtu,ahtv,ahtw never used
21      !!       harmonic operator (ahtt never used)
22      !!           iso-model level   : ahtu, ahtv defined at u-, v-points
23      !!         isopycnal         : ahtu, ahtv, ahtw defined at u-, v-, w-pts
24      !!         or geopotential   
25      !!       eddy induced velocity
26      !!           always harmonic   : aeiu, aeiv, aeiw defined at u-, v-, w-pts
27      !!----------------------------------------------------------------------
28      LOGICAL, INTENT (in) ::   ld_print   ! If true, print arrays in numout
29      !
30      INTEGER ::   ji, jj   ! dummy loop indices
31      REAL(wp) ::   za00, zd_max, zeumax, zevmax, zetmax
32      !!----------------------------------------------------------------------
33
34      IF( lk_traldf_eiv ) THEN
35         IF(lwp) WRITE(numout,*)
36         IF(lwp) WRITE(numout,*) ' ldf_tra_c2d : 2D eddy diffusivity and eddy'
37         IF(lwp) WRITE(numout,*) ' ~~~~~~~~~~~   --  induced velocity coefficients'
38      ELSE
39         IF(lwp) WRITE(numout,*)
40         IF(lwp) WRITE(numout,*) ' ldf_tra2d : 2D eddy diffusivity coefficient'
41         IF(lwp) WRITE(numout,*) ' ~~~~~~~~~~~   --'
42      ENDIF
43
44      zd_max = MAX( MAXVAL( e1t(:,:) ), MAXVAL( e2t(:,:) ) )
45      IF( lk_mpp ) CALL mpp_max( zd_max )   ! max over the global domain
46
47      ! harmonic operator : (U-, V-, W-points)
48      ! ==================
49      IF( ln_traldf_lap ) THEN
50         !
51         za00 = aht0 / zd_max
52         !
53         DO jj = 1, jpj
54            DO ji = 1, jpi
55               zeumax = MAX( e1u(ji,jj), e2u(ji,jj) )
56               zevmax = MAX( e1v(ji,jj), e2v(ji,jj) )
57               zetmax = MAX( e1t(ji,jj), e2t(ji,jj) )
58               ahtu(ji,jj) = za00 * zeumax ! set ahtu = ahtv at u- and v-points,
59               ahtv(ji,jj) = za00 * zevmax ! and ahtw at w-point (idem T-point)
60               ahtw(ji,jj) = za00 * zetmax !
61            END DO
62         END DO
63
64         CALL lbc_lnk( ahtu, 'U', 1. )   ! Lateral boundary conditions
65         CALL lbc_lnk( ahtv, 'V', 1. )   ! (no change of sign)
66         CALL lbc_lnk( ahtw, 'W', 1. )
67
68         ! Special case for ORCA R2 and R4 configurations (overwrite the value of ahtu ahtv ahtw)
69         ! Add PALEORCA2 configuration -- JBL 08.02.2017
70         ! ==============================================
71         IF( ( cp_cfg == "orca" .OR. cp_cfg == "paleorca" ) .AND. ( jp_cfg == 2 .OR. jp_cfg == 4 ) )   THEN
72            ahtu(:,:) = aht0              ! set ahtu = ahtv at u- and v-points,
73            ahtv(:,:) = aht0              ! and ahtw at w-point
74            ahtw(:,:) = aht0              ! (here : no space variation)
75            IF(lwp) WRITE(numout,*) '               ORCA R2 or R4 case'
76            IF(lwp) WRITE(numout,*) '               Constant values used for eddy diffusivity coefficients'
77            IF(lwp) WRITE(numout,*) '               Variation lat/lon only for eddy induced velocity coefficients'
78         ENDIF
79
80         ! Control print
81         IF( lwp .AND. ld_print ) THEN
82            WRITE(numout,*)
83            WRITE(numout,*) 'inildf: ahtu array'
84            CALL prihre( ahtu, jpi, jpj, 1, jpi, 1,   &
85               &                         1, jpj, 1, 1.e-3, numout )
86            WRITE(numout,*)
87            WRITE(numout,*) 'inildf: ahtv array'
88            CALL prihre( ahtv, jpi, jpj, 1, jpi, 1,   &
89               &                         1, jpj, 1, 1.e-3, numout )
90            WRITE(numout,*)
91            WRITE(numout,*) 'inildf: ahtw array'
92            CALL prihre( ahtw, jpi, jpj, 1, jpi, 1,   &
93               &                         1, jpj, 1, 1.e-3, numout )
94         ENDIF
95      ENDIF
96     
97      ! biharmonic operator : (T-point)
98      ! ====================
99      IF( ln_traldf_bilap ) THEN
100         ! (USER: modify ahtt following your desiderata)
101         ! Here: ahm is proportional to the cube of the maximum of the gridspacing
102         !       in the to horizontal direction
103
104         zd_max = MAX( MAXVAL( e1t(:,:) ), MAXVAL( e2t(:,:) ) )
105         IF( lk_mpp )   CALL mpp_max( zd_max )   ! max over the global domain
106
107         za00 = aht0 / ( zd_max * zd_max * zd_max )
108         DO jj = 1, jpj
109            DO ji = 1, jpi
110               zetmax = MAX( e1t(ji,jj), e2t(ji,jj) )
111               ahtt(ji,jj) = za00 * zetmax * zetmax * zetmax      ! set ahtt at T-point
112            END DO
113         END DO
114
115         CALL lbc_lnk( ahtt, 'T', 1. )   ! Lateral boundary conditions on ( ahtt )
116
117         ! Control print
118         IF( lwp .AND. ld_print ) THEN
119            WRITE(numout,*)
120            WRITE(numout,*) 'inildf: 2D ahtt array'
121            CALL prihre( ahtt, jpi, jpj, 1, jpi, 1,   &
122               &                         1, jpj, 1, 1.e-3, numout )
123         ENDIF
124      ENDIF
125
126# if defined key_traldf_eiv
127      ! set aeiu = aeiv at u- and v-points, and aeiw at w-point (idem T-point)
128      ! (here no space variation)
129      aeiu(:,:) = aeiv0
130      aeiv(:,:) = aeiv0
131      aeiw(:,:) = aeiv0
132     
133      IF( cp_cfg == "orca" .AND. jp_cfg == 4 ) THEN
134         !                                 ! Cancel eiv in Gibraltar strait
135         aeiu( mi0(68):mi1(71) , mj0(50):mj1(53) ) = 0.e0
136         aeiv( mi0(68):mi1(71) , mj0(50):mj1(53) ) = 0.e0
137         aeiw( mi0(68):mi1(71) , mj0(50):mj1(53) ) = 0.e0
138         !                                 ! Cancel eiv in Mediterrannean sea
139         aeiu( mi0(70):mi1(90) , mj0(49):mj1(56) ) = 0.e0
140         aeiv( mi0(70):mi1(90) , mj0(49):mj1(56) ) = 0.e0
141         aeiw( mi0(70):mi1(90) , mj0(49):mj1(56) ) = 0.e0
142      ENDIF
143
144      ! Lateral boundary conditions on ( aeiu, aeiv, aeiw )
145      CALL lbc_lnk( aeiu, 'U', 1. )
146      CALL lbc_lnk( aeiv, 'V', 1. )
147      CALL lbc_lnk( aeiw, 'W', 1. )
148
149      ! Control print
150      IF( lwp .AND. ld_print ) THEN
151         WRITE(numout,*)
152         WRITE(numout,*) 'inildf: aeiu array'
153         CALL prihre(aeiu,jpi,jpj,1,jpi,1,1,jpj,1,1.e-3,numout)
154         WRITE(numout,*)
155         WRITE(numout,*) 'inildf: aeiv array'
156         CALL prihre(aeiv,jpi,jpj,1,jpi,1,1,jpj,1,1.e-3,numout)
157         WRITE(numout,*)
158         WRITE(numout,*) 'inildf: aeiw array'
159         CALL prihre(aeiw,jpi,jpj,1,jpi,1,1,jpj,1,1.e-3,numout)
160      ENDIF
161# endif
162      !
163   END SUBROUTINE ldf_tra_c2d
Note: See TracBrowser for help on using the repository browser.