source: codes/icosagcm/trunk/src/timeloop_gcm.f90 @ 363

Last change on this file since 363 was 363, checked in by dubos, 9 years ago

Bugfix : memory leak when nqtot>0
File size: 10.0 KB
Line 
1MODULE timeloop_gcm_mod
2  USE icosa
3  USE disvert_mod
4  USE trace
5  USE omp_para
6  USE euler_scheme_mod
7  USE explicit_scheme_mod
8  USE hevi_scheme_mod
9  IMPLICIT NONE
10  PRIVATE
11 
12  INTEGER, PARAMETER :: itau_sync=10
13  TYPE(t_message),SAVE :: req_ps0, req_mass0, req_theta_rhodz0, req_u0, req_q0
14
15  PUBLIC :: init_timeloop, timeloop
16
17CONTAINS
18 
19  SUBROUTINE init_timeloop
20    USE dissip_gcm_mod
21    USE observable_mod
22    USE caldyn_mod
23    USE etat0_mod
24    USE guided_mod
25    USE advect_tracer_mod
26    USE check_conserve_mod
27    USE output_field_mod
28    USE theta2theta_rhodz_mod
29    USE sponge_mod
30
31    CHARACTER(len=255) :: def
32   
33    IF (xios_output) itau_out=1
34    IF (.NOT. enable_io) itau_out=HUGE(itau_out)
35   
36    def='RK2.5'
37    CALL getin('time_scheme',def)
38    SELECT CASE (TRIM(def))
39    CASE('euler')
40       scheme_family=explicit
41       scheme=euler
42       nb_stage=1
43    CASE ('runge_kutta')
44       scheme_family=explicit
45       scheme=rk4
46       nb_stage=4
47    CASE ('RK2.5')
48       scheme_family=explicit
49       scheme=rk25
50       nb_stage=5
51    CASE ('leapfrog_matsuno')
52       scheme_family=explicit
53       scheme=mlf
54       matsuno_period=5
55       CALL getin('matsuno_period',matsuno_period)
56       nb_stage=matsuno_period+1
57    CASE('ARK2.3')
58       scheme_family=hevi
59       scheme=ark23
60       nb_stage=3
61       CALL set_coefs_ark23(dt)
62    CASE('ARK3.3')
63       scheme_family=hevi
64       scheme=ark33
65       nb_stage=3
66       CALL set_coefs_ark33(dt)
67    CASE ('none')
68       nb_stage=0
69    CASE default
70       PRINT*,'Bad selector for variable scheme : <', TRIM(def),             &
71            ' > options are <euler>, <runge_kutta>, <leapfrog_matsuno>,<RK2.5>,<ARK2.3>'
72       STOP
73    END SELECT
74   
75    ! Time-independant orography
76    CALL allocate_field(f_phis,field_t,type_real,name='phis')
77    ! Model state at current time step
78    CALL allocate_field(f_geopot,field_t,type_real,llm+1,name='geopot')
79    CALL allocate_field(f_ps,field_t,type_real, name='ps')
80    CALL allocate_field(f_mass,field_t,type_real,llm,name='mass')
81    CALL allocate_field(f_rhodz,field_t,type_real,llm,name='rhodz')
82    CALL allocate_field(f_theta_rhodz,field_t,type_real,llm,name='theta_rhodz')
83    CALL allocate_field(f_u,field_u,type_real,llm,name='u')
84    CALL allocate_field(f_q,field_t,type_real,llm,nqtot,'q')
85    ! Mass fluxes
86    CALL allocate_field(f_hflux,field_u,type_real,llm)    ! instantaneous mass fluxes
87    CALL allocate_field(f_hfluxt,field_u,type_real,llm)   ! mass "fluxes" accumulated in time
88    CALL allocate_field(f_wflux,field_t,type_real,llm+1)  ! vertical mass fluxes
89    CALL allocate_field(f_wfluxt,field_t,type_real,llm+1,name='wfluxt')
90   
91    SELECT CASE(scheme_family)
92    CASE(explicit)
93       ! Trends
94       CALL allocate_field(f_dps,field_t,type_real,name='dps')
95       CALL allocate_field(f_dmass,field_t,type_real,llm, name='dmass')
96       CALL allocate_field(f_dtheta_rhodz,field_t,type_real,llm,name='dtheta_rhodz')
97       CALL allocate_field(f_du,field_u,type_real,llm,name='du')
98       ! Model state at previous time step (RK/MLF)
99       CALL allocate_field(f_psm1,field_t,type_real,name='psm1')
100       CALL allocate_field(f_massm1,field_t,type_real,llm, name='massm1')
101       CALL allocate_field(f_theta_rhodzm1,field_t,type_real,llm,name='theta_rhodzm1')
102       CALL allocate_field(f_um1,field_u,type_real,llm,name='um1')
103    CASE(hevi)
104       ! Trends
105       CALL allocate_fields(nb_stage,f_dps_slow, field_t,type_real,name='dps_slow')
106       CALL allocate_fields(nb_stage,f_dmass_slow, field_t,type_real,llm, name='dmass_slow')
107       CALL allocate_fields(nb_stage,f_dtheta_rhodz_slow, field_t,type_real,llm,name='dtheta_rhodz_fast')
108       CALL allocate_fields(nb_stage,f_du_slow, field_u,type_real,llm,name='du_slow')
109       CALL allocate_fields(nb_stage,f_du_fast, field_u,type_real,llm,name='du_fast')
110       f_dps => f_dps_slow(:,1)
111       f_du => f_du_slow(:,1)
112       f_dtheta_rhodz => f_dtheta_rhodz_slow(:,1)
113    END SELECT
114
115    SELECT CASE(scheme)
116    CASE(mlf)
117       ! Model state 2 time steps ago (MLF)
118       CALL allocate_field(f_psm2,field_t,type_real)
119       CALL allocate_field(f_massm2,field_t,type_real,llm)
120       CALL allocate_field(f_theta_rhodzm2,field_t,type_real,llm)
121       CALL allocate_field(f_um2,field_u,type_real,llm)
122    END SELECT
123
124    CALL init_theta2theta_rhodz
125    CALL init_dissip
126    CALL init_sponge
127    CALL init_observable
128    CALL init_caldyn
129    CALL init_guided
130    CALL init_advect_tracer
131    CALL init_check_conserve
132
133    CALL etat0(f_ps,f_mass,f_phis,f_theta_rhodz,f_u, f_q)
134
135    CALL transfert_request(f_phis,req_i0) 
136    CALL transfert_request(f_phis,req_i1) 
137    CALL writefield("phis",f_phis,once=.TRUE.)
138
139    CALL init_message(f_ps,req_i0,req_ps0)
140    CALL init_message(f_mass,req_i0,req_mass0)
141    CALL init_message(f_theta_rhodz,req_i0,req_theta_rhodz0)
142    CALL init_message(f_u,req_e0_vect,req_u0)
143    CALL init_message(f_q,req_i0,req_q0)
144
145  END SUBROUTINE init_timeloop
146 
147  SUBROUTINE timeloop
148    USE dissip_gcm_mod
149    USE sponge_mod
150    USE observable_mod
151    USE etat0_mod
152    USE guided_mod
153    USE caldyn_mod
154    USE advect_tracer_mod
155    USE physics_mod
156    USE mpipara
157    USE transfert_mod
158    USE check_conserve_mod
159    USE xios_mod
160    USE output_field_mod
161    USE write_etat0_mod
162    USE checksum_mod
163    USE explicit_scheme_mod
164    USE hevi_scheme_mod
165    REAL(rstd),POINTER :: rhodz(:,:), mass(:,:), ps(:)
166
167    INTEGER :: ind
168    INTEGER :: it,i,j,l,n,  stage
169    LOGICAL :: fluxt_zero(ndomain) ! set to .TRUE. to start accumulating fluxes in time
170    LOGICAL, PARAMETER :: check_rhodz=.FALSE.
171    INTEGER :: start_clock, stop_clock, rate_clock
172    LOGICAL,SAVE :: first_physic=.TRUE.
173    !$OMP THREADPRIVATE(first_physic)   
174
175    CALL switch_omp_distrib_level
176    CALL caldyn_BC(f_phis, f_geopot, f_wflux) ! set constant values in first/last interfaces
177
178    !$OMP BARRIER
179    DO ind=1,ndomain
180       IF (.NOT. assigned_domain(ind)) CYCLE
181       CALL swap_dimensions(ind)
182       CALL swap_geometry(ind)
183       rhodz=f_rhodz(ind); mass=f_mass(ind); ps=f_ps(ind)
184       IF(caldyn_eta==eta_mass) THEN
185          CALL compute_rhodz(.TRUE., ps, rhodz) ! save rhodz for transport scheme before dynamics update ps
186       ELSE
187          DO l=ll_begin,ll_end
188             rhodz(:,l)=mass(:,l)
189          ENDDO
190       END IF
191    END DO
192    !$OMP BARRIER
193    fluxt_zero=.TRUE.
194
195    !$OMP MASTER
196    CALL SYSTEM_CLOCK(start_clock)
197    !$OMP END MASTER   
198
199    CALL check_conserve(f_ps,f_dps,f_u,f_theta_rhodz,f_phis,itau0) 
200
201    CALL trace_on
202
203    DO it=itau0+1,itau0+itaumax
204
205       CALL check_conserve_detailed('detailed_budget 0', &
206            f_ps,f_dps,f_u,f_theta_rhodz,f_phis,it)
207
208       IF (xios_output) CALL xios_update_calendar(it)
209       IF (it==itau0+1 .OR. MOD(it,itau_sync)==0) THEN
210          CALL send_message(f_ps,req_ps0)
211          CALL wait_message(req_ps0)
212          CALL send_message(f_mass,req_mass0)
213          CALL wait_message(req_mass0)
214          CALL send_message(f_theta_rhodz,req_theta_rhodz0) 
215          CALL wait_message(req_theta_rhodz0) 
216          CALL send_message(f_u,req_u0)
217          CALL wait_message(req_u0)
218          CALL send_message(f_q,req_q0) 
219          CALL wait_message(req_q0) 
220       ENDIF
221
222       IF (is_master) PRINT *,"It No :",It,"   t :",dt*It
223
224       IF (mod(it,itau_out)==0 ) THEN
225          CALL update_time_counter(dt*it)
226          CALL write_output_fields_basic(f_ps, f_u, f_q)
227       ENDIF
228
229       CALL guided(it*dt,f_ps,f_theta_rhodz,f_u,f_q)
230
231       SELECT CASE(scheme_family)
232       CASE(explicit)
233          CALL explicit_scheme(it, fluxt_zero)
234       CASE(hevi)
235          CALL HEVI_scheme(it, fluxt_zero)
236       END SELECT
237
238       CALL check_conserve_detailed('detailed_budget 1', &
239            f_ps,f_dps,f_u,f_theta_rhodz,f_phis,it)
240       
241       IF (MOD(it,itau_dissip)==0) THEN
242         
243          IF(caldyn_eta==eta_mass) THEN
244             !ym flush ps
245             !$OMP BARRIER
246             DO ind=1,ndomain
247                IF (.NOT. assigned_domain(ind)) CYCLE
248                CALL swap_dimensions(ind)
249                CALL swap_geometry(ind)
250                mass=f_mass(ind); ps=f_ps(ind);
251                CALL compute_rhodz(.TRUE., ps, mass)
252             END DO
253          ENDIF
254         
255          CALL dissip(f_u,f_du,f_mass,f_phis, f_theta_rhodz,f_dtheta_rhodz)
256         
257          CALL euler_scheme(.FALSE.)  ! update only u, theta
258          IF (iflag_sponge > 0) THEN
259             CALL sponge(f_u,f_du,f_theta_rhodz,f_dtheta_rhodz)
260             CALL euler_scheme(.FALSE.)  ! update only u, theta
261          END IF
262       END IF
263       
264       CALL check_conserve_detailed('detailed_budget 2', &
265            f_ps,f_dps,f_u,f_theta_rhodz,f_phis,it)
266       
267       IF(MOD(it,itau_adv)==0) THEN
268          IF(nqtot>0) CALL advect_tracer(f_hfluxt,f_wfluxt,f_u, f_q,f_rhodz)  ! update q and rhodz after RK step
269          fluxt_zero=.TRUE.
270          ! FIXME : check that rhodz is consistent with ps
271          IF (check_rhodz) THEN
272             DO ind=1,ndomain
273                IF (.NOT. assigned_domain(ind)) CYCLE
274                CALL swap_dimensions(ind)
275                CALL swap_geometry(ind)
276                rhodz=f_rhodz(ind); ps=f_ps(ind);
277                CALL compute_rhodz(.FALSE., ps, rhodz)   
278             END DO
279          ENDIF
280         
281       END IF
282       
283       IF (MOD(it,itau_check_conserv)==0) THEN
284          CALL check_conserve(f_ps,f_dps,f_u,f_theta_rhodz,f_phis,it) 
285       ENDIF
286       
287       IF (MOD(it,itau_physics)==0) THEN
288          CALL physics(it,f_phis, f_ps, f_theta_rhodz, f_u, f_wflux, f_q)       
289          !$OMP MASTER
290          IF (first_physic) CALL SYSTEM_CLOCK(start_clock)
291          !$OMP END MASTER   
292          first_physic=.FALSE.
293       END IF
294       
295    END DO
296   
297    CALL write_etat0(itau0+itaumax,f_ps, f_phis,f_theta_rhodz,f_u,f_q) 
298   
299    CALL check_conserve(f_ps,f_dps,f_u,f_theta_rhodz,f_phis,it) 
300   
301    !$OMP MASTER
302    CALL SYSTEM_CLOCK(stop_clock)
303    CALL SYSTEM_CLOCK(count_rate=rate_clock)
304   
305    IF (mpi_rank==0) THEN
306       PRINT *,"Time elapsed : ",(stop_clock-start_clock)*1./rate_clock 
307    ENDIF
308    !$OMP END MASTER
309   
310    ! CONTAINS
311  END SUBROUTINE timeloop
312 
313END MODULE timeloop_gcm_mod
Note: See TracBrowser for help on using the repository browser.