source: CONFIG/LMDZOR/branches/LMDZOR_v4/CREATE/SCRIPT/add_step.x @ 1169

#!/bin/csh
#set verbose echo

set an_debut=$1
set an_fin=$2
set mois_debut=$3
set mois_fin=$4

# suf : file name must look like u$suf$an-$mois.nc (par default suf=_ERAI_)
set suf=$5
# outdir : repertoire ou sont stocke les fichiers interpole
set outdir=$6


echo 'Entering add_step.x'
echo an_debut=$an_debut an_fin=$an_fin
echo mois_debut=$mois_debut mois_fin=$mois_fin
echo 'premier fichier : '$outdir/u$suf$an_debut-$mois_debut.nc
echo outdir=$outdir
echo ' '

##################################################
cd $outdir
##################################################
# Debut boucle sur annees
#
# Si moins d'un an, mettre mois_fin inferieur a 12
##################################################
set an=$an_debut
set imois=$mois_debut
while ( $an <= $an_fin )
    #####################
    # Boucle sur les mois
    ######################
    while ( $imois <= $mois_fin )
        if ( $imois <= 9 ) then
            set mois=0$imois
        else
            set mois=$imois
        endif
        ###############################
        # Determination du mois suivant
        ###############################
        set anp1=$an
        set imoisp1=`expr $imois + 1`
        if ( $imoisp1 == 13 ) then
            set anp1=`expr $an + 1`
            set imoisp1=1
        endif
    
        if ( $imoisp1 <= 9 ) then
            set moisp1=0$imoisp1
        else
            set moisp1=$imoisp1
        endif


        set outsuf=$suf$an-$mois.nc
        set outsufp1=$suf$anp1-$moisp1.nc
        
        if ( -f u$outsufp1 ) then
            echo First time step from file u$outsufp1 will be added in file u$outsuf 
            ncks -O -d THOUR,0,0 u$outsufp1 u1.nc
            ncrcat -O u$outsuf u1.nc u$outsuf
        else
            echo File u$outsufp1 does not exist
        endif

        if ( -f v$outsufp1 ) then
            echo First time step from file v$outsufp1 will be added in file v$outsuf 
            ncks -O -d THOUR,0,0 v$outsufp1 v1.nc
            ncrcat -O v$outsuf v1.nc v$outsuf
        else
            echo File v$outsufp1 does not exist
        endif

        # Mois prochain
        set imois=`expr $imois + 1`
    end
    set an=`expr $an + 1`
    set imois=1
end