MODULE compute_NH_geopot_mod
  USE grid_param
  IMPLICIT NONE
  PRIVATE

  LOGICAL, SAVE :: debug_hevi_solver = .FALSE.

#include "../unstructured/unstructured.h90"

  PUBLIC :: compute_NH_geopot,compute_NH_geopot_unst

CONTAINS

#ifdef BEGIN_DYSL

KERNEL(compute_NH_geopot)
  tau2_g=tau*tau/g
  g2=g*g
  gm2 = 1./g2
  vreff = Treff*cpp/preff*kappa
  gamma = 1./(1.-kappa)

  BARRIER

  ! compute Phi_star
  SEQUENCE_C1
    BODY('1,llm+1')
      Phi_star_il(CELL) = Phi_il(CELL) + tau*g2*(W_il(CELL)/m_il(CELL)-tau)
    END_BLOCK
  END_BLOCK

  ! Newton-Raphson iteration : Phi_il contains current guess value
  DO iter=1,2 ! 2 iterations should be enough
    ! Compute pressure, A_ik
    SELECT CASE(caldyn_thermo)
    CASE(thermo_theta)
      {% call() compute_p_and_Aik() %}
        X_ij = (cpp/preff)*kappa*theta(CELL)*rho_ij
        p_ik(CELL) = preff*(X_ij**gamma)
        c2_mik = gamma*p_ik(CELL)/(rho_ij*m_ik(CELL)) ! c^2 = gamma*R*T = gamma*p/rho
      {% endcall %}
    CASE(thermo_entropy)
      {% call() compute_p_and_Aik() %}
        X_ij = log(vreff*rho_ij) + theta(CELL)/cpp
        p_ik(CELL) = preff*exp(X_ij*gamma)
        c2_mik = gamma*p_ik(CELL)/(rho_ij*m_ik(CELL)) ! c^2 = gamma*R*T = gamma*p/rho
      {% endcall %}
    CASE DEFAULT
        PRINT *, 'caldyn_thermo not supported by compute_NH_geopot', caldyn_thermo
        STOP
    END SELECT

    ! NB : A(1), A(llm), R(1), R(llm+1) = 0 => x(l)=0 at l=1,llm+1 => flat, rigid top and bottom
    ! Solve -A(l-1)x(l-1) + B(l)x(l) - A(l)x(l+1) = R(l) using Thomas algorithm

    SEQUENCE_C1
      ! Compute residual R_il and B_il
      PROLOGUE(1)
        ! bottom interface l=1
        ml_g2 = gm2*m_il(CELL)
        B_il(CELL) = A_ik(CELL) + ml_g2 + tau2_g*rho_bot
        R_il(CELL) = ml_g2*( Phi_il(CELL)-Phi_star_il(CELL))  &
                  + tau2_g*( p_ik(CELL)-pbot+rho_bot*(Phi_il(CELL)-PHI_BOT(HIDX(CELL))) )
      END_BLOCK
      BODY('2,llm')
        ! inner interfaces
        ml_g2 = gm2*m_il(CELL)
        B_il(CELL) = A_ik(CELL)+A_ik(DOWN(CELL)) + ml_g2
        R_il(CELL) = ml_g2*( Phi_il(CELL)-Phi_star_il(CELL))  &
                  + tau2_g*(p_ik(CELL)-p_ik(DOWN(CELL)))
        ! consistency check : if Wil=0 and initial state is in hydrostatic balance
        ! then Phi_star_il(CELL) = Phi_il(CELL) - tau^2*g^2
        ! and residual = tau^2*(ml+(1/g)dl_pi)=0
      END_BLOCK
      EPILOGUE('llm+1')
        ! top interface l=llm+1
        ml_g2 = gm2*m_il(CELL)
        B_il(CELL) = A_ik(DOWN(CELL)) + ml_g2
        R_il(CELL) = ml_g2*( Phi_il(CELL)-Phi_star_il(CELL))  &
                  + tau2_g*( ptop-p_ik(DOWN(CELL)) )
      END_BLOCK
      !
      ! Forward sweep :
      ! C(0)=0, C(l) = -A(l) / (B(l)+A(l-1)C(l-1)),
      ! D(0)=0, D(l) = (R(l)+A(l-1)D(l-1)) / (B(l)+A(l-1)C(l-1))
      PROLOGUE(1)
        X_ij = 1./B_il(CELL)
        C_ik(CELL) = -A_ik(CELL) * X_ij
        D_il(CELL) =  R_il(CELL) * X_ij
      END_BLOCK
      BODY('2,llm')
        X_ij = 1./( B_il(CELL) + A_ik(DOWN(CELL))*C_ik(DOWN(CELL)) )
        C_ik(CELL) = -A_ik(CELL) * X_ij
        D_il(CELL) =  (R_il(CELL)+A_ik(DOWN(CELL))*D_il(DOWN(CELL))) * X_ij
      END_BLOCK
      EPILOGUE('llm+1')
        X_ij = 1./( B_il(CELL) + A_ik(DOWN(CELL))*C_ik(DOWN(CELL)) )
        D_il(CELL) =  (R_il(CELL)+A_ik(DOWN(CELL))*D_il(DOWN(CELL))) * X_ij
        ! Back substitution :
        ! x(i) = D(i)-C(i)x(i+1), x(llm+1)=0
        ! + Newton-Raphson update
        ! top interface l=llm+1
        x_il(CELL) = D_il(CELL)
        Phi_il(CELL) = Phi_il(CELL) - x_il(CELL)
      END_BLOCK
      BODY('llm,1,-1')
        ! Back substitution at lower interfaces
        x_il(CELL) = D_il(CELL) - C_ik(CELL)*x_il(UP(CELL))
        Phi_il(CELL) = Phi_il(CELL) - x_il(CELL)
      END_BLOCK
    END_BLOCK

    IF(debug_hevi_solver) THEN
       PRINT *, '[hevi_solver] A,B', iter, MAXVAL(ABS(A_ik)),MAXVAL(ABS(B_il))
       PRINT *, '[hevi_solver] C,D', iter, MAXVAL(ABS(C_ik)),MAXVAL(ABS(D_il))
       DO l=1,llm+1
          WRITE(*,'(A,I2.1,I3.2,E9.2)') '[hevi_solver] x_il', iter,l, MAXVAL(ABS(x_il(l,:)))
       END DO
       DO l=1,llm+1
          WRITE(*,'(A,I2.1,I3.2,E9.2)') '[hevi_solver] R_il', iter,l, MAXVAL(ABS(R_il(l,:)))
       END DO
    END IF

  END DO ! Newton-Raphson

  BARRIER

  debug_hevi_solver=.FALSE.
