source: codes/icosagcm/trunk/src/caldyn_gcm.f90 @ 350

Last change on this file since 350 was 350, checked in by dubos, 9 years ago

Move geopotential to timeloop, prepare for prognostic geopotential (NH)
File size: 39.9 KB
Line 
1MODULE caldyn_gcm_mod
2  USE icosa
3  USE transfert_mod
4  IMPLICIT NONE
5  PRIVATE
6
7  INTEGER, PARAMETER :: energy=1, enstrophy=2
8  TYPE(t_field),POINTER :: f_out_u(:), f_qu(:), f_qv(:)
9  REAL(rstd),SAVE,POINTER :: out_u(:,:), p(:,:), qu(:,:)
10  !$OMP THREADPRIVATE(out_u, p, qu)
11
12  TYPE(t_field),POINTER :: f_buf_i(:), f_buf_ulon(:), f_buf_ulat(:), f_buf_u3d(:)
13  TYPE(t_field),POINTER :: f_buf_v(:), f_buf_s(:), f_buf_p(:)
14
15! temporary shared variable for caldyn
16  TYPE(t_field),POINTER :: f_theta(:)
17  TYPE(t_field),POINTER :: f_pk(:)
18  TYPE(t_field),POINTER :: f_wwuu(:)
19  TYPE(t_field),POINTER :: f_planetvel(:)
20   
21  INTEGER :: caldyn_conserv
22 !$OMP THREADPRIVATE(caldyn_conserv)
23 
24  TYPE(t_message) :: req_ps, req_mass, req_theta_rhodz, req_u, req_qu
25
26  PUBLIC init_caldyn, caldyn_BC, caldyn, write_output_fields, &
27       req_ps, req_mass
28
29CONTAINS
30 
31  SUBROUTINE init_caldyn
32    USE icosa
33    USE exner_mod
34    USE mpipara
35    USE omp_para
36    IMPLICIT NONE
37    CHARACTER(len=255) :: def
38    INTEGER            :: ind
39    REAL(rstd),POINTER :: planetvel(:)
40 
41    def='energy'
42    CALL getin('caldyn_conserv',def)
43    SELECT CASE(TRIM(def))
44    CASE('energy')
45       caldyn_conserv=energy
46    CASE('enstrophy')
47       caldyn_conserv=enstrophy
48    CASE DEFAULT
49       IF (is_mpi_root) PRINT *,'Bad selector for variable caldyn_conserv : <', &
50            TRIM(def),'> options are <energy>, <enstrophy>'
51       STOP
52    END SELECT
53    IF (is_master) PRINT *, 'caldyn_conserv=',def
54
55    CALL allocate_caldyn
56
57    DO ind=1,ndomain
58       IF (.NOT. assigned_domain(ind)) CYCLE
59       CALL swap_dimensions(ind)
60       CALL swap_geometry(ind)
61       planetvel=f_planetvel(ind)
62       CALL compute_planetvel(planetvel)
63    END DO
64
65  END SUBROUTINE init_caldyn
66
67  SUBROUTINE allocate_caldyn
68  USE icosa
69  IMPLICIT NONE
70
71    CALL allocate_field(f_out_u,field_u,type_real,llm) 
72    CALL allocate_field(f_qu,field_u,type_real,llm) 
73    CALL allocate_field(f_qv,field_z,type_real,llm) 
74 
75    CALL allocate_field(f_buf_i,   field_t,type_real,llm,name="buffer_i")
76    CALL allocate_field(f_buf_p,   field_t,type_real,llm+1) 
77    CALL allocate_field(f_buf_u3d, field_t,type_real,3,llm)  ! 3D vel at cell centers
78    CALL allocate_field(f_buf_ulon,field_t,type_real,llm)
79    CALL allocate_field(f_buf_ulat,field_t,type_real,llm)
80    CALL allocate_field(f_buf_v,   field_z,type_real,llm)
81    CALL allocate_field(f_buf_s,   field_t,type_real)
82
83    CALL allocate_field(f_theta, field_t,type_real,llm,  name='theta')   ! potential temperature
84    CALL allocate_field(f_pk,    field_t,type_real,llm,  name='pk')
85    CALL allocate_field(f_wwuu,  field_u,type_real,llm+1,name='wwuu')
86    CALL allocate_field(f_planetvel,  field_u,type_real, name='planetvel') ! planetary velocity at r=a
87
88  END SUBROUTINE allocate_caldyn
89
90  SUBROUTINE caldyn_BC(f_phis, f_geopot, f_wflux)
91    USE icosa
92    USE mpipara
93    USE omp_para
94    TYPE(t_field),POINTER :: f_phis(:)
95    TYPE(t_field),POINTER :: f_geopot(:)
96    TYPE(t_field),POINTER :: f_wflux(:)
97    REAL(rstd),POINTER  :: phis(:)
98    REAL(rstd),POINTER  :: wflux(:,:)
99    REAL(rstd),POINTER  :: geopot(:,:)
100    REAL(rstd),POINTER  :: wwuu(:,:)
101
102    INTEGER :: ind,i,j,ij,l
103
104    IF (is_omp_first_level) THEN
105       DO ind=1,ndomain
106          IF (.NOT. assigned_domain(ind)) CYCLE
107          CALL swap_dimensions(ind)
108          CALL swap_geometry(ind)
109          geopot=f_geopot(ind)
110          phis=f_phis(ind)
111          wflux=f_wflux(ind)
112          wwuu=f_wwuu(ind)
113         
114          DO ij=ij_begin_ext,ij_end_ext
115              ! lower BCs : geopot=phis, wflux=0, wwuu=0
116              geopot(ij,1) = phis(ij)
117              wflux(ij,1) = 0.
118              wwuu(ij+u_right,1)=0   
119              wwuu(ij+u_lup,1)=0   
120              wwuu(ij+u_ldown,1)=0
121              ! top BCs : wflux=0, wwuu=0
122              wflux(ij,llm+1)  = 0.
123              wwuu(ij+u_right,llm+1)=0   
124              wwuu(ij+u_lup,llm+1)=0   
125              wwuu(ij+u_ldown,llm+1)=0
126          ENDDO
127       END DO
128    ENDIF
129
130    !$OMP BARRIER
131  END SUBROUTINE caldyn_BC
132   
133  SUBROUTINE caldyn(write_out,f_phis, f_ps, f_mass, f_theta_rhodz, f_u, f_q, &
134       f_geopot, f_hflux, f_wflux, f_dps, f_dmass, f_dtheta_rhodz, f_du)
135    USE icosa
136    USE disvert_mod, ONLY : caldyn_eta, eta_mass
137    USE vorticity_mod
138    USE kinetic_mod
139    USE theta2theta_rhodz_mod
140    USE wind_mod
141    USE mpipara
142    USE trace
143    USE omp_para
144    USE output_field_mod
145    USE checksum_mod
146    IMPLICIT NONE
147    LOGICAL,INTENT(IN)    :: write_out
148    TYPE(t_field),POINTER :: f_phis(:)
149    TYPE(t_field),POINTER :: f_ps(:)
150    TYPE(t_field),POINTER :: f_mass(:)
151    TYPE(t_field),POINTER :: f_theta_rhodz(:)
152    TYPE(t_field),POINTER :: f_u(:)
153    TYPE(t_field),POINTER :: f_q(:)
154    TYPE(t_field),POINTER :: f_geopot(:)
155    TYPE(t_field),POINTER :: f_hflux(:), f_wflux(:)
156    TYPE(t_field),POINTER :: f_dps(:)
157    TYPE(t_field),POINTER :: f_dmass(:)
158    TYPE(t_field),POINTER :: f_dtheta_rhodz(:)
159    TYPE(t_field),POINTER :: f_du(:)
160   
161    REAL(rstd),POINTER :: ps(:), dps(:)
162    REAL(rstd),POINTER :: mass(:,:), theta_rhodz(:,:), dtheta_rhodz(:,:)
163    REAL(rstd),POINTER :: u(:,:), du(:,:), hflux(:,:), wflux(:,:)
164    REAL(rstd),POINTER :: qu(:,:)
165    REAL(rstd),POINTER :: qv(:,:)
166
167! temporary shared variable
168    REAL(rstd),POINTER  :: theta(:,:) 
169    REAL(rstd),POINTER  :: pk(:,:)
170    REAL(rstd),POINTER  :: geopot(:,:)
171    REAL(rstd),POINTER  :: convm(:,:) 
172    REAL(rstd),POINTER  :: wwuu(:,:)
173       
174    INTEGER :: ind
175    LOGICAL,SAVE :: first=.TRUE.
176!$OMP THREADPRIVATE(first)
177   
178    ! MPI messages need to be sent at first call to caldyn
179    ! This is needed only once : the next ones will be sent by timeloop
180    IF (first) THEN
181      first=.FALSE.
182      IF(caldyn_eta==eta_mass) THEN
183         CALL init_message(f_ps,req_i1,req_ps)
184      ELSE
185         CALL init_message(f_mass,req_i1,req_mass)
186      END IF
187      CALL init_message(f_theta_rhodz,req_i1,req_theta_rhodz)
188      CALL init_message(f_u,req_e1_vect,req_u)
189      CALL init_message(f_qu,req_e1_scal,req_qu)
190!      IF(caldyn_eta==eta_mass) THEN
191!         CALL send_message(f_ps,req_ps)
192!         CALL wait_message(req_ps) 
193!      ELSE
194!         CALL send_message(f_mass,req_mass)
195!         CALL wait_message(req_mass) 
196!      END IF
197    ENDIF
198   
199    CALL trace_start("caldyn")
200
201      IF(caldyn_eta==eta_mass) THEN
202         CALL send_message(f_ps,req_ps) 
203      ELSE
204         CALL send_message(f_mass,req_mass) 
205      END IF
206
207    CALL send_message(f_theta_rhodz,req_theta_rhodz) 
208    CALL send_message(f_u,req_u)
209
210    SELECT CASE(caldyn_conserv)
211    CASE(energy) ! energy-conserving
212       DO ind=1,ndomain
213          IF (.NOT. assigned_domain(ind)) CYCLE
214          CALL swap_dimensions(ind)
215          CALL swap_geometry(ind)
216          ps=f_ps(ind)
217          u=f_u(ind)
218          theta_rhodz = f_theta_rhodz(ind)
219          mass=f_mass(ind)
220          theta = f_theta(ind)
221          qu=f_qu(ind)
222          qv=f_qv(ind)
223          CALL compute_pvort(ps,u,theta_rhodz, mass,theta,qu,qv)
224       ENDDO
225!       CALL checksum(f_mass)
226!       CALL checksum(f_theta)
227
228       CALL send_message(f_qu,req_qu)
229!       CALL wait_message(req_qu)
230
231       DO ind=1,ndomain
232          IF (.NOT. assigned_domain(ind)) CYCLE
233          CALL swap_dimensions(ind)
234          CALL swap_geometry(ind)
235          ps=f_ps(ind)
236          u=f_u(ind)
237          theta_rhodz=f_theta_rhodz(ind)
238          mass=f_mass(ind)
239          theta = f_theta(ind)
240          qu=f_qu(ind)
241          pk = f_pk(ind)
242          geopot = f_geopot(ind) 
243          CALL compute_geopot(ps,mass,theta, pk,geopot)
244          hflux=f_hflux(ind)
245          convm = f_dmass(ind)
246          dtheta_rhodz=f_dtheta_rhodz(ind)
247          du=f_du(ind)
248          CALL compute_caldyn_horiz(u,mass,qu,theta,pk,geopot, hflux,convm,dtheta_rhodz,du)
249          IF(caldyn_eta==eta_mass) THEN
250             wflux=f_wflux(ind)
251             wwuu=f_wwuu(ind)
252             dps=f_dps(ind)
253             CALL compute_caldyn_vert(u,theta,mass,convm, wflux,wwuu, dps, dtheta_rhodz, du)
254          END IF
255       ENDDO       
256   
257!       CALL checksum(f_geopot)
258!       CALL checksum(f_dmass)
259!       CALL checksum(f_pk)
260!       CALL checksum(f_pk)
261       
262    CASE(enstrophy) ! enstrophy-conserving
263       DO ind=1,ndomain
264          IF (.NOT. assigned_domain(ind)) CYCLE
265          CALL swap_dimensions(ind)
266          CALL swap_geometry(ind)
267          ps=f_ps(ind)
268          u=f_u(ind)
269          theta_rhodz=f_theta_rhodz(ind)
270          mass=f_mass(ind)
271          theta = f_theta(ind)
272          qu=f_qu(ind)
273          qv=f_qv(ind)
274          CALL compute_pvort(ps,u,theta_rhodz, mass,theta,qu,qv)
275          pk = f_pk(ind)
276          geopot = f_geopot(ind) 
277          CALL compute_geopot(ps,mass,theta, pk,geopot)
278          hflux=f_hflux(ind)
279          convm = f_dmass(ind)
280          dtheta_rhodz=f_dtheta_rhodz(ind)
281          du=f_du(ind)
282          CALL compute_caldyn_horiz(u,mass,qu,theta,pk,geopot, hflux,convm,dtheta_rhodz,du)
283          IF(caldyn_eta==eta_mass) THEN
284             wflux=f_wflux(ind)
285             wwuu=f_wwuu(ind)
286             dps=f_dps(ind)
287             CALL compute_caldyn_vert(u,theta,mass,convm, wflux,wwuu, dps, dtheta_rhodz, du)
288          END IF
289       ENDDO
290       
291    CASE DEFAULT
292       STOP
293    END SELECT
294
295!$OMP BARRIER
296    IF (write_out) THEN
297
298       IF (is_master) PRINT *,'CALL write_output_fields'
299
300! ---> for openMP test to fix later
301!       CALL write_output_fields(f_ps, f_phis, f_dps, f_u, f_theta_rhodz, f_q, &
302!            f_buf_i, f_buf_v, f_buf_u3d, f_buf_ulon, f_buf_ulat, f_buf_s, f_buf_p)
303       CALL un2ulonlat(f_u, f_buf_ulon, f_buf_ulat)
304       CALL output_field("ulon",f_buf_ulon)
305       CALL output_field("ulat",f_buf_ulat)
306       CALL output_field("ps",f_ps)
307!       CALL output_field("dps",f_dps)
308!       CALL output_field("mass",f_mass)
309!       CALL output_field("dmass",f_dmass)
310       CALL output_field("vort",f_qv)
311       CALL output_field("theta",f_theta)
312!       CALL output_field("exner",f_pk)
313!       CALL output_field("pv",f_qv)
314 
315    END IF
316   
317    !    CALL check_mass_conservation(f_ps,f_dps)
318    CALL trace_end("caldyn")
319!!$OMP BARRIER
320   
321END SUBROUTINE caldyn
322
323SUBROUTINE compute_planetvel(planetvel)
324  USE wind_mod
325  REAL(rstd),INTENT(OUT)  :: planetvel(iim*3*jjm)
326  REAL(rstd) :: ulon(iim*3*jjm)
327  REAL(rstd) :: ulat(iim*3*jjm)
328  REAL(rstd) :: lon,lat
329  INTEGER :: ij
330  DO ij=ij_begin_ext,ij_end_ext
331     ulon(ij+u_right)=radius*omega*cos(lat_e(ij+u_right))
332     ulat(ij+u_right)=0
333
334     ulon(ij+u_lup)=radius*omega*cos(lat_e(ij+u_lup))
335     ulat(ij+u_lup)=0
336
337     ulon(ij+u_ldown)=radius*omega*cos(lat_e(ij+u_ldown))
338     ulat(ij+u_ldown)=0
339  END DO
340  CALL compute_wind2D_perp_from_lonlat_compound(ulon, ulat, planetvel)
341END SUBROUTINE compute_planetvel
342   
343SUBROUTINE compute_pvort(ps,u,theta_rhodz, rhodz,theta,qu,qv)
344  USE icosa
345  USE disvert_mod, ONLY : mass_dak, mass_dbk, caldyn_eta, eta_mass
346  USE exner_mod
347  USE trace
348  USE omp_para
349  IMPLICIT NONE
350  REAL(rstd),INTENT(IN)  :: u(iim*3*jjm,llm)
351  REAL(rstd),INTENT(IN)  :: ps(iim*jjm)
352  REAL(rstd),INTENT(IN)  :: theta_rhodz(iim*jjm,llm)
353  REAL(rstd),INTENT(INOUT) :: rhodz(iim*jjm,llm)
354  REAL(rstd),INTENT(OUT) :: theta(iim*jjm,llm)
355  REAL(rstd),INTENT(OUT) :: qu(iim*3*jjm,llm)
356  REAL(rstd),INTENT(OUT) :: qv(iim*2*jjm,llm)
357 
358  INTEGER :: i,j,ij,l
359  REAL(rstd) :: etav,hv, m
360!  REAL(rstd) :: qv(2*iim*jjm,llm)     ! potential velocity 
361 
362  CALL trace_start("compute_pvort") 
363
364  IF(caldyn_eta==eta_mass) THEN
365     CALL wait_message(req_ps) 
366  ELSE
367     CALL wait_message(req_mass)
368  END IF
369  CALL wait_message(req_theta_rhodz) 
370
371  IF(caldyn_eta==eta_mass) THEN ! Compute mass & theta
372     DO l = ll_begin,ll_end
373        CALL test_message(req_u) 
374!DIR$ SIMD
375        DO ij=ij_begin_ext,ij_end_ext
376           m = ( mass_dak(l)+ps(ij)*mass_dbk(l) )/g
377           rhodz(ij,l) = m
378           theta(ij,l) = theta_rhodz(ij,l)/rhodz(ij,l)
379        ENDDO
380     ENDDO
381  ELSE ! Compute only theta
382     DO l = ll_begin,ll_end
383        CALL test_message(req_u) 
384!DIR$ SIMD
385       DO ij=ij_begin_ext,ij_end_ext
386         theta(ij,l) = theta_rhodz(ij,l)/rhodz(ij,l)
387       ENDDO
388     ENDDO
389  END IF
390
391  CALL wait_message(req_u)   
392 
393!!! Compute shallow-water potential vorticity
394  DO l = ll_begin,ll_end
395!DIR$ SIMD
396     DO ij=ij_begin_ext,ij_end_ext
397          etav= 1./Av(ij+z_up)*(  ne_rup        * u(ij+u_rup,l)        * de(ij+u_rup)         &
398                                + ne_left * u(ij+t_rup+u_left,l) * de(ij+t_rup+u_left)  &
399                                - ne_lup        * u(ij+u_lup,l)        * de(ij+u_lup) )                               
400
401          hv =  Riv2(ij,vup)          * rhodz(ij,l)            &
402              + Riv2(ij+t_rup,vldown) * rhodz(ij+t_rup,l)     &
403              + Riv2(ij+t_lup,vrdown) * rhodz(ij+t_lup,l)
404     
405          qv(ij+z_up,l) = ( etav+fv(ij+z_up) )/hv
406         
407          etav = 1./Av(ij+z_down)*(  ne_ldown         * u(ij+u_ldown,l)          * de(ij+u_ldown)          &
408                                   + ne_right * u(ij+t_ldown+u_right,l)  * de(ij+t_ldown+u_right)  &
409                                   - ne_rdown         * u(ij+u_rdown,l)          * de(ij+u_rdown) )
410       
411          hv =  Riv2(ij,vdown)        * rhodz(ij,l)          &
412              + Riv2(ij+t_ldown,vrup) * rhodz(ij+t_ldown,l)  &
413              + Riv2(ij+t_rdown,vlup) * rhodz(ij+t_rdown,l)
414                       
415          qv(ij+z_down,l) =( etav+fv(ij+z_down) )/hv
416
417      ENDDO
418
419!DIR$ SIMD
420      DO ij=ij_begin,ij_end
421         qu(ij+u_right,l) = 0.5*(qv(ij+z_rdown,l)+qv(ij+z_rup,l)) 
422         qu(ij+u_lup,l) = 0.5*(qv(ij+z_up,l)+qv(ij+z_lup,l)) 
423         qu(ij+u_ldown,l) = 0.5*(qv(ij+z_ldown,l)+qv(ij+z_down,l)) 
424      END DO
425     
426   ENDDO
427
428   CALL trace_end("compute_pvort")
429                                                       
430  END SUBROUTINE compute_pvort
431 
432  SUBROUTINE compute_geopot(ps,rhodz,theta, pk,geopot) 
433  USE icosa
434  USE disvert_mod
435  USE exner_mod
436  USE trace
437  USE omp_para
438  IMPLICIT NONE
439    REAL(rstd),INTENT(INOUT) :: ps(iim*jjm)
440    REAL(rstd),INTENT(IN)    :: rhodz(iim*jjm,llm)
441    REAL(rstd),INTENT(IN)    :: theta(iim*jjm,llm)    ! potential temperature
442    REAL(rstd),INTENT(INOUT) :: pk(iim*jjm,llm)       ! Exner function
443    REAL(rstd),INTENT(INOUT) :: geopot(iim*jjm,llm+1) ! geopotential
444   
445    INTEGER :: i,j,ij,l
446    REAL(rstd) :: p_ik, exner_ik
447    INTEGER    :: ij_omp_begin_ext, ij_omp_end_ext
448
449
450    CALL trace_start("compute_geopot")
451   
452    CALL distrib_level(ij_end_ext-ij_begin_ext+1,ij_omp_begin_ext,ij_omp_end_ext)
453    ij_omp_begin_ext=ij_omp_begin_ext+ij_begin_ext-1
454    ij_omp_end_ext=ij_omp_end_ext+ij_begin_ext-1
455
456    IF(caldyn_eta==eta_mass) THEN
457
458!!! Compute exner function and geopotential
459         DO l = 1,llm
460          !DIR$ SIMD
461            DO ij=ij_omp_begin_ext,ij_omp_end_ext         
462               p_ik = ptop + mass_ak(l) + mass_bk(l)*ps(ij) ! FIXME : leave ps for the moment ; change ps to Ms later
463               !         p_ik = ptop + g*(mass_ak(l)+ mass_bk(l)*ps(i,j))
464               exner_ik = cpp * (p_ik/preff) ** kappa
465               pk(ij,l) = exner_ik
466             ! specific volume v = kappa*theta*pi/p = dphi/g/rhodz
467               geopot(ij,l+1) = geopot(ij,l) + (g*kappa)*rhodz(ij,l)*theta(ij,l)*exner_ik/p_ik
468          ENDDO
469         ENDDO
470!       ENDIF
471    ELSE 
472       ! We are using a Lagrangian vertical coordinate
473       ! Pressure must be computed first top-down (temporarily stored in pk)
474       ! Then Exner pressure and geopotential are computed bottom-up
475       ! Notice that the computation below should work also when caldyn_eta=eta_mass         
476
477       IF(boussinesq) THEN ! compute only geopotential : pressure pk will be computed in compute_caldyn_horiz
478          ! specific volume 1 = dphi/g/rhodz
479!         IF (is_omp_level_master) THEN ! no openMP on vertical due to dependency
480         DO l = 1,llm
481           !DIR$ SIMD
482           DO ij=ij_omp_begin_ext,ij_omp_end_ext         
483              geopot(ij,l+1) = geopot(ij,l) + g*rhodz(ij,l)
484           ENDDO
485         ENDDO
486       ELSE ! non-Boussinesq, compute geopotential and Exner pressure
487          ! uppermost layer
488
489         !DIR$ SIMD
490         DO ij=ij_omp_begin_ext,ij_omp_end_ext         
491            pk(ij,llm) = ptop + (.5*g)*rhodz(ij,llm)
492         END DO
493         ! other layers
494         DO l = llm-1, 1, -1
495            !DIR$ SIMD
496            DO ij=ij_omp_begin_ext,ij_omp_end_ext         
497               pk(ij,l) = pk(ij,l+1) + (.5*g)*(rhodz(ij,l)+rhodz(ij,l+1))
498            END DO
499         END DO
500        ! surface pressure (for diagnostics)
501         DO ij=ij_omp_begin_ext,ij_omp_end_ext         
502            ps(ij) = pk(ij,1) + (.5*g)*rhodz(ij,1)
503         END DO
504
505         ! specific volume v = kappa*theta*pi/p = dphi/g/rhodz
506         DO l = 1,llm
507           !DIR$ SIMD
508            DO ij=ij_omp_begin_ext,ij_omp_end_ext         
509               p_ik = pk(ij,l)
510               exner_ik = cpp * (p_ik/preff) ** kappa
511               geopot(ij,l+1) = geopot(ij,l) + (g*kappa)*rhodz(ij,l)*theta(ij,l)*exner_ik/p_ik 
512               pk(ij,l) = exner_ik
513            ENDDO
514          ENDDO
515       END IF
516
517    END IF
518
519!ym flush geopot
520!$OMP BARRIER
521
522  CALL trace_end("compute_geopot")
523
524  END SUBROUTINE compute_geopot
525
526  SUBROUTINE compute_caldyn_horiz(u,rhodz,qu,theta,pk,geopot, hflux,convm, dtheta_rhodz, du)
527  USE icosa
528  USE disvert_mod
529  USE exner_mod
530  USE trace
531  USE omp_para
532  IMPLICIT NONE
533    REAL(rstd),INTENT(IN)  :: u(iim*3*jjm,llm)    ! prognostic "velocity"
534    REAL(rstd),INTENT(IN)  :: rhodz(iim*jjm,llm)
535    REAL(rstd),INTENT(IN)  :: qu(iim*3*jjm,llm)
536    REAL(rstd),INTENT(IN)  :: theta(iim*jjm,llm)  ! potential temperature
537    REAL(rstd),INTENT(INOUT) :: pk(iim*jjm,llm) ! Exner function
538    REAL(rstd),INTENT(IN)  :: geopot(iim*jjm,llm+1)    ! geopotential
539
540    REAL(rstd),INTENT(OUT) :: hflux(iim*3*jjm,llm) ! hflux in kg/s
541    REAL(rstd),INTENT(OUT) :: convm(iim*jjm,llm)  ! mass flux convergence
542    REAL(rstd),INTENT(OUT) :: dtheta_rhodz(iim*jjm,llm)
543    REAL(rstd),INTENT(OUT) :: du(iim*3*jjm,llm)
544
545    REAL(rstd) :: cor_NT(iim*jjm,llm)  ! NT coriolis force u.(du/dPhi)
546    REAL(rstd) :: urel(3*iim*jjm,llm)  ! relative velocity
547    REAL(rstd) :: Ftheta(3*iim*jjm,llm) ! theta flux
548    REAL(rstd) :: berni(iim*jjm,llm)  ! Bernoulli function
549   
550    INTEGER :: i,j,ij,l
551    REAL(rstd) :: ww,uu
552
553    CALL trace_start("compute_caldyn_horiz")
554
555!    CALL wait_message(req_theta_rhodz)
556
557  DO l = ll_begin, ll_end
558!!!  Compute mass and theta fluxes
559    IF (caldyn_conserv==energy) CALL test_message(req_qu) 
560!DIR$ SIMD
561    DO ij=ij_begin_ext,ij_end_ext         
562        hflux(ij+u_right,l)=0.5*(rhodz(ij,l)+rhodz(ij+t_right,l))*u(ij+u_right,l)*le(ij+u_right)
563        hflux(ij+u_lup,l)=0.5*(rhodz(ij,l)+rhodz(ij+t_lup,l))*u(ij+u_lup,l)*le(ij+u_lup)
564        hflux(ij+u_ldown,l)=0.5*(rhodz(ij,l)+rhodz(ij+t_ldown,l))*u(ij+u_ldown,l)*le(ij+u_ldown)
565
566        Ftheta(ij+u_right,l)=0.5*(theta(ij,l)+theta(ij+t_right,l))*hflux(ij+u_right,l)
567        Ftheta(ij+u_lup,l)=0.5*(theta(ij,l)+theta(ij+t_lup,l))*hflux(ij+u_lup,l)
568        Ftheta(ij+u_ldown,l)=0.5*(theta(ij,l)+theta(ij+t_ldown,l))*hflux(ij+u_ldown,l)
569    ENDDO
570
571!!! compute horizontal divergence of fluxes
572!DIR$ SIMD
573    DO ij=ij_begin,ij_end         
574        ! convm = -div(mass flux), sign convention as in Ringler et al. 2012, eq. 21
575        convm(ij,l)= -1./Ai(ij)*(ne_right*hflux(ij+u_right,l)   +  &
576                                ne_rup*hflux(ij+u_rup,l)       +  & 
577                                ne_lup*hflux(ij+u_lup,l)       +  & 
578                                ne_left*hflux(ij+u_left,l)     +  & 
579                                ne_ldown*hflux(ij+u_ldown,l)   +  & 
580                                ne_rdown*hflux(ij+u_rdown,l))   
581
582        ! signe ? attention d (rho theta dz)
583        ! dtheta_rhodz =  -div(flux.theta)
584        dtheta_rhodz(ij,l)=-1./Ai(ij)*(ne_right*Ftheta(ij+u_right,l)    +  &
585                                 ne_rup*Ftheta(ij+u_rup,l)        +  & 
586                                 ne_lup*Ftheta(ij+u_lup,l)        +  & 
587                                 ne_left*Ftheta(ij+u_left,l)      +  & 
588                                 ne_ldown*Ftheta(ij+u_ldown,l)    +  & 
589                                 ne_rdown*Ftheta(ij+u_rdown,l))
590    ENDDO
591
592 END DO
593
594!!! Compute potential vorticity (Coriolis) contribution to du
595 
596    SELECT CASE(caldyn_conserv)
597    CASE(energy) ! energy-conserving TRiSK
598
599       CALL wait_message(req_qu)
600
601        DO l=ll_begin,ll_end
602!DIR$ SIMD
603          DO ij=ij_begin,ij_end         
604   
605                uu = wee(ij+u_right,1,1)*hflux(ij+u_rup,l)*(qu(ij+u_right,l)+qu(ij+u_rup,l))+                             &
606                     wee(ij+u_right,2,1)*hflux(ij+u_lup,l)*(qu(ij+u_right,l)+qu(ij+u_lup,l))+                             &
607                     wee(ij+u_right,3,1)*hflux(ij+u_left,l)*(qu(ij+u_right,l)+qu(ij+u_left,l))+                           &
608                     wee(ij+u_right,4,1)*hflux(ij+u_ldown,l)*(qu(ij+u_right,l)+qu(ij+u_ldown,l))+                         &
609                     wee(ij+u_right,5,1)*hflux(ij+u_rdown,l)*(qu(ij+u_right,l)+qu(ij+u_rdown,l))+                         & 
610                     wee(ij+u_right,1,2)*hflux(ij+t_right+u_ldown,l)*(qu(ij+u_right,l)+qu(ij+t_right+u_ldown,l))+         &
611                     wee(ij+u_right,2,2)*hflux(ij+t_right+u_rdown,l)*(qu(ij+u_right,l)+qu(ij+t_right+u_rdown,l))+         &
612                     wee(ij+u_right,3,2)*hflux(ij+t_right+u_right,l)*(qu(ij+u_right,l)+qu(ij+t_right+u_right,l))+         &
613                     wee(ij+u_right,4,2)*hflux(ij+t_right+u_rup,l)*(qu(ij+u_right,l)+qu(ij+t_right+u_rup,l))+             &
614                     wee(ij+u_right,5,2)*hflux(ij+t_right+u_lup,l)*(qu(ij+u_right,l)+qu(ij+t_right+u_lup,l))
615                du(ij+u_right,l) = .5*uu/de(ij+u_right)
616               
617                uu = wee(ij+u_lup,1,1)*hflux(ij+u_left,l)*(qu(ij+u_lup,l)+qu(ij+u_left,l)) +                        &
618                     wee(ij+u_lup,2,1)*hflux(ij+u_ldown,l)*(qu(ij+u_lup,l)+qu(ij+u_ldown,l)) +                      &
619                     wee(ij+u_lup,3,1)*hflux(ij+u_rdown,l)*(qu(ij+u_lup,l)+qu(ij+u_rdown,l)) +                      &
620                     wee(ij+u_lup,4,1)*hflux(ij+u_right,l)*(qu(ij+u_lup,l)+qu(ij+u_right,l)) +                      &
621                     wee(ij+u_lup,5,1)*hflux(ij+u_rup,l)*(qu(ij+u_lup,l)+qu(ij+u_rup,l)) +                          & 
622                     wee(ij+u_lup,1,2)*hflux(ij+t_lup+u_right,l)*(qu(ij+u_lup,l)+qu(ij+t_lup+u_right,l)) +          &
623                     wee(ij+u_lup,2,2)*hflux(ij+t_lup+u_rup,l)*(qu(ij+u_lup,l)+qu(ij+t_lup+u_rup,l)) +              &
624                     wee(ij+u_lup,3,2)*hflux(ij+t_lup+u_lup,l)*(qu(ij+u_lup,l)+qu(ij+t_lup+u_lup,l)) +              &
625                     wee(ij+u_lup,4,2)*hflux(ij+t_lup+u_left,l)*(qu(ij+u_lup,l)+qu(ij+t_lup+u_left,l)) +            &
626                     wee(ij+u_lup,5,2)*hflux(ij+t_lup+u_ldown,l)*(qu(ij+u_lup,l)+qu(ij+t_lup+u_ldown,l))
627                du(ij+u_lup,l) = .5*uu/de(ij+u_lup)
628
629               
630                uu = wee(ij+u_ldown,1,1)*hflux(ij+u_rdown,l)*(qu(ij+u_ldown,l)+qu(ij+u_rdown,l)) +                      &
631                     wee(ij+u_ldown,2,1)*hflux(ij+u_right,l)*(qu(ij+u_ldown,l)+qu(ij+u_right,l)) +                      &
632                     wee(ij+u_ldown,3,1)*hflux(ij+u_rup,l)*(qu(ij+u_ldown,l)+qu(ij+u_rup,l)) +                          &
633                     wee(ij+u_ldown,4,1)*hflux(ij+u_lup,l)*(qu(ij+u_ldown,l)+qu(ij+u_lup,l)) +                          &
634                     wee(ij+u_ldown,5,1)*hflux(ij+u_left,l)*(qu(ij+u_ldown,l)+qu(ij+u_left,l)) +                        & 
635                     wee(ij+u_ldown,1,2)*hflux(ij+t_ldown+u_lup,l)*(qu(ij+u_ldown,l)+qu(ij+t_ldown+u_lup,l)) +          &
636                     wee(ij+u_ldown,2,2)*hflux(ij+t_ldown+u_left,l)*(qu(ij+u_ldown,l)+qu(ij+t_ldown+u_left,l)) +        &
637                     wee(ij+u_ldown,3,2)*hflux(ij+t_ldown+u_ldown,l)*(qu(ij+u_ldown,l)+qu(ij+t_ldown+u_ldown,l)) +      &
638                     wee(ij+u_ldown,4,2)*hflux(ij+t_ldown+u_rdown,l)*(qu(ij+u_ldown,l)+qu(ij+t_ldown+u_rdown,l)) +      &
639                     wee(ij+u_ldown,5,2)*hflux(ij+t_ldown+u_right,l)*(qu(ij+u_ldown,l)+qu(ij+t_ldown+u_right,l))
640                du(ij+u_ldown,l) = .5*uu/de(ij+u_ldown)
641               
642          ENDDO
643       ENDDO
644       
645    CASE(enstrophy) ! enstrophy-conserving TRiSK
646 
647        DO l=ll_begin,ll_end
648!DIR$ SIMD
649          DO ij=ij_begin,ij_end         
650
651                uu = wee(ij+u_right,1,1)*hflux(ij+u_rup,l)+                           &
652                     wee(ij+u_right,2,1)*hflux(ij+u_lup,l)+                           &
653                     wee(ij+u_right,3,1)*hflux(ij+u_left,l)+                          &
654                     wee(ij+u_right,4,1)*hflux(ij+u_ldown,l)+                         &
655                     wee(ij+u_right,5,1)*hflux(ij+u_rdown,l)+                         & 
656                     wee(ij+u_right,1,2)*hflux(ij+t_right+u_ldown,l)+                 &
657                     wee(ij+u_right,2,2)*hflux(ij+t_right+u_rdown,l)+                 &
658                     wee(ij+u_right,3,2)*hflux(ij+t_right+u_right,l)+                 &
659                     wee(ij+u_right,4,2)*hflux(ij+t_right+u_rup,l)+                   &
660                     wee(ij+u_right,5,2)*hflux(ij+t_right+u_lup,l)
661                du(ij+u_right,l) = qu(ij+u_right,l)*uu/de(ij+u_right)
662               
663               
664                uu = wee(ij+u_lup,1,1)*hflux(ij+u_left,l)+                        &
665                     wee(ij+u_lup,2,1)*hflux(ij+u_ldown,l)+                       &
666                     wee(ij+u_lup,3,1)*hflux(ij+u_rdown,l)+                       &
667                     wee(ij+u_lup,4,1)*hflux(ij+u_right,l)+                       &
668                     wee(ij+u_lup,5,1)*hflux(ij+u_rup,l)+                         & 
669                     wee(ij+u_lup,1,2)*hflux(ij+t_lup+u_right,l)+                 &
670                     wee(ij+u_lup,2,2)*hflux(ij+t_lup+u_rup,l)+                   &
671                     wee(ij+u_lup,3,2)*hflux(ij+t_lup+u_lup,l)+                   &
672                     wee(ij+u_lup,4,2)*hflux(ij+t_lup+u_left,l)+                  &
673                     wee(ij+u_lup,5,2)*hflux(ij+t_lup+u_ldown,l)
674                du(ij+u_lup,l) = qu(ij+u_lup,l)*uu/de(ij+u_lup)
675
676                uu = wee(ij+u_ldown,1,1)*hflux(ij+u_rdown,l)+                      &
677                     wee(ij+u_ldown,2,1)*hflux(ij+u_right,l)+                      &
678                     wee(ij+u_ldown,3,1)*hflux(ij+u_rup,l)+                        &
679                     wee(ij+u_ldown,4,1)*hflux(ij+u_lup,l)+                        &
680                     wee(ij+u_ldown,5,1)*hflux(ij+u_left,l)+                       & 
681                     wee(ij+u_ldown,1,2)*hflux(ij+t_ldown+u_lup,l)+                &
682                     wee(ij+u_ldown,2,2)*hflux(ij+t_ldown+u_left,l)+               &
683                     wee(ij+u_ldown,3,2)*hflux(ij+t_ldown+u_ldown,l)+              &
684                     wee(ij+u_ldown,4,2)*hflux(ij+t_ldown+u_rdown,l)+              &
685                     wee(ij+u_ldown,5,2)*hflux(ij+t_ldown+u_right,l)
686                du(ij+u_ldown,l) = qu(ij+u_ldown,l)*uu/de(ij+u_ldown)
687     
688          ENDDO
689       ENDDO
690       
691    CASE DEFAULT
692       STOP
693    END SELECT
694 
695!!! Compute bernouilli term = Kinetic Energy + geopotential
696    IF(boussinesq) THEN
697       ! first use hydrostatic balance with theta*rhodz to find pk (Lagrange multiplier=pressure)
698       ! uppermost layer
699       !DIR$ SIMD
700       DO ij=ij_begin_ext,ij_end_ext         
701          pk(ij,llm) = ptop + (.5*g)*theta(ij,llm)*rhodz(ij,llm)
702       END DO
703       ! other layers
704       DO l = llm-1, 1, -1
705!          !$OMP DO SCHEDULE(STATIC)
706          !DIR$ SIMD
707          DO ij=ij_begin_ext,ij_end_ext         
708             pk(ij,l) = pk(ij,l+1) + (.5*g)*(theta(ij,l)*rhodz(ij,l)+theta(ij,l+1)*rhodz(ij,l+1))
709          END DO
710       END DO
711       ! surface pressure (for diagnostics) FIXME
712       ! DO ij=ij_begin_ext,ij_end_ext         
713       !   ps(ij) = pk(ij,1) + (.5*g)*theta(ij,1)*rhodz(ij,1)
714       ! END DO
715       ! now pk contains the Lagrange multiplier (pressure)
716
717       DO l=ll_begin,ll_end
718!DIR$ SIMD
719          DO ij=ij_begin,ij_end         
720               
721                berni(ij,l) = pk(ij,l) + &
722                       1/(4*Ai(ij))*(le(ij+u_right)*de(ij+u_right)*u(ij+u_right,l)**2 +    &
723                                     le(ij+u_rup)*de(ij+u_rup)*u(ij+u_rup,l)**2 +          &
724                                     le(ij+u_lup)*de(ij+u_lup)*u(ij+u_lup,l)**2 +          &
725                                     le(ij+u_left)*de(ij+u_left)*u(ij+u_left,l)**2 +       &
726                                     le(ij+u_ldown)*de(ij+u_ldown)*u(ij+u_ldown,l)**2 +    &
727                                     le(ij+u_rdown)*de(ij+u_rdown)*u(ij+u_rdown,l)**2 ) 
728                ! from now on pk contains the vertically-averaged geopotential
729                pk(ij,l) = .5*(geopot(ij,l)+geopot(ij,l+1))
730          ENDDO
731       ENDDO
732
733    ELSE ! compressible
734
735       DO l=ll_begin,ll_end
736!DIR$ SIMD
737            DO ij=ij_begin,ij_end         
738               
739                berni(ij,l) = .5*(geopot(ij,l)+geopot(ij,l+1)) &
740                     + 1/(4*Ai(ij))*(le(ij+u_right)*de(ij+u_right)*u(ij+u_right,l)**2 +    &
741                                     le(ij+u_rup)*de(ij+u_rup)*u(ij+u_rup,l)**2 +          &
742                                     le(ij+u_lup)*de(ij+u_lup)*u(ij+u_lup,l)**2 +          &
743                                     le(ij+u_left)*de(ij+u_left)*u(ij+u_left,l)**2 +       &
744                                     le(ij+u_ldown)*de(ij+u_ldown)*u(ij+u_ldown,l)**2 +    &
745                                     le(ij+u_rdown)*de(ij+u_rdown)*u(ij+u_rdown,l)**2 ) 
746          ENDDO
747       ENDDO
748
749    END IF ! Boussinesq/compressible
750
751!!! Add gradients of Bernoulli and Exner functions to du
752    DO l=ll_begin,ll_end
753!DIR$ SIMD
754       DO ij=ij_begin,ij_end         
755       
756             du(ij+u_right,l) = du(ij+u_right,l) + 1/de(ij+u_right) * (             &
757                               0.5*(theta(ij,l)+theta(ij+t_right,l))                &
758                                  *( ne_right*pk(ij,l)+ne_left*pk(ij+t_right,l))    &
759                                   + ne_right*berni(ij,l)+ne_left*berni(ij+t_right,l) )
760       
761       
762             du(ij+u_lup,l) = du(ij+u_lup,l) +  1/de(ij+u_lup) * (                  &
763                               0.5*(theta(ij,l)+theta(ij+t_lup,l))                  &
764                                  *( ne_lup*pk(ij,l)+ne_rdown*pk(ij+t_lup,l))       &
765                                   + ne_lup*berni(ij,l)+ne_rdown*berni(ij+t_lup,l) )
766               
767             du(ij+u_ldown,l) = du(ij+u_ldown,l) + 1/de(ij+u_ldown) * (             &
768                               0.5*(theta(ij,l)+theta(ij+t_ldown,l))                &
769                                  *( ne_ldown*pk(ij,l)+ne_rup*pk(ij+t_ldown,l))     &
770                                   + ne_ldown*berni(ij,l)+ne_rup*berni(ij+t_ldown,l) )
771
772       ENDDO
773    ENDDO
774 
775    CALL trace_end("compute_caldyn_horiz")
776
777END SUBROUTINE compute_caldyn_horiz
778
779SUBROUTINE compute_caldyn_vert(u,theta,rhodz,convm, wflux,wwuu, dps,dtheta_rhodz,du)
780  USE icosa
781  USE disvert_mod
782  USE exner_mod
783  USE trace
784  USE omp_para
785  IMPLICIT NONE
786    REAL(rstd),INTENT(IN)  :: u(iim*3*jjm,llm)
787    REAL(rstd),INTENT(IN)  :: theta(iim*jjm,llm)
788    REAL(rstd),INTENT(IN)  :: rhodz(iim*jjm,llm)
789    REAL(rstd),INTENT(INOUT)  :: convm(iim*jjm,llm)  ! mass flux convergence
790
791    REAL(rstd),INTENT(INOUT) :: wflux(iim*jjm,llm+1) ! vertical mass flux (kg/m2/s)
792    REAL(rstd),INTENT(INOUT) :: wwuu(iim*3*jjm,llm+1)
793    REAL(rstd),INTENT(INOUT) :: du(iim*3*jjm,llm)
794    REAL(rstd),INTENT(INOUT) :: dtheta_rhodz(iim*jjm,llm)
795    REAL(rstd),INTENT(OUT) :: dps(iim*jjm)
796
797! temporary variable   
798    INTEGER :: i,j,ij,l
799    REAL(rstd) :: p_ik, exner_ik
800    INTEGER    :: ij_omp_begin, ij_omp_end
801
802
803    CALL trace_start("compute_geopot")
804
805    CALL distrib_level(ij_end-ij_begin+1,ij_omp_begin,ij_omp_end)
806    ij_omp_begin=ij_omp_begin+ij_begin-1
807    ij_omp_end=ij_omp_end+ij_begin-1
808
809!    REAL(rstd) :: wwuu(iim*3*jjm,llm+1) ! tmp var, don't know why but gain 30% on the whole code in opemp
810                                        ! need to be understood
811
812!    wwuu=wwuu_out
813  CALL trace_start("compute_caldyn_vert")
814
815!$OMP BARRIER   
816!!! cumulate mass flux convergence from top to bottom
817!  IF (is_omp_level_master) THEN
818    DO  l = llm-1, 1, -1
819!    IF (caldyn_conserv==energy) CALL test_message(req_qu)
820
821!!$OMP DO SCHEDULE(STATIC)
822!DIR$ SIMD
823      DO ij=ij_omp_begin,ij_omp_end         
824          convm(ij,l) = convm(ij,l) + convm(ij,l+1)
825      ENDDO
826    ENDDO
827!  ENDIF
828
829!$OMP BARRIER
830! FLUSH on convm
831!!!!!!!!!!!!!!!!!!!!!!!!!
832
833! compute dps
834  IF (is_omp_first_level) THEN
835!DIR$ SIMD
836     DO ij=ij_begin,ij_end         
837        ! dps/dt = -int(div flux)dz
838        dps(ij) = convm(ij,1) * g 
839    ENDDO
840  ENDIF
841 
842!!! Compute vertical mass flux (l=1,llm+1 done by caldyn_BC)
843  DO l=ll_beginp1,ll_end
844!    IF (caldyn_conserv==energy) CALL test_message(req_qu)
845!DIR$ SIMD
846      DO ij=ij_begin,ij_end         
847        ! w = int(z,ztop,div(flux)dz) + B(eta)dps/dt
848        ! => w>0 for upward transport
849        wflux( ij, l ) = bp(l) * convm( ij, 1 ) - convm( ij, l ) 
850    ENDDO
851  ENDDO
852
853 !--> flush wflux 
854 !$OMP BARRIER
855
856  DO l=ll_begin,ll_endm1
857!DIR$ SIMD
858     DO ij=ij_begin,ij_end         
859        dtheta_rhodz(ij, l ) = dtheta_rhodz(ij, l )  -   0.5 * (  wflux(ij,l+1) * (theta(ij,l) + theta(ij,l+1)))
860    ENDDO
861  ENDDO
862 
863  DO l=ll_beginp1,ll_end
864!DIR$ SIMD
865      DO ij=ij_begin,ij_end         
866        dtheta_rhodz(ij, l ) = dtheta_rhodz(ij, l )  +   0.5 * ( wflux(ij,l  ) * (theta(ij,l-1) + theta(ij,l) ) )
867    ENDDO
868  ENDDO
869
870 
871! Compute vertical transport
872  DO l=ll_beginp1,ll_end
873!DIR$ SIMD
874      DO ij=ij_begin,ij_end         
875        wwuu(ij+u_right,l) = 0.5*( wflux(ij,l) + wflux(ij+t_right,l)) * (u(ij+u_right,l) - u(ij+u_right,l-1))
876        wwuu(ij+u_lup,l) = 0.5* ( wflux(ij,l) + wflux(ij+t_lup,l)) * (u(ij+u_lup,l) - u(ij+u_lup,l-1))
877        wwuu(ij+u_ldown,l) = 0.5*( wflux(ij,l) + wflux(ij+t_ldown,l)) * (u(ij+u_ldown,l) - u(ij+u_ldown,l-1))
878     ENDDO
879   ENDDO
880
881 !--> flush wwuu 
882 !$OMP BARRIER
883
884! Add vertical transport to du
885  DO l=ll_begin,ll_end
886!DIR$ SIMD
887     DO ij=ij_begin,ij_end         
888        du(ij+u_right, l )   = du(ij+u_right,l)  - (wwuu(ij+u_right,l+1)+ wwuu(ij+u_right,l)) / (rhodz(ij,l)+rhodz(ij+t_right,l))
889        du(ij+u_lup, l )     = du(ij+u_lup,l)    - (wwuu(ij+u_lup,l+1)  + wwuu(ij+u_lup,l))   / (rhodz(ij,l)+rhodz(ij+t_lup,l))
890        du(ij+u_ldown, l )   = du(ij+u_ldown,l)  - (wwuu(ij+u_ldown,l+1)+ wwuu(ij+u_ldown,l)) / (rhodz(ij,l)+rhodz(ij+t_ldown,l))
891    ENDDO
892  ENDDO     
893
894!  DO l=ll_beginp1,ll_end
895!!DIR$ SIMD
896!      DO ij=ij_begin,ij_end         
897!        wwuu_out(ij+u_right,l) = wwuu(ij+u_right,l)
898!        wwuu_out(ij+u_lup,l)   = wwuu(ij+u_lup,l)
899!        wwuu_out(ij+u_ldown,l) = wwuu(ij+u_ldown,l)
900!     ENDDO
901!   ENDDO
902 
903  CALL trace_end("compute_caldyn_vert")
904
905  END SUBROUTINE compute_caldyn_vert
906
907!-------------------------------- Diagnostics ----------------------------
908
909  SUBROUTINE check_mass_conservation(f_ps,f_dps)
910  USE icosa
911  USE mpipara
912  IMPLICIT NONE
913    TYPE(t_field),POINTER :: f_ps(:)
914    TYPE(t_field),POINTER :: f_dps(:)
915    REAL(rstd),POINTER :: ps(:)
916    REAL(rstd),POINTER :: dps(:)
917    REAL(rstd) :: mass_tot,dmass_tot
918    INTEGER :: ind,i,j,ij
919   
920    mass_tot=0
921    dmass_tot=0
922   
923    CALL transfert_request(f_dps,req_i1)
924    CALL transfert_request(f_ps,req_i1)
925
926    DO ind=1,ndomain
927      CALL swap_dimensions(ind)
928      CALL swap_geometry(ind)
929
930      ps=f_ps(ind)
931      dps=f_dps(ind)
932
933      DO j=jj_begin,jj_end
934        DO i=ii_begin,ii_end
935          ij=(j-1)*iim+i
936          IF (domain(ind)%own(i,j)) THEN
937            mass_tot=mass_tot+ps(ij)*Ai(ij)/g
938            dmass_tot=dmass_tot+dps(ij)*Ai(ij)/g
939          ENDIF
940        ENDDO
941      ENDDO
942   
943    ENDDO
944    IF (is_mpi_root) PRINT*, "mass_tot ", mass_tot,"      dmass_tot ",dmass_tot       
945
946  END SUBROUTINE check_mass_conservation 
947 
948  SUBROUTINE write_output_fields(f_ps, f_phis, f_dps, f_u, f_theta_rhodz, f_q, &
949       f_buf_i, f_buf_v, f_buf_i3, f_buf1_i, f_buf2_i, f_buf_s, f_buf_p)
950    USE icosa
951    USE vorticity_mod
952    USE theta2theta_rhodz_mod
953    USE pression_mod
954    USE omega_mod
955    USE write_field_mod
956    USE vertical_interp_mod
957    USE wind_mod
958    TYPE(t_field),POINTER :: f_ps(:), f_phis(:), f_u(:), f_theta_rhodz(:), f_q(:), f_dps(:), &
959         f_buf_i(:), f_buf_v(:), f_buf_i3(:), f_buf1_i(:), f_buf2_i(:), f_buf_s(:), f_buf_p(:)
960   
961    REAL(rstd) :: out_pression_level
962    CHARACTER(LEN=255) :: str_pression
963    CHARACTER(LEN=255) :: physics_type
964   
965    out_pression_level=0.
966    CALL getin("out_pression_level",out_pression_level) 
967    WRITE(str_pression,*) INT(out_pression_level/100)
968    str_pression=ADJUSTL(str_pression)
969   
970    CALL writefield("ps",f_ps)
971    CALL writefield("dps",f_dps)
972    CALL writefield("phis",f_phis)
973    CALL vorticity(f_u,f_buf_v)
974    CALL writefield("vort",f_buf_v)
975
976    CALL w_omega(f_ps, f_u, f_buf_i)
977    CALL writefield('omega', f_buf_i)
978    IF (out_pression_level<=preff .AND. out_pression_level > 0) THEN
979      CALL vertical_interp(f_ps,f_buf_i,f_buf_s,out_pression_level)
980      CALL writefield("omega"//TRIM(str_pression),f_buf_s)
981    ENDIF
982   
983    ! Temperature
984!    CALL theta_rhodz2temperature(f_ps,f_theta_rhodz,f_buf_i) ; ! FIXME
985     
986    CALL getin('physics',physics_type)
987    IF (TRIM(physics_type)=='dcmip') THEN
988      CALL Tv2T(f_buf_i,f_q,f_buf1_i) 
989      CALL writefield("T",f_buf1_i)
990      IF (out_pression_level<=preff .AND. out_pression_level > 0) THEN
991        CALL vertical_interp(f_ps,f_buf1_i,f_buf_s,out_pression_level)
992        CALL writefield("T"//TRIM(str_pression),f_buf_s)
993      ENDIF
994    ELSE
995      CALL writefield("T",f_buf_i)
996      IF (out_pression_level<=preff .AND. out_pression_level > 0) THEN
997        CALL vertical_interp(f_ps,f_buf_i,f_buf_s,out_pression_level)
998        CALL writefield("T"//TRIM(str_pression),f_buf_s)
999      ENDIF
1000    ENDIF
1001   
1002    ! velocity components
1003    CALL un2ulonlat(f_u, f_buf1_i, f_buf2_i)
1004    CALL writefield("ulon",f_buf1_i)
1005    CALL writefield("ulat",f_buf2_i)
1006
1007    IF (out_pression_level<=preff .AND. out_pression_level > 0) THEN
1008      CALL vertical_interp(f_ps,f_buf1_i,f_buf_s,out_pression_level)
1009      CALL writefield("ulon"//TRIM(str_pression),f_buf_s)
1010      CALL vertical_interp(f_ps,f_buf2_i,f_buf_s,out_pression_level)
1011      CALL writefield("ulat"//TRIM(str_pression),f_buf_s)
1012    ENDIF
1013   
1014    ! geopotential ! FIXME
1015    CALL thetarhodz2geopot(f_ps,f_phis,f_theta_rhodz, f_buf_s,f_buf_p,f_buf1_i,f_buf2_i,f_buf_i)
1016    CALL writefield("p",f_buf_p)
1017!    CALL writefield("phi",f_geopot)   ! geopotential
1018    CALL writefield("theta",f_buf1_i) ! potential temperature
1019    CALL writefield("pk",f_buf2_i)    ! Exner pressure
1020 
1021  END SUBROUTINE write_output_fields
1022 
1023  SUBROUTINE thetarhodz2geopot(f_ps,f_phis,f_theta_rhodz, f_pks,f_p,f_theta,f_pk,f_phi) 
1024    USE field_mod
1025    USE pression_mod
1026    USE exner_mod
1027    USE geopotential_mod
1028    USE theta2theta_rhodz_mod
1029    TYPE(t_field), POINTER :: f_ps(:), f_phis(:), f_theta_rhodz(:), &  ! IN
1030         f_pks(:), f_p(:), f_theta(:), f_pk(:), f_phi(:)               ! OUT
1031    REAL(rstd),POINTER :: pk(:,:), p(:,:), theta(:,:), theta_rhodz(:,:), &
1032         phi(:,:), phis(:), ps(:), pks(:)
1033    INTEGER :: ind
1034
1035    DO ind=1,ndomain
1036       IF (.NOT. assigned_domain(ind)) CYCLE
1037       CALL swap_dimensions(ind)
1038       CALL swap_geometry(ind)
1039       ps = f_ps(ind)
1040       p  = f_p(ind)
1041!$OMP BARRIER
1042       CALL compute_pression(ps,p,0)
1043       pk = f_pk(ind)
1044       pks = f_pks(ind)
1045!$OMP BARRIER
1046       CALL compute_exner(ps,p,pks,pk,0)
1047!$OMP BARRIER
1048       theta_rhodz = f_theta_rhodz(ind)
1049       theta = f_theta(ind)
1050       CALL compute_theta_rhodz2theta(ps, theta_rhodz,theta,0)
1051       phis = f_phis(ind)
1052       phi = f_phi(ind)
1053       CALL compute_geopotential(phis,pks,pk,theta,phi,0)
1054    END DO
1055
1056  END SUBROUTINE thetarhodz2geopot
1057 
1058  SUBROUTINE Tv2T(f_Tv, f_q, f_T)
1059  USE icosa
1060  IMPLICIT NONE
1061    TYPE(t_field), POINTER :: f_TV(:)
1062    TYPE(t_field), POINTER :: f_q(:)
1063    TYPE(t_field), POINTER :: f_T(:)
1064   
1065    REAL(rstd),POINTER :: Tv(:,:), q(:,:,:), T(:,:)
1066    INTEGER :: ind
1067   
1068    DO ind=1,ndomain
1069       IF (.NOT. assigned_domain(ind)) CYCLE
1070       CALL swap_dimensions(ind)
1071       CALL swap_geometry(ind)
1072       Tv=f_Tv(ind)
1073       q=f_q(ind)
1074       T=f_T(ind)
1075       T=Tv/(1+0.608*q(:,:,1))
1076    END DO
1077   
1078  END SUBROUTINE Tv2T
1079 
1080END MODULE caldyn_gcm_mod
Note: See TracBrowser for help on using the repository browser.