source: codes/icosagcm/devel/src/unstructured/data_unstructured.F90 @ 837

Last change on this file since 837 was 837, checked in by dubos, 5 years ago

devel : Cp(T) thermodynamics (TBC)
File size: 10.4 KB
Line 
1MODULE data_unstructured_mod
2  USE ISO_C_BINDING
3  USE earth_const, ONLY : thermo_theta
4  USE mpipara, ONLY : is_mpi_master
5  USE grid_param, ONLY : llm, nqdyn
6#ifdef CPP_USING_OMP
7  USE OMP_LIB
8#endif
9  IMPLICIT NONE
10  SAVE
11
12
13#include "unstructured.h90"
14
15  INTEGER, PARAMETER :: eta_mass=1, eta_lag=2, &
16       caldyn_vert_cons=1, max_nb_stage=5
17  INDEX,  BIND(C) :: caldyn_eta=eta_lag, &
18       caldyn_vert_variant=caldyn_vert_cons, nb_threads=0, nb_stage=0
19  LOGICAL(C_BOOL), BIND(C) :: hydrostatic=.TRUE., debug_on=.FALSE.
20  LOGICAL(C_BOOL), BIND(C, NAME='debug_hevi_solver') :: debug_hevi_solver_=.TRUE.
21
22#ifdef CPP_MIXED_PREC
23  LOGICAL(C_BOOL), BIND(C) :: mixed_precision=.TRUE.
24#else
25  LOGICAL(C_BOOL), BIND(C) :: mixed_precision=.FALSE.
26#endif
27
28  INDEX, BIND(C) :: edge_num, primal_num, dual_num, &
29       max_primal_deg, max_dual_deg, max_trisk_deg
30  INDEX, ALLOCATABLE :: & ! deg(ij) = nb of vertices = nb of edges of primal/dual cell ij
31       primal_deg(:), primal_edge(:,:), primal_vertex(:,:), primal_ne(:,:), & 
32       dual_deg(:), dual_edge(:,:), dual_vertex(:,:), dual_ne(:,:), &
33       trisk_deg(:), trisk(:,:), &
34       left(:), right(:), up(:), down(:)
35  ! left and right are adjacent primal cells
36  ! flux is positive when going from left to right
37  ! up and down are adjacent dual cells
38  ! circulation is positive when going from down to up
39
40  TIME, PARAMETER :: print_trace_interval = 1.
41  TIME, BIND(C) :: elapsed
42  NUM, BIND(C) :: ptop, pbot, Phi_bot, rho_bot
43  NUM1(max_nb_stage), BIND(C)              :: tauj       ! diagonal of fast Butcher tableau
44  NUM2(max_nb_stage,max_nb_stage), BIND(C) :: cslj, cflj ! slow and fast modified Butcher tableaus
45  NUM1(:), ALLOCATABLE            :: le, le_de, fv, Av, Ai
46  NUM2(:,:), ALLOCATABLE          :: centroid, xyz_v, Riv2, wee, ap,bp, mass_bl, mass_dak, mass_dbk
47
48  INTEGER(C_INT), BIND(C) :: comm_icosa
49
50  INTEGER, PARAMETER :: id_dev1=1, id_dev2=2, &
51       id_pvort_only=3, id_slow_hydro=4, id_fast=5, id_coriolis=6, id_theta=7, id_geopot=8, id_vert=9, &
52       id_solver=10, id_slow_NH=11, id_NH_geopot=12, id_vert_NH=13, id_update=14, id_halo=15, &
53       id_scalar_laplacian=16, nb_routines=16 
54  TIME, PRIVATE :: start_time, time_spent(nb_routines) ! time spent in each kernel
55  INTEGER, PRIVATE :: current_id, nb_calls(nb_routines)
56  INTEGER(KIND=8), PRIVATE :: bytes(nb_routines) ! bytes read or written by each kernel
57  CHARACTER(len = 10) :: id_name(nb_routines) = &
58       (/'dev1      ', 'dev2      ', &
59       'pvort_only', 'slow_hydro', 'fast      ', 'coriolis  ', 'theta     ', 'geopot    ', 'vert      ', &
60       'solver    ', 'slow_NH   ', 'NH_geopot ', 'vert_NH   ',  'update    ', 'halo_xchg ', 'scalar_lap' /)
61
62  INTEGER, PARAMETER ::transfer_primal=1, transfer_edge=2, transfer_dual=3, transfer_max=3
63  TYPE Halo_transfer
64     INTEGER :: ranks ! size of arrays rank, len
65     INTEGER, ALLOCATABLE :: rank(:), & ! MPI ranks to communicate with
66          num(:), & ! number of cells to send to / receive from other MPI ranks
67          cells(:) ! local indices of cells to send/receive
68     NUM, ALLOCATABLE :: buf2(:,:)
69  END TYPE Halo_transfer
70  TYPE(Halo_transfer), TARGET :: send_info(transfer_max), recv_info(transfer_max)
71
72CONTAINS
73
74  !----------------------------      PROFILING      --------------------------
75
76#ifndef CPP_USING_OMP
77  FUNCTION omp_get_wtime()
78    TIME :: omp_get_wtime
79    CALL CPU_TIME(omp_get_wtime)
80  END FUNCTION omp_get_wtime
81
82  FUNCTION omp_get_num_procs()
83    INTEGER :: omp_get_num_procs
84    omp_get_num_procs=1
85  END FUNCTION omp_get_num_procs
86
87  FUNCTION omp_get_max_threads()
88    INTEGER :: omp_get_max_threads
89    omp_get_max_threads=1
90  END FUNCTION omp_get_max_threads
91#endif
92
93  SUBROUTINE init_trace()
94    !$OMP MASTER
95    time_spent(:)=0.
96    bytes(:)=0
97    nb_calls(:)=0
98    !$OMP END MASTER
99  END SUBROUTINE init_trace
100
101  SUBROUTINE print_trace_() BIND(C, name='dynamico_print_trace')
102    INTEGER :: id
103    TIME :: total_spent
104    total_spent=SUM(time_spent)
105    IF(is_mpi_master) THEN
106       PRINT *, '========================= Performance metrics ========================='
107       PRINT *, 'Total time spent in instrumented code (seconds) :', total_spent
108       PRINT *, 'Name, #calls, %time, microsec/call, MB/sec'   
109       DO id=1,nb_routines
110          IF(nb_calls(id)>0) PRINT *, id_name(id), nb_calls(id), INT(100.*time_spent(id)/total_spent), &
111               INT(1e6*time_spent(id)/nb_calls(id)), INT(1e-6*bytes(id)/time_spent(id))
112       END DO
113    END IF
114  END SUBROUTINE print_trace_
115
116  SUBROUTINE print_trace()
117    !$OMP MASTER
118       IF(SUM(time_spent)>print_trace_interval) THEN
119          CALL print_trace_
120          CALL init_trace()
121       END IF
122    !$OMP END MASTER
123  END SUBROUTINE print_trace
124
125  SUBROUTINE enter_trace(id, nbytes)
126    INTEGER :: id, nbytes
127    !$OMP MASTER
128    current_id = id
129    bytes(id) = bytes(id) + nbytes
130    nb_calls(id)=nb_calls(id)+1
131    start_time = OMP_GET_WTIME()
132    !$OMP END MASTER
133  END SUBROUTINE enter_trace
134
135  SUBROUTINE exit_trace()
136    TIME :: elapsed
137    !$OMP MASTER
138    elapsed = OMP_GET_WTIME()-start_time
139    IF(elapsed<0.) elapsed=0.
140    time_spent(current_id) = time_spent(current_id) + elapsed
141    !$OMP END MASTER
142  END SUBROUTINE exit_trace
143
144  !---------------------------- CONTEXT INITIALIZATION --------------------------
145
146#define ALLOC1(v,n1) IF(ALLOCATED(v)) DEALLOCATE(v) ; ALLOCATE(v(n1))
147#define ALLOC2(v,n1,n2) IF(ALLOCATED(v)) DEALLOCATE(v) ; ALLOCATE(v(n1,n2))
148
149  SUBROUTINE init_mesh( & 
150       primal_deg_, primal_edge_, primal_ne_, &
151       dual_deg_, dual_edge_, dual_ne_, dual_vertex_, &
152       left_, right_, up_, down_ ,&
153       trisk_deg_, trisk_) BINDC(init_mesh)
154    INDEX :: primal_deg_(primal_num), primal_edge_(max_primal_deg,primal_num), &
155         primal_ne_(max_primal_deg,primal_num), &
156         dual_deg_(dual_num), dual_edge_(max_dual_deg,dual_num), &
157         dual_ne_(max_dual_deg,dual_num), &
158         dual_vertex_(max_dual_deg,dual_num), &
159         trisk_deg_(edge_num), trisk_(max_trisk_deg, edge_num)
160    INDEX, DIMENSION(edge_num) :: left_, right_, down_, up_
161
162    IF(is_mpi_master) THEN
163       PRINT *, 'init_mesh ...'
164       PRINT *, 'Primal mesh : ', primal_num, max_primal_deg
165       PRINT *, 'Dual mesh   : ', dual_num, max_dual_deg
166       PRINT *, '       Edge mesh   : ', edge_num, max_trisk_deg
167       PRINT *, 'Vertical levels :', llm
168    END IF
169    ALLOC1(primal_deg, primal_num)
170    ALLOC2(primal_edge, max_primal_deg,primal_num)
171    ALLOC2(primal_ne, max_primal_deg,primal_num)
172    ALLOC1(dual_deg,dual_num)
173    ALLOC2(dual_edge, max_dual_deg,dual_num)
174    ALLOC2(dual_ne, max_dual_deg,dual_num)
175    ALLOC2(dual_vertex, max_dual_deg,dual_num)
176    ALLOC1(trisk_deg, edge_num)
177    ALLOC2(trisk, max_trisk_deg, edge_num)
178    ALLOC1(left, edge_num)
179    ALLOC1(right, edge_num)
180    ALLOC1(up, edge_num)
181    ALLOC1(down, edge_num)
182    primal_deg(:) = primal_deg_(:)
183    primal_edge(:,:) = primal_edge_(:,:)
184    primal_ne(:,:) = primal_ne_(:,:)
185    dual_deg(:) = dual_deg_(:)
186    dual_edge(:,:) = dual_edge_(:,:)
187    dual_ne(:,:) = dual_ne_(:,:)
188    dual_vertex(:,:) = dual_vertex_(:,:)
189    IF(MINVAL(dual_deg)<2) THEN
190       STOP 'At least one dual cell has less than 2 vertices'
191    END IF
192    IF(MINVAL(primal_deg)<2) THEN
193       STOP 'At least one primal cell has less than 2 vertices'
194    END IF
195    left(:)=left_(:)
196    right(:)=right_(:)
197    down(:)=down_(:)
198    up=up_(:)
199    trisk_deg(:)=trisk_deg_(:)
200    trisk(:,:)=trisk_(:,:)
201    IF(is_mpi_master) THEN
202       PRINT *, MAXVAL(primal_edge), edge_num
203       PRINT *, MAXVAL(dual_edge), edge_num
204       PRINT *, MAXVAL(dual_vertex), dual_num
205       PRINT *, MAXVAL(trisk), edge_num
206       PRINT *, MAX(MAXVAL(left),MAXVAL(right)), primal_num
207       PRINT *, MAX(MAXVAL(up),MAXVAL(down)), dual_num
208       PRINT *, SHAPE(trisk), edge_num
209       PRINT *,' ... Done.'
210    END IF
211  END SUBROUTINE init_mesh
212
213  ! Input arrays to init_metric and init_hybrid are declared DBL
214  ! => always float64 on the Python side
215  ! They are copied to Fortran arrays of type NUM (float or double)
216
217  SUBROUTINE init_metric(Ai_, Av_, fv_, le_de_, Riv2_, wee_) BINDC(init_metric)
218    DBL :: Ai_(primal_num), Av_(dual_num), fv_(dual_num), le_de_(edge_num), &
219         Riv2_(max_dual_deg,dual_num), wee_(max_trisk_deg,edge_num)
220    IF(is_mpi_master) PRINT *, 'init_metric ...'
221    ALLOC1(Ai,primal_num)
222    ALLOC1(Av,dual_num)
223    ALLOC1(fv,dual_num)
224    ALLOC1(le_de,edge_num)
225    ALLOC2(Riv2, max_dual_deg, dual_num)
226    ALLOC2(wee, max_trisk_deg, edge_num)
227    Ai(:) = Ai_(:)
228    Av(:) = Av_(:)
229    fv(:) = fv_(:)
230    le_de(:) = le_de_(:)
231    Riv2(:,:)=Riv2_(:,:)
232    wee(:,:) = wee_(:,:)
233    IF(is_mpi_master) THEN
234       PRINT *, 'Max Ai : ',    MAXVAL(ABS(Ai))
235       PRINT *, 'Max Av : ',    MAXVAL(ABS(Av))
236       PRINT *, 'Max fv : ',    MAXVAL(ABS(fv))
237       PRINT *, 'Max le_de : ', MAXVAL(ABS(le_de))
238       PRINT *, 'Max Riv2 : ',  MAXVAL(ABS(Riv2))
239       PRINT *, 'Max wee : ',   MAXVAL(ABS(wee))
240       PRINT *, MINVAL(right),  MAXVAL(right)
241       PRINT *, MINVAL(right),  MAXVAL(left)
242       PRINT *,' ... Done.'
243       IF(nb_threads==0) nb_threads=OMP_GET_MAX_THREADS()
244       PRINT *,'OpenMP : max_threads, num_procs, nb_threads', OMP_GET_MAX_THREADS(), OMP_GET_NUM_PROCS(), nb_threads
245    END IF
246  END SUBROUTINE init_metric
247  !
248  SUBROUTINE show_openmp() BINDC(show_openmp)
249    PRINT *,'OpenMP : max_threads, num_procs', OMP_GET_MAX_THREADS(), OMP_GET_NUM_PROCS()
250  END SUBROUTINE show_openmp
251  !
252  SUBROUTINE init_params() BINDC(init_params)
253    USE earth_const
254    kappa = Rd/cpp
255    IF(is_mpi_master) THEN
256       PRINT *, 'Setting physical parameters ...'
257       IF(hydrostatic) THEN
258          PRINT *, 'Hydrostatic dynamics (HPE)'
259       ELSE
260          PRINT *, 'Non-hydrostatic dynamics (Euler)'
261       END IF
262       PRINT *, 'g = ',g
263       PRINT *, 'preff = ',preff
264       PRINT *, 'Treff = ',Treff
265       PRINT *, 'Rd = ',Rd
266       PRINT *, 'cpp = ',cpp
267       PRINT *, 'kappa = ',kappa
268       PRINT *, '... Done'
269    END IF
270    CALL init_trace
271  END SUBROUTINE init_params
272  !
273  SUBROUTINE init_hybrid(bl,dak,dbk) BINDC(init_hybrid)
274    DBL :: bl(llm+1, primal_num), &
275         dak(llm, primal_num), dbk(llm, primal_num)
276    IF(is_mpi_master) PRINT *, 'Setting hybrid coefficients ...'
277    ALLOC2(mass_bl, llm+1, primal_num)
278    ALLOC2(mass_dak, llm, primal_num)
279    ALLOC2(mass_dbk, llm, primal_num)
280    mass_bl(:,:)  = bl(:,:)
281    mass_dak(:,:) = dak(:,:)
282    mass_dbk(:,:) = dbk(:,:)
283    IF(is_mpi_master) PRINT *, '... Done, llm = ', llm
284  END SUBROUTINE Init_hybrid
285
286END MODULE data_unstructured_mod
Note: See TracBrowser for help on using the repository browser.