END_BLOCK

#endif END_DYSL

SUBROUTINE compute_NH_geopot_unst(tau, m_ik, m_il, theta, W_il, Phi_il)
  USE ISO_C_BINDING, only : C_DOUBLE, C_FLOAT
  USE disvert_mod, only : g,Treff,cpp,preff,kappa,caldyn_thermo,thermo_theta, &
    thermo_entropy
  USE disvert_mod, ONLY : ptop
  USE data_unstructured_mod, ONLY : enter_trace, exit_trace, &
       id_NH_geopot,debug_hevi_solver_, &
       PHI_BOT,pbot,rho_bot
  FIELD_MASS   :: m_ik, theta   ! IN*2
  FIELD_GEOPOT :: m_il, W_il, Phi_il, Phi_star_il  ! IN,INOUT*2, LOCAL
  NUM :: tau, gamma, tau2_g, tau2_g2, g2, gm2, vreff, Rd_preff
  INTEGER :: iter
  LOGICAL :: debug_hevi_solver
  DECLARE_INDICES
  NUM :: rho_ij, X_ij, Y_ij, wil, rho_c2_mik, c2_mik, ml_g2
#define COLUMN 0
#if COLUMN 
  NUM1(llm)  :: pk, Ak, Ck
  NUM1(llm+1):: Rl, Bl, Dl, xl
#define p_ik(l,ij) pk(l)
#define A_ik(l,ij) Ak(l)
#define C_ik(l,ij) Ck(l)
#define R_il(l,ij) Rl(l)
#define B_il(l,ij) Bl(l)
#define D_il(l,ij) Dl(l)
#define x_il(l,ij) xl(l)
#else
  FIELD_MASS :: p_ik, A_ik, C_ik
  FIELD_GEOPOT :: R_il, B_il, D_il, x_il
#endif

  debug_hevi_solver=.FALSE.
!$OMP MASTER
  debug_hevi_solver = debug_hevi_solver_
!$OMP END MASTER

#define PHI_BOT(ij) Phi_bot
  START_TRACE(id_NH_geopot, 7,0,0)
#include "../kernels_unst/compute_NH_geopot.k90"
  STOP_TRACE

!$OMP MASTER
  debug_hevi_solver_ = debug_hevi_solver
!$OMP END MASTER
#undef PHI_BOT

