source: codes/icosagcm/trunk/src/diagnostics/check_conserve.f90 @ 548

Last change on this file since 548 was 548, checked in by dubos, 7 years ago

trunk : reorganize source tree
File size: 14.0 KB
Line 
1MODULE check_conserve_mod
2  USE icosa 
3  IMPLICIT NONE
4
5  PRIVATE
6 
7  INTEGER, PARAMETER, PUBLIC :: check_basic=1, check_detailed=2, &
8       AAM_dissip=1, AAM_dyn=2, AAM_phys=3
9  INTEGER, SAVE :: check_type
10
11  TYPE(t_field),POINTER,SAVE :: f_pk(:), f_pks(:), f_p(:)
12  TYPE(t_field),POINTER,SAVE :: f_vort(:)
13  TYPE(t_field),POINTER,SAVE :: f_rhodz(:) 
14 
15  REAL(rstd),SAVE :: AAM_mass, AAM_mass_old, AAM_vel, AAM_vel_old, &
16       AAM_mass_source(3), AAM_vel_source(3) ! read/written only IF is_master
17  REAL(rstd),SAVE :: mtot0,ztot0,etot0,angtot0,stot0,rmsvtot0
18  !$OMP THREADPRIVATE(check_type, mtot0,ztot0,etot0,angtot0,stot0,rmsvtot0)
19 
20  PUBLIC :: init_check_conserve, check_conserve_detailed, check_conserve
21CONTAINS 
22
23!---------------------------------------------------------------------
24
25  SUBROUTINE init_check_conserve
26    USE getin_mod
27    USE omp_para, ONLY : is_master
28    CHARACTER(LEN=255) :: check_type_str
29    CALL allocate_field(f_pk,field_t,type_real,llm)
30    CALL allocate_field(f_p,field_t,type_real,llm+1)
31    CALL allocate_field(f_pks,field_t,type_real)
32    CALL allocate_field(f_rhodz,field_t,type_real,llm)
33    CALL allocate_field(f_vort,field_z,type_real,llm)
34   
35    check_type_str='basic'
36    CALL getin("check_conservation",check_type_str)
37    SELECT CASE(TRIM(check_type_str))
38    CASE('basic')
39       check_type=check_basic
40    CASE('detailed')
41       check_type=check_detailed
42    CASE DEFAULT
43       IF(is_master) PRINT*,'Bad selector <', TRIM(check_type_str), &
44            '> for variable check_conservation : options are <basic>, <detailed>'
45       STOP
46    END SELECT
47  END SUBROUTINE init_check_conserve
48
49!--------------------------------- Basic check --------------------------------
50
51  SUBROUTINE check_conserve(f_ps,f_dps,f_ue,f_theta_rhodz,f_phis,it) 
52  USE pression_mod
53  USE vorticity_mod
54  USE caldyn_gcm_mod
55  USE exner_mod 
56!  USE mpipara, ONLY : is_mpi_master, comm_icosa
57  USE omp_para, ONLY : is_master
58    TYPE(t_field),POINTER :: f_ps(:)
59    TYPE(t_field),POINTER :: f_dps(:)
60    TYPE(t_field),POINTER :: f_ue(:)
61    TYPE(t_field),POINTER :: f_theta_rhodz(:)
62    TYPE(t_field),POINTER :: f_phis(:)
63    INTEGER, INTENT(IN) :: it
64
65    REAL(rstd),POINTER :: p(:,:),rhodz(:,:) 
66    INTEGER :: ind,ierr
67    REAL(rstd) :: mtot, angtot, rmsdpdt
68    REAL(rstd) :: etot, stot, ang_mass, ang_vel, rmsvtot, ztot
69
70    CALL transfert_request(f_ue,req_e1_vect)
71    CALL pression(f_ps,f_p)
72
73    DO ind=1,ndomain 
74      IF (.NOT. assigned_domain(ind)) CYCLE
75      CALL swap_dimensions(ind)
76      CALL swap_geometry(ind)
77      p=f_p(ind) 
78      rhodz=f_rhodz(ind)
79      CALL compute_rhodz(p,rhodz) 
80    END DO
81
82    CALL vorticity(f_ue,f_vort)
83    CALL check_mass_conserve(f_ps,f_dps,mtot,rmsdpdt)
84    CALL check_PV(ztot) 
85    CALL exner(f_ps,f_p,f_pks,f_pk)
86    CALL check_energy(f_ue,f_theta_rhodz,f_phis, etot, stot, ang_mass, ang_vel, rmsvtot) 
87
88    IF (is_master) THEN ! is_master = is_omp_master && is_mpi_master
89       ! AAM_mass and AAM_vel must be read/written only IF is_master
90       AAM_mass = ang_mass
91       AAM_vel = ang_vel
92       angtot  = ang_mass + ang_vel
93       IF ( it == itau0  ) THEN
94          ztot0 = ztot
95          mtot0 = mtot
96          etot0 = etot 
97          angtot0  = angtot
98          stot0 = stot 
99          AAM_mass_old=AAM_mass
100          AAM_vel_old=AAM_vel
101          AAM_mass_source=0.
102          AAM_vel_source=0.
103       END IF
104       rmsvtot=SQRT(rmsvtot/mtot) 
105       ztot=ztot/ztot0-1. ; mtot=mtot/mtot0-1. 
106       etot=etot/etot0-1. ; angtot=angtot/angtot0-1. ; stot=stot/stot0-1. 
107       rmsdpdt= daysec*1.e-2*sqrt(rmsdpdt/ncell_glo) 
108       
109       OPEN(134,file="checkconsicosa.txt",position='append')
110       WRITE(134,4000)mtot,rmsdpdt,etot,ztot,stot,rmsvtot,angtot
111       WRITE(134,*)mtot,rmsdpdt,etot,ztot,stot,rmsvtot,angtot 
112       WRITE(134,*)"=================================================="
113       WRITE(*,4000)mtot,rmsdpdt,etot,ztot,stot,rmsvtot,angtot
114       
1154000   FORMAT(10x,'masse',5x,'rmsdpdt',5x,'energie',5x,'enstrophie'  &
116            ,5x,'entropie',5x,'rmsv',5x,'mt.ang',/,'GLOB  '          &
117            ,e10.3,e13.6,5e13.3/)     
118       CLOSE(134)
119
120       IF(check_type == check_detailed) THEN
121          !ang_mass = AAM_mass-AAM_mass_old
122          !WRITE(*,'(A,3E12.4)') 'AAM_mass sanity check', SUM(AAM_mass_source), ang_mass, SUM(AAM_mass_source)-ang_mass
123          !ang_vel = AAM_vel-AAM_vel_old
124          !WRITE(*,'(A,3E12.4)') 'AAM_vel  sanity check', SUM(AAM_vel_source), ang_vel, SUM(AAM_vel_source)-ang_vel
125          WRITE(*,'(A,6E12.4)') 'AAM_mass : time,old,new,dissip,dyn,phys', dt*it, AAM_mass_old, AAM_mass, &
126               AAM_mass_source(AAM_dissip), AAM_mass_source(AAM_dyn), AAM_mass_source(AAM_phys)
127          WRITE(*,'(A,6E12.4)') 'AAM_vel  : time,old,new,dissip,dyn,phys', dt*it, AAM_vel_old, AAM_vel, &
128               AAM_vel_source(AAM_dissip), AAM_vel_source(AAM_dyn), AAM_vel_source(AAM_phys)
129          AAM_mass_old=AAM_mass
130          AAM_vel_old=AAM_vel
131          AAM_mass_source=0.
132          AAM_vel_source=0.
133       END IF
134    END IF
135
136  END SUBROUTINE check_conserve
137
138!------------------------ Detailed check (Lauritzen et al., 2014) -----------------------------
139
140  SUBROUTINE check_conserve_detailed(it,tag, f_ps,f_dps,f_ue,f_theta_rhodz,f_phis) 
141    USE pression_mod
142    USE vorticity_mod
143    USE caldyn_gcm_mod
144    USE exner_mod 
145!    USE mpipara, ONLY : is_mpi_root, comm_icosa
146    USE omp_para, ONLY : is_master
147    INTEGER, INTENT(IN) :: tag
148    TYPE(t_field),POINTER :: f_ps(:)
149    TYPE(t_field),POINTER :: f_dps(:)
150    TYPE(t_field),POINTER :: f_ue(:)
151    TYPE(t_field),POINTER :: f_theta_rhodz(:)
152    TYPE(t_field),POINTER :: f_phis(:)
153    INTEGER, INTENT(IN) ::it
154
155    REAL(rstd),POINTER :: p(:,:),rhodz(:,:) 
156    INTEGER::ind,ierr
157    REAL(rstd) :: mtot, ztot, rmsdpdt, etot,stot,rmsv, ang_mass, ang_vel
158   
159    IF(check_type == check_detailed) THEN
160
161       CALL transfert_request(f_ue,req_e1_vect)
162       CALL pression(f_ps,f_p)
163       DO ind=1,ndomain 
164          IF (.NOT. assigned_domain(ind)) CYCLE
165          CALL swap_dimensions(ind)
166          CALL swap_geometry(ind)
167          p=f_p(ind) 
168          rhodz=f_rhodz(ind)
169          CALL compute_rhodz(p,rhodz) 
170       END DO
171       CALL exner(f_ps,f_p,f_pks,f_pk)
172       CALL check_energy(f_ue,f_theta_rhodz,f_phis, etot, stot, ang_mass, ang_vel, rmsv) 
173       
174       IF (is_master) THEN
175          ! XXX=mass,vel
176          ! AAM_XXX = value of total AAM_XXX at last check
177          ! ang_XXX = value of total AAM_XXX now
178          ! AAM_XXX_source(tag) = source of AAA_XXX due to tag=dissip,dyn,phys
179          !WRITE(*,'(A,3E12.2)') 'AAM_mass', tag, ang_mass, AAM_mass, ang_mass-AAM_mass ! FIXME
180          !WRITE(*,'(A,3E12.2)') 'AAM_vel ', tag, ang_vel, AAM_vel, ang_vel-AAM_vel ! FIXME
181          AAM_mass_source(tag) = AAM_mass_source(tag) + ang_mass - AAM_mass
182          AAM_vel_source(tag) = AAM_vel_source(tag) + ang_vel - AAM_vel
183          AAM_mass = ang_mass
184          AAM_vel = ang_vel
185       END IF
186    END IF
187  END SUBROUTINE check_conserve_detailed
188 
189!---------------------------------------------------------------------
190
191  SUBROUTINE global_sum(loc_sum, glob_sum)
192    USE mpi_mod
193    USE mpipara
194    USE transfert_omp_mod
195    REAL(rstd), INTENT(IN) :: loc_sum
196    REAL(rstd), INTENT(OUT) :: glob_sum
197    REAL(rstd) :: sum
198
199    CALL reduce_sum_omp(loc_sum, sum)
200    IF (using_mpi) THEN
201!$OMP MASTER   
202      CALL MPI_REDUCE(sum, glob_sum, 1, MPI_REAL8, MPI_SUM, 0, comm_icosa, ierr)
203!$OMP END MASTER
204    ELSE
205      glob_sum=loc_sum
206    ENDIF
207  END SUBROUTINE global_sum
208
209  SUBROUTINE check_mass_conserve(f_ps,f_dps,mtot,rmsdpdt)
210  USE mpi_mod
211  USE mpipara
212  USE transfert_omp_mod
213  USE omp_para
214  IMPLICIT NONE
215    TYPE(t_field),POINTER :: f_ps(:)
216    TYPE(t_field),POINTER :: f_dps(:)
217    REAL(rstd),POINTER :: ps(:),dps(:) 
218    REAL(rstd), INTENT(OUT) :: mtot, rmsdpdt
219
220    INTEGER :: ind,i,j,ij 
221    REAL :: mloc, rmsloc
222    REAL :: mloc_mpi, rmsloc_mpi
223
224    mloc=0.0; rmsloc=0.0
225    DO ind=1,ndomain
226      IF (.NOT. assigned_domain(ind) .OR. .NOT. is_omp_level_master) CYCLE
227      CALL swap_dimensions(ind)
228      CALL swap_geometry(ind)
229      dps=f_dps(ind) 
230      ps=f_ps(ind)
231      DO j=jj_begin,jj_end
232        DO i=ii_begin,ii_end
233          ij=(j-1)*iim+i
234          IF (domain(ind)%own(i,j)) THEN
235             mloc=mloc+ps(ij)*Ai(ij)
236             rmsloc=rmsloc+dps(ij)*dps(ij)
237          ENDIF
238        ENDDO
239      ENDDO
240    ENDDO
241   
242    CALL global_sum(mloc, mtot)
243    CALL global_sum(rmsloc, rmsdpdt)
244  END SUBROUTINE check_mass_conserve
245
246!---------------------------------------------------------------------
247
248  SUBROUTINE check_energy(f_ue,f_theta_rhodz,f_phis, etot, &
249                      stot, AAM_mass_tot, AAM_vel_tot, rmsvtot) 
250  USE pression_mod
251  USE vorticity_mod
252    TYPE(t_field), POINTER :: f_ue(:)
253    TYPE(t_field), POINTER :: f_theta_rhodz(:)
254    TYPE(t_field), POINTER :: f_phis(:)
255    REAL(rstd),INTENT(OUT) :: etot, stot, AAM_mass_tot, AAM_vel_tot, rmsvtot
256    REAL(rstd), POINTER :: ue(:,:)
257    REAL(rstd), POINTER :: p(:,:) 
258    REAL(rstd), POINTER :: theta_rhodz(:,:,:) 
259    REAL(rstd), POINTER :: pk(:,:) 
260    REAL(rstd), POINTER :: phis(:) 
261    REAL(rstd), POINTER :: rhodz(:,:) 
262    REAL(rstd) :: e, s, AAM_mass, AAM_vel, rmsv
263    INTEGER :: ind
264
265    e = 0 ; s = 0 ; AAM_mass = 0 ; AAM_vel=0 ; rmsv = 0
266
267    DO ind=1,ndomain 
268      IF (.NOT. assigned_domain(ind)) CYCLE
269      CALL swap_dimensions(ind)
270      CALL swap_geometry(ind)
271      ue=f_ue(ind) 
272      p=f_p(ind)
273      rhodz=f_rhodz(ind) 
274      theta_rhodz=f_theta_rhodz(ind) 
275      pk=f_pk(ind) 
276      phis=f_phis(ind) 
277      CALL compute_energy(ind,ue,p,rhodz,theta_rhodz(:,:,1),pk,phis, &
278           e, s, AAM_mass, AAM_vel, rmsv)
279    END DO
280
281    CALL global_sum(e, etot)
282    CALL global_sum(s, stot)
283    CALL global_sum(rmsv, rmsvtot)
284    CALL global_sum(AAM_mass, AAM_mass_tot)
285    CALL global_sum(AAM_vel, AAM_vel_tot)
286  END SUBROUTINE check_energy
287
288  SUBROUTINE compute_energy(ind,u,p,rhodz,theta_rhodz,pk,phis, e, s, AAM_mass, AAM_vel, rmsv)
289    USE disvert_mod
290    USE wind_mod
291    USE omp_para
292    INTEGER,INTENT(IN)::ind 
293    REAL(rstd),INTENT(IN) :: u(3*iim*jjm,llm)
294    REAL(rstd),INTENT(IN) :: p(iim*jjm,llm+1)
295    REAL(rstd),INTENT(IN) :: rhodz(iim*jjm,llm)
296    REAL(rstd),INTENT(IN) :: theta_rhodz(iim*jjm,llm)
297    REAL(rstd),INTENT(IN) :: pk(iim*jjm,llm)
298    REAL(rstd),INTENT(IN) :: phis(iim*jjm)
299    REAL(rstd),INTENT(INOUT) :: e, s, AAM_mass, AAM_vel, rmsv
300   
301    REAL(rstd) :: ucenter(iim*jjm,3,llm)
302    REAL(rstd) :: ulon(iim*jjm,llm)
303    REAL(rstd) :: ulat(iim*jjm,llm)
304   
305    REAL(rstd) :: mass_ij, theta_ij, KE_ij, rad,radomeg,lat
306    INTEGER :: i,j,ij,l
307   
308    CALL compute_wind_centered(u,ucenter)
309    CALL compute_wind_centered_lonlat_compound(ucenter,ulon,ulat)
310    rad = radius 
311    radomeg = rad*omega
312   
313    DO l = ll_begin,ll_end
314       DO j=jj_begin,jj_end
315          DO i=ii_begin,ii_end
316             ij=(j-1)*iim+i
317             IF (domain(ind)%own(i,j)) THEN
318                lat = lat_i(ij) 
319                mass_ij = rhodz(ij,l)*Ai(ij) 
320                theta_ij = theta_rhodz(ij,l)/rhodz(ij,l)
321                KE_ij = 1/(4*Ai(ij))*(le(ij+u_right)*de(ij+u_right)*u(ij+u_right,l)**2 +   &
322                     le(ij+u_rup)*de(ij+u_rup)*u(ij+u_rup,l)**2 +           &
323                     le(ij+u_lup)*de(ij+u_lup)*u(ij+u_lup,l)**2 +           &
324                     le(ij+u_left)*de(ij+u_left)*u(ij+u_left,l)**2 +        &
325                     le(ij+u_ldown)*de(ij+u_ldown)*u(ij+u_ldown,l)**2 +     &
326                     le(ij+u_rdown)*de(ij+u_rdown)*u(ij+u_rdown,l)**2 ) 
327                rmsv = rmsv + 2*mass_ij*KE_ij
328                s    = s + Ai(ij)*theta_rhodz(ij,l)
329                e    = e + mass_ij*(phis(ij)+theta_ij*pk(ij,l)+KE_ij)
330                AAM_mass = AAM_mass + rad*cos(lat)*mass_ij*radomeg*cos(lat)
331                AAM_vel  = AAM_vel  + rad*cos(lat)*mass_ij*ulon(ij,l)
332             END IF
333          END DO
334       END DO
335    END DO
336   
337  END SUBROUTINE compute_energy
338
339!---------------------------------------------------------------------
340 
341  SUBROUTINE check_PV(ztot)
342    REAL(rstd),INTENT(OUT) :: ztot
343    REAL(rstd), POINTER :: vort(:,:)
344    REAL(rstd), POINTER :: rhodz(:,:) 
345    INTEGER :: ind
346    REAL(rstd) :: z,z_mpi
347   
348    z=0
349    DO ind=1,ndomain 
350       IF (.NOT. assigned_domain(ind)) CYCLE
351       CALL swap_dimensions(ind)
352       CALL swap_geometry(ind)
353       vort=f_vort(ind)
354       rhodz=f_rhodz(ind) 
355       CALL compute_PV(vort,rhodz,z) 
356    ENDDO
357    CALL global_sum(z, ztot)
358  END SUBROUTINE check_PV 
359
360  SUBROUTINE compute_PV(vort,rhodz,z) 
361  USE disvert_mod
362  USE omp_para
363    REAL(rstd),INTENT(IN) :: vort(2*iim*jjm,llm)
364    REAL(rstd),INTENT(IN) :: rhodz(iim*jjm,llm) 
365    REAL(rstd),INTENT(INOUT) :: z
366    REAL(rstd)::qv1,qv2 
367    REAL(rstd)::hv1,hv2 
368    INTEGER :: i,j,ij,l,ij2
369
370    hv1 = 0.0 ; hv2 = 0.0 
371   
372    DO l = ll_begin,ll_end
373      DO j=jj_begin+1,jj_end-1
374        DO i=ii_begin+1,ii_end-1
375          ij=(j-1)*iim+i
376          hv1 =  Riv2(ij,vup)        * rhodz(ij,l)           &
377            + Riv2(ij+t_rup,vldown) * rhodz(ij+t_rup,l)     &
378            + Riv2(ij+t_lup,vrdown) * rhodz(ij+t_lup,l)
379   
380          qv1 = ( vort(ij+z_up,l)+fv(ij+z_up) )/hv1
381         
382          hv2  =  Riv2(ij,vdown)     * rhodz(ij,l)          &
383            + Riv2(ij+t_ldown,vrup) * rhodz(ij+t_ldown,l)  &
384            + Riv2(ij+t_rdown,vlup) * rhodz(ij+t_rdown,l)
385                     
386          qv2 =( vort(ij+z_down,l)+fv(ij+z_down) )/hv2
387
388          z = z + (qv1*qv1*hv1 + qv2*qv2*hv2) 
389
390        ENDDO
391      ENDDO
392     
393    ENDDO
394
395  END SUBROUTINE compute_PV
396!---------------------------------------------------------------------
397
398   SUBROUTINE compute_rhodz(p,rhodz) 
399     REAL(rstd),INTENT(IN) :: p(iim*jjm,llm+1)
400     REAL(rstd),INTENT(OUT):: rhodz(iim*jjm,llm)
401     REAL(rstd) ::mass(iim*jjm,llm)
402     INTEGER :: i,j,ij,l 
403       
404     DO l = 1, llm
405      DO j=jj_begin,jj_end
406       DO i=ii_begin,ii_end
407         ij=(j-1)*iim+i
408         mass(ij,l) = ( p(ij,l) - p(ij,l+1) ) * Ai(ij)/g
409         rhodz(ij,l) = mass(ij,l) / Ai(ij)
410       ENDDO
411      ENDDO
412     ENDDO
413
414   END SUBROUTINE compute_rhodz
415!====================================================================
416
417
418 END MODULE check_conserve_mod
Note: See TracBrowser for help on using the repository browser.