source: codes/icosagcm/devel/src/diagnostics/observable.f90 @ 728

Last change on this file since 728 was 728, checked in by dubos, 6 years ago

devel : diagnose consistent kinetic energy using new req_z1_scal (r711)
File size: 14.0 KB
Line 
1MODULE observable_mod
2  USE icosa
3  USE diagflux_mod
4  USE output_field_mod
5  IMPLICIT NONE
6  PRIVATE
7
8  TYPE(t_field),POINTER, SAVE :: f_buf_i(:), &
9       f_buf_Fel(:), f_buf_uh(:), & ! horizontal velocity, different from prognostic velocity if NH
10       f_buf_ulon(:), f_buf_ulat(:)
11  TYPE(t_field),POINTER, SAVE :: f_buf_v(:), f_buf_s(:), f_buf_p(:)
12  TYPE(t_field),POINTER, SAVE :: f_pmid(:)
13
14! temporary shared variable for caldyn
15  TYPE(t_field),POINTER, SAVE :: f_theta(:)
16
17  PUBLIC init_observable, write_output_fields_basic, & 
18       f_theta, f_buf_i, f_buf_ulon, f_buf_ulat
19
20CONTAINS
21 
22  SUBROUTINE init_observable
23    CALL allocate_field(f_buf_i,   field_t,type_real,llm,name="buffer_i")
24    CALL allocate_field(f_buf_p,   field_t,type_real,llm+1) 
25    CALL allocate_field(f_buf_ulon,field_t,type_real,llm, name="buf_ulon")
26    CALL allocate_field(f_buf_ulat,field_t,type_real,llm, name="buf_ulat")
27    CALL allocate_field(f_buf_uh,  field_u,type_real,llm, name="buf_uh")
28    CALL allocate_field(f_buf_Fel, field_u,type_real,llm+1, name="buf_F_el")
29    CALL allocate_field(f_buf_v,   field_z,type_real,llm, name="buf_v")
30    CALL allocate_field(f_buf_s,   field_t,type_real, name="buf_s")
31
32    CALL allocate_field(f_theta, field_t,type_real,llm,nqdyn,  name='theta') ! potential temperature
33    CALL allocate_field(f_pmid,  field_t,type_real,llm,  name='pmid')       ! mid layer pressure
34  END SUBROUTINE init_observable
35
36  SUBROUTINE write_output_fields_basic(init, f_phis, f_ps, f_mass, f_geopot, f_theta_rhodz, f_u, f_W, f_q)
37    USE xios_mod
38    USE disvert_mod
39    USE wind_mod
40    USE omp_para
41    USE time_mod
42    USE xios_mod
43    USE earth_const
44    USE pression_mod
45    USE vertical_interp_mod
46    USE theta2theta_rhodz_mod
47    USE omega_mod
48    USE kinetic_mod
49
50    LOGICAL, INTENT(IN) :: init
51    INTEGER :: l
52    REAL :: scalar(1)
53    REAL :: mid_ap(llm)
54    REAL :: mid_bp(llm)
55
56    TYPE(t_field),POINTER :: f_phis(:), f_ps(:), f_mass(:), f_geopot(:), f_theta_rhodz(:), f_u(:), f_W(:), f_q(:)
57!    IF (is_master) PRINT *,'CALL write_output_fields_basic'
58
59    CALL transfert_request(f_ps,req_i1)
60   
61    IF(init) THEN
62       IF(is_master) PRINT *, 'Creating output files ...'
63       scalar(1)=dt
64       IF (is_omp_master) CALL xios_send_field("timestep", scalar)
65       scalar(1)=preff
66       IF (is_omp_master) CALL xios_send_field("preff", scalar)
67       IF (is_omp_master) CALL xios_send_field("ap",ap)
68       IF (is_omp_master) CALL xios_send_field("bp",bp)
69       DO l=1,llm
70          mid_ap(l)=(ap(l)+ap(l+1))/2
71          mid_bp(l)=(bp(l)+bp(l+1))/2
72       ENDDO
73       IF (is_omp_master) CALL xios_send_field("mid_ap",mid_ap)
74       IF (is_omp_master) CALL xios_send_field("mid_bp",mid_bp)
75
76       CALL output_field("phis",f_phis)
77       CALL output_field("Ai",geom%Ai) 
78       IF(is_master) PRINT *, '... done creating output files. Writing initial condition ...'
79    END IF
80
81    IF(nqdyn>1) THEN
82       CALL divide_by_mass(2, f_mass, f_theta_rhodz, f_buf_i)
83       IF(init) THEN
84          CALL output_field("dyn_q_init",f_buf_i)
85       ELSE
86          CALL output_field("dyn_q",f_buf_i)
87       END IF
88    END IF
89
90    CALL divide_by_mass(1, f_mass, f_theta_rhodz, f_buf_i)
91    IF(init) THEN
92       CALL output_field("theta_init",f_buf_i)
93    ELSE
94       CALL output_field("theta",f_buf_i)
95    END IF
96
97    CALL pression_mid(f_ps, f_pmid)
98    CALL diagnose_temperature(f_pmid, f_q, f_buf_i) ! f_buf_i : IN = theta, out = T
99
100    IF(init) THEN
101       CALL output_field("temp_init",f_buf_i)
102    ELSE
103       CALL output_field("temp",f_buf_i)
104       CALL vertical_interp(f_pmid,f_buf_i,f_buf_s,85000.)
105       CALL output_field("t850",f_buf_s)
106       CALL vertical_interp(f_pmid,f_buf_i,f_buf_s,50000.)
107       CALL output_field("t500",f_buf_s)
108       CALL vertical_interp(f_pmid,f_buf_i,f_buf_s,preff)
109       CALL output_field("SST",f_buf_s)       
110    END IF
111   
112    CALL progonostic_vel_to_horiz(f_geopot, f_ps, f_mass, f_u, f_W, f_buf_uh, f_buf_i)
113    CALL transfert_request(f_buf_uh,req_e1_vect) 
114    CALL un2ulonlat(f_buf_uh, f_buf_ulon, f_buf_ulat)
115    IF(init) THEN
116       CALL output_field("uz_init",f_buf_i)
117       CALL output_field("ulon_init",f_buf_ulon)
118       CALL output_field("ulat_init",f_buf_ulat)
119       CALL output_field("p_init",f_pmid)
120       CALL output_field("ps_init",f_ps)
121       CALL output_field("mass_init",f_mass)
122       CALL output_field("geopot_init",f_geopot)
123       CALL output_field("q_init",f_q)
124       IF(is_master) PRINT *, 'Done writing initial condition ...'
125    ELSE
126       CALL output_field("uz",f_buf_i)
127       CALL output_field("ulon",f_buf_ulon)
128       CALL output_field("ulat",f_buf_ulat)
129       CALL output_field("p",f_pmid)
130       CALL output_field("ps",f_ps)
131       CALL output_field("mass",f_mass)
132       CALL output_field("geopot",f_geopot)
133       CALL output_field("q",f_q)
134
135       !       CALL output_field("exner",f_pk)
136       !       CALL output_field("pv",f_qv)
137       
138       CALL vertical_interp(f_pmid,f_buf_ulon,f_buf_s,85000.)
139       CALL output_field("u850",f_buf_s)
140       CALL vertical_interp(f_pmid,f_buf_ulon,f_buf_s,50000.)
141       CALL output_field("u500",f_buf_s)
142       
143       CALL vertical_interp(f_pmid,f_buf_ulat,f_buf_s,85000.)
144       CALL output_field("v850",f_buf_s)
145       CALL vertical_interp(f_pmid,f_buf_ulat,f_buf_s,50000.)
146       CALL output_field("v500",f_buf_s)
147
148       CALL vertical_interp(f_pmid,f_buf_i,f_buf_s,85000.)
149       CALL output_field("w850",f_buf_s)
150       CALL vertical_interp(f_pmid,f_buf_i,f_buf_s,50000.)
151       CALL output_field("w500",f_buf_s)   
152
153       CALL w_omega(f_ps, f_u, f_buf_i)
154       CALL output_field("omega",f_buf_i)
155       CALL vertical_interp(f_pmid,f_buf_i,f_buf_s,85000.)
156       CALL output_field("omega850",f_buf_s)
157       CALL vertical_interp(f_pmid,f_buf_i,f_buf_s,50000.)
158       CALL output_field("omega500",f_buf_s)
159    END IF
160
161    CALL kinetic(f_u, f_buf_i)
162    IF(init) THEN
163       CALL output_field("kinetic_trisk_init",f_buf_i)
164    ELSE
165       CALL output_field("kinetic_trisk",f_buf_i)
166    END IF
167
168    CALL kinetic_new(f_u, f_buf_v, f_buf_i)
169    IF(init) THEN
170       CALL output_field("kinetic_init",f_buf_i)
171    ELSE
172       CALL output_field("kinetic",f_buf_i)
173    END IF
174
175    IF(.NOT. init) THEN
176       IF(diagflux_on) THEN
177          CALL flux_centered_lonlat(1./(itau_out*dt) , f_massfluxt, f_buf_ulon, f_buf_ulat)
178          CALL output_field("mass_t", f_masst)
179          CALL output_field("massflux_lon",f_buf_ulon)
180          CALL output_field("massflux_lat",f_buf_ulat)
181
182          CALL output_energyflux(f_ulont, f_ulonfluxt, "ulon_t", "ulonflux_lon", "ulonflux_lat")
183          CALL output_energyflux(f_thetat, f_thetafluxt, "theta_t", "thetaflux_lon", "thetaflux_lat")
184          CALL output_energyflux(f_epot, f_epotfluxt, "epot_t", "epotflux_lon", "epotflux_lat")
185          CALL output_energyflux(f_ekin, f_ekinfluxt, "ekin_t", "ekinflux_lon", "ekinflux_lat")
186          CALL output_energyflux(f_enthalpy, f_enthalpyfluxt, "enthalpy_t", "enthalpyflux_lon", "enthalpyflux_lat")
187
188          CALL qflux_centered_lonlat(1./(itau_out*dt) , f_qfluxt, f_qfluxt_lon, f_qfluxt_lat)
189          CALL output_field("qmass_t", f_qmasst)
190          CALL output_field("qflux_lon",f_qfluxt_lon)
191          CALL output_field("qflux_lat",f_qfluxt_lat)
192          CALL zero_qfluxt  ! restart accumulating fluxes
193       END IF
194    END IF
195  END SUBROUTINE write_output_fields_basic
196
197  SUBROUTINE output_energyflux(f_energy, f_flux, name_energy, name_fluxlon, name_fluxlat)
198    TYPE(t_field), POINTER :: f_energy(:), f_flux(:)
199    CHARACTER(*), INTENT(IN) :: name_energy, name_fluxlon, name_fluxlat
200    CALL transfert_request(f_flux,req_e1_vect)
201    CALL flux_centered_lonlat(1./(itau_out*dt) , f_flux, f_buf_ulon, f_buf_ulat)
202    CALL output_field(name_energy,  f_energy)
203    CALL output_field(name_fluxlon, f_buf_ulon)
204    CALL output_field(name_fluxlat, f_buf_ulat)
205  END SUBROUTINE output_energyflux
206 
207 !------------------- Conversion from prognostic to observable variables ------------------
208
209  SUBROUTINE progonostic_vel_to_horiz(f_geopot, f_ps, f_rhodz, f_u, f_W, f_uh, f_uz)
210    USE disvert_mod
211    TYPE(t_field), POINTER :: f_geopot(:), f_ps(:), f_rhodz(:), &
212         f_u(:), f_W(:), f_uz(:), &  ! IN
213         f_uh(:)                         ! OUT
214    REAL(rstd),POINTER :: geopot(:,:), ps(:), rhodz(:,:), u(:,:), W(:,:), uh(:,:), uz(:,:), F_el(:,:)
215    INTEGER :: ind
216   
217    DO ind=1,ndomain
218       IF (.NOT. assigned_domain(ind)) CYCLE
219       CALL swap_dimensions(ind)
220       CALL swap_geometry(ind)
221       geopot = f_geopot(ind)
222       rhodz = f_rhodz(ind)
223       u = f_u(ind)
224       W = f_W(ind)
225       uh  = f_uh(ind)
226       F_el  = f_buf_Fel(ind)
227       IF(caldyn_eta==eta_mass) THEN
228          ps=f_ps(ind)
229          CALL compute_rhodz(.TRUE., ps, rhodz)
230       END IF
231       uz = f_uz(ind)
232       !$OMP BARRIER
233       CALL compute_prognostic_vel_to_horiz(geopot,rhodz,u,W, F_el, uh,uz)
234       !$OMP BARRIER
235    END DO
236  END SUBROUTINE progonostic_vel_to_horiz
237 
238  SUBROUTINE compute_prognostic_vel_to_horiz(Phi, rhodz, u, W, F_el, uh, uz)
239    USE omp_para
240    REAL(rstd), INTENT(IN) :: Phi(iim*jjm,llm+1)
241    REAL(rstd), INTENT(IN) :: rhodz(iim*jjm,llm)
242    REAL(rstd), INTENT(IN) :: u(3*iim*jjm,llm)
243    REAL(rstd), INTENT(IN) :: W(iim*jjm,llm+1)
244    REAL(rstd), INTENT(OUT) :: uh(3*iim*jjm,llm)
245    REAL(rstd), INTENT(OUT) :: uz(iim*jjm,llm)
246    INTEGER :: ij,l
247    REAL(rstd) :: F_el(3*iim*jjm,llm+1)
248    REAL(rstd) :: uu_right, uu_lup, uu_ldown, W_el, DePhil
249    ! NB : u and uh are not in DEC form, they are normal components   
250    ! => we must divide by de
251    IF(hydrostatic) THEN
252       uh(:,:)=u(:,:)
253       uz(:,:)=0.
254    ELSE
255       DO l=ll_begin, ll_endp1 ! compute on l levels (interfaces)
256          DO ij=ij_begin_ext, ij_end_ext
257             ! Compute on edge 'right'
258             W_el   = .5*( W(ij,l)+W(ij+t_right,l) )
259             DePhil = ne_right*(Phi(ij+t_right,l)-Phi(ij,l))
260             F_el(ij+u_right,l)   = DePhil*W_el/de(ij+u_right)
261             ! Compute on edge 'lup'
262             W_el   = .5*( W(ij,l)+W(ij+t_lup,l) )
263             DePhil = ne_lup*(Phi(ij+t_lup,l)-Phi(ij,l))
264             F_el(ij+u_lup,l)   = DePhil*W_el/de(ij+u_lup)
265             ! Compute on edge 'ldown'
266             W_el   = .5*( W(ij,l)+W(ij+t_ldown,l) )
267             DePhil = ne_ldown*(Phi(ij+t_ldown,l)-Phi(ij,l))
268             F_el(ij+u_ldown,l) = DePhil*W_el/de(ij+u_ldown)
269          END DO
270       END DO
271
272       ! We need a barrier here because we compute F_el above and do a vertical average below
273       !$OMP BARRIER
274
275       DO l=ll_begin, ll_end ! compute on k levels (full levels)
276          DO ij=ij_begin_ext, ij_end_ext
277             ! w = vertical momentum = g^-2*dPhi/dt = uz/g
278             uz(ij,l) = (.5*g)*(W(ij,l)+W(ij,l+1))/rhodz(ij,l)
279             ! uh = u-w.grad(Phi) = u - uz.grad(z)
280             uh(ij+u_right,l) = u(ij+u_right,l) - (F_el(ij+u_right,l)+F_el(ij+u_right,l+1)) / (rhodz(ij,l)+rhodz(ij+t_right,l))
281             uh(ij+u_lup,l)   = u(ij+u_lup,l)   - (F_el(ij+u_lup,l)+F_el(ij+u_lup,l+1))     / (rhodz(ij,l)+rhodz(ij+t_lup,l))
282             uh(ij+u_ldown,l) = u(ij+u_ldown,l) - (F_el(ij+u_ldown,l)+F_el(ij+u_ldown,l+1)) / (rhodz(ij,l)+rhodz(ij+t_ldown,l))
283          END DO
284       END DO
285
286    END IF
287  END SUBROUTINE compute_prognostic_vel_to_horiz
288
289  SUBROUTINE diagnose_temperature(f_pmid,f_q,f_temp)
290    USE icosa
291    USE pression_mod
292    IMPLICIT NONE
293    TYPE(t_field), POINTER :: f_pmid(:)           ! IN
294    TYPE(t_field), POINTER :: f_q(:)            ! IN
295    TYPE(t_field), POINTER :: f_temp(:)         ! INOUT
296   
297    REAL(rstd), POINTER :: pmid(:,:)
298    REAL(rstd), POINTER :: q(:,:,:)
299    REAL(rstd), POINTER :: temp(:,:)
300    INTEGER :: ind
301   
302    DO ind=1,ndomain
303       IF (.NOT. assigned_domain(ind)) CYCLE
304       CALL swap_dimensions(ind)
305       CALL swap_geometry(ind)
306       pmid=f_pmid(ind)
307       q=f_q(ind)
308       temp=f_temp(ind)
309       CALL compute_diagnose_temp(pmid,q,temp)
310    END DO
311  END SUBROUTINE diagnose_temperature
312 
313  SUBROUTINE compute_diagnose_temp(pmid,q,temp)
314    USE omp_para
315    USE pression_mod
316    REAL(rstd),INTENT(IN)    :: pmid(iim*jjm,llm)
317    REAL(rstd),INTENT(IN)    :: q(iim*jjm,llm,nqtot)
318    REAL(rstd),INTENT(INOUT) :: temp(iim*jjm,llm)
319
320    REAL(rstd) :: Rd, p_ik, theta_ik, temp_ik, qv, chi, Rmix
321    INTEGER :: ij,l
322
323    Rd = kappa*cpp
324    DO l=ll_begin,ll_end
325       DO ij=ij_begin,ij_end
326          p_ik = pmid(ij,l)
327          theta_ik = temp(ij,l)
328          qv = q(ij,l,1) ! water vaper mixing ratio = mv/md
329          SELECT CASE(caldyn_thermo)
330          CASE(thermo_theta)
331             temp_ik = theta_ik*((p_ik/preff)**kappa)
332          CASE(thermo_entropy)
333             temp_ik = Treff*exp((theta_ik + Rd*log(p_ik/preff))/cpp)
334          CASE(thermo_moist)
335             Rmix = Rd+qv*Rv
336             chi = ( theta_ik + Rmix*log(p_ik/preff) ) / (cpp + qv*cppv) ! log(T/Treff)
337             temp_ik = Treff*exp(chi)
338          END SELECT
339          IF(physics_thermo==thermo_fake_moist) temp_ik=temp_ik/(1+0.608*qv)
340          temp(ij,l)=temp_ik
341       END DO
342    END DO
343  END SUBROUTINE compute_diagnose_temp
344
345  SUBROUTINE Tv2T(f_Tv, f_q, f_T)
346    TYPE(t_field), POINTER :: f_TV(:)
347    TYPE(t_field), POINTER :: f_q(:)
348    TYPE(t_field), POINTER :: f_T(:)
349   
350    REAL(rstd),POINTER :: Tv(:,:), q(:,:,:), T(:,:)
351    INTEGER :: ind
352   
353    DO ind=1,ndomain
354       IF (.NOT. assigned_domain(ind)) CYCLE
355       CALL swap_dimensions(ind)
356       CALL swap_geometry(ind)
357       Tv=f_Tv(ind)
358       T=f_T(ind)
359       SELECT CASE(physics_thermo)
360       CASE(thermo_dry)
361          T=Tv
362       CASE(thermo_fake_moist)
363          q=f_q(ind)
364          T=Tv/(1+0.608*q(:,:,1))
365       END SELECT
366    END DO
367  END SUBROUTINE Tv2T
368
369  SUBROUTINE divide_by_mass(iq, f_mass, f_theta_rhodz, f_theta)
370    INTEGER, INTENT(IN) :: iq
371    TYPE(t_field), POINTER :: f_mass(:), f_theta_rhodz(:), f_theta(:)
372    REAL(rstd), POINTER :: mass(:,:), theta_rhodz(:,:,:), theta(:,:)
373    INTEGER :: ind
374    DO ind=1,ndomain
375       IF (.NOT. assigned_domain(ind)) CYCLE
376       CALL swap_dimensions(ind)
377       CALL swap_geometry(ind)
378       mass=f_mass(ind)
379       theta_rhodz=f_theta_rhodz(ind)
380       theta=f_theta(ind)
381       theta(:,:) = theta_rhodz(:,:,iq) / mass(:,:)
382    END DO
383  END SUBROUTINE divide_by_mass
384   
385END MODULE observable_mod
Note: See TracBrowser for help on using the repository browser.