#if COLUMN
#undef p_ik
#undef A_ik
#undef C_ik
#undef R_il
#undef B_il
#undef D_il
#undef x_il
#endif
#undef COLUMN
END SUBROUTINE compute_NH_geopot_unst

  SUBROUTINE compute_NH_geopot(tau, phis, m_ik, m_il, theta, W_il, Phi_il)
    USE icosa
    USE disvert_mod
    USE caldyn_vars_mod
    USE omp_para
    REAL(rstd), PARAMETER :: pbot=1e5, rho_bot=1e6
    REAL(rstd),INTENT(IN)    :: tau ! solve Phi-tau*dPhi/dt = Phi_rhs
    REAL(rstd),INTENT(IN)    :: phis(iim*jjm)
    REAL(rstd),INTENT(IN)    :: m_ik(iim*jjm,llm)
    REAL(rstd),INTENT(IN)    :: m_il(iim*jjm,llm+1)
    REAL(rstd),INTENT(IN)    :: theta(iim*jjm,llm)
    REAL(rstd),INTENT(IN)    :: W_il(iim*jjm,llm+1)   ! vertical momentum
    REAL(rstd),INTENT(INOUT) :: Phi_il(iim*jjm,llm+1) ! geopotential

    REAL(rstd) :: Phi_star_il(iim*jjm,llm+1) 
    REAL(rstd) :: p_ik(iim*jjm,llm)      ! pressure
    REAL(rstd) :: R_il(iim*jjm,llm+1)    ! rhs of tridiag problem
    REAL(rstd) :: x_il(iim*jjm,llm+1)    ! solution of tridiag problem
    REAL(rstd) :: A_ik(iim*jjm,llm)      ! off-diagonal coefficients of tridiag problem
    REAL(rstd) :: B_il(iim*jjm,llm+1)    ! diagonal coefficients of tridiag problem
    REAL(rstd) :: C_ik(iim*jjm,llm)      ! Thomas algorithm
    REAL(rstd) :: D_il(iim*jjm,llm+1)    ! Thomas algorithm
    REAL(rstd) :: gamma, rho_ij, X_ij, Y_ij
    REAL(rstd) :: wil, tau2_g, g2, gm2, ml_g2, c2_mik, vreff

    INTEGER    :: iter, ij, l, ij_omp_begin_ext, ij_omp_end_ext

    CALL distrib_level(ij_begin_ext,ij_end_ext, ij_omp_begin_ext,ij_omp_end_ext)

    IF(dysl) THEN
#define PHI_BOT(ij) phis(ij)
#include "../kernels_hex/compute_NH_geopot.k90"
#undef PHI_BOT
    ELSE
!    FIXME : vertical OpenMP parallelism will not work
   
    tau2_g=tau*tau/g
    g2=g*g
    gm2 = g**-2
    gamma = 1./(1.-kappa)
    
    ! compute Phi_star
    DO l=1,llm+1
       !DIR$ SIMD
       DO ij=ij_begin_ext,ij_end_ext
          Phi_star_il(ij,l) = Phi_il(ij,l) + tau*g2*(W_il(ij,l)/m_il(ij,l)-tau)
       ENDDO
    ENDDO

    ! Newton-Raphson iteration : Phi_il contains current guess value
    DO iter=1,5 ! 2 iterations should be enough

       ! Compute pressure, A_ik
       DO l=1,llm
          !DIR$ SIMD
          DO ij=ij_begin_ext,ij_end_ext
             rho_ij = (g*m_ik(ij,l))/(Phi_il(ij,l+1)-Phi_il(ij,l))
             X_ij = (cpp/preff)*kappa*theta(ij,l)*rho_ij
             p_ik(ij,l) = preff*(X_ij**gamma)
             c2_mik = gamma*p_ik(ij,l)/(rho_ij*m_ik(ij,l)) ! c^2 = gamma*R*T = gamma*p/rho
             A_ik(ij,l) = c2_mik*(tau/g*rho_ij)**2
          ENDDO
       ENDDO

       ! Compute residual, B_il
       ! bottom interface l=1
       !DIR$ SIMD
       DO ij=ij_begin_ext,ij_end_ext
          ml_g2 = gm2*m_il(ij,1) 
          B_il(ij,1) = A_ik(ij,1) + ml_g2 + tau2_g*rho_bot
          R_il(ij,1) = ml_g2*( Phi_il(ij,1)-Phi_star_il(ij,1))  &
               + tau2_g*( p_ik(ij,1)-pbot+rho_bot*(Phi_il(ij,1)-phis(ij)) )
       ENDDO
       ! inner interfaces
       DO l=2,llm
          !DIR$ SIMD
          DO ij=ij_begin_ext,ij_end_ext
             ml_g2 = gm2*m_il(ij,l) 
             B_il(ij,l) = A_ik(ij,l)+A_ik(ij,l-1) + ml_g2
             R_il(ij,l) = ml_g2*( Phi_il(ij,l)-Phi_star_il(ij,l))  &
                     + tau2_g*(p_ik(ij,l)-p_ik(ij,l-1))
             ! consistency check : if Wil=0 and initial state is in hydrostatic balance
             ! then Phi_star_il(ij,l) = Phi_il(ij,l) - tau^2*g^2
             ! and residual = tau^2*(ml+(1/g)dl_pi)=0
          ENDDO
       ENDDO
       ! top interface l=llm+1
       !DIR$ SIMD
       DO ij=ij_begin_ext,ij_end_ext
          ml_g2 = gm2*m_il(ij,llm+1) 
          B_il(ij,llm+1) = A_ik(ij,llm) + ml_g2
          R_il(ij,llm+1) = ml_g2*( Phi_il(ij,llm+1)-Phi_star_il(ij,llm+1))  &
               + tau2_g*( ptop-p_ik(ij,llm) )
       ENDDO

       ! FIXME later
       ! the lines below modify the tridiag problem 
       ! for flat, rigid boundary conditions at top and bottom :
       ! zero out A(1), A(llm), R(1), R(llm+1)
       ! => x(l)=0 at l=1,llm+1
       DO ij=ij_begin_ext,ij_end_ext
          A_ik(ij,1) = 0.
          A_ik(ij,llm) = 0.
          R_il(ij,1) = 0.
          R_il(ij,llm+1) = 0.
       ENDDO

       IF(debug_hevi_solver) THEN ! print Linf(residual)
          PRINT *, '[hevi_solver] R,p', iter, MAXVAL(ABS(R_il)), MAXVAL(p_ik)
       END IF

       ! Solve -A(l-1)x(l-1) + B(l)x(l) - A(l)x(l+1) = R(l) using Thomas algorithm
       ! Forward sweep :
       ! C(0)=0, C(l) = -A(l) / (B(l)+A(l-1)C(l-1)), 
       ! D(0)=0, D(l) = (R(l)+A(l-1)D(l-1)) / (B(l)+A(l-1)C(l-1))
       ! bottom interface l=1
       !DIR$ SIMD
       DO ij=ij_begin_ext,ij_end_ext
          X_ij = 1./B_il(ij,1)
          C_ik(ij,1) = -A_ik(ij,1) * X_ij 
          D_il(ij,1) =  R_il(ij,1) * X_ij
       ENDDO
       ! inner interfaces/layers
       DO l=2,llm
          !DIR$ SIMD
          DO ij=ij_begin_ext,ij_end_ext
             X_ij = 1./(B_il(ij,l) + A_ik(ij,l-1)*C_ik(ij,l-1))
             C_ik(ij,l) = -A_ik(ij,l) * X_ij 
             D_il(ij,l) =  (R_il(ij,l)+A_ik(ij,l-1)*D_il(ij,l-1)) * X_ij
          ENDDO
       ENDDO
       ! top interface l=llm+1
       !DIR$ SIMD
       DO ij=ij_begin_ext,ij_end_ext
          X_ij = 1./(B_il(ij,llm+1) + A_ik(ij,llm)*C_ik(ij,llm))
          D_il(ij,llm+1) =  (R_il(ij,llm+1)+A_ik(ij,llm)*D_il(ij,llm)) * X_ij
       ENDDO
       
       ! Back substitution :
       ! x(i) = D(i)-C(i)x(i+1), x(N+1)=0
       ! + Newton-Raphson update
       x_il=0. ! FIXME
       ! top interface l=llm+1
       !DIR$ SIMD
       DO ij=ij_begin_ext,ij_end_ext
          x_il(ij,llm+1) = D_il(ij,llm+1)
          Phi_il(ij,llm+1) = Phi_il(ij,llm+1) - x_il(ij,llm+1)
       ENDDO
       ! lower interfaces
       DO l=llm,1,-1
          !DIR$ SIMD
          DO ij=ij_begin_ext,ij_end_ext
             x_il(ij,l) = D_il(ij,l) - C_ik(ij,l)*x_il(ij,l+1)
             Phi_il(ij,l) = Phi_il(ij,l) - x_il(ij,l)
          ENDDO
       ENDDO

       IF(debug_hevi_solver) THEN
          PRINT *, '[hevi_solver] A,B', iter, MAXVAL(ABS(A_ik)),MAXVAL(ABS(B_il))
          PRINT *, '[hevi_solver] C,D', iter, MAXVAL(ABS(C_ik)),MAXVAL(ABS(D_il))
          DO l=1,llm+1
             WRITE(*,'(A,I2.1,I3.2,E9.2)') '[hevi_solver] x', iter,l, MAXVAL(ABS(x_il(:,l)))
          END DO
       END IF

    END DO ! Newton-Raphson

    END IF ! dysl
    
  END SUBROUTINE compute_NH_geopot

END MODULE compute_NH_geopot_mod