source: codes/icosagcm/devel/src/diagnostics/check_conserve.f90 @ 1052

Last change on this file since 1052 was 1052, checked in by dubos, 4 years ago

devel : diagnose divergence and vorticity
File size: 15.4 KB
Line 
1MODULE check_conserve_mod
2  USE icosa 
3  USE compute_pression_mod, ONLY : pression
4  IMPLICIT NONE
5  PRIVATE
6 
7  INTEGER, PARAMETER, PUBLIC :: check_basic=1, check_detailed=2, &
8       AAM_dissip=1, AAM_dyn=2, AAM_phys=3
9  INTEGER, SAVE :: check_type
10
11  TYPE(t_field),POINTER,SAVE :: f_pk(:), f_pks(:), f_p(:)
12  TYPE(t_field),POINTER,SAVE :: f_vort(:)
13  TYPE(t_field),POINTER,SAVE :: f_rhodz(:) 
14 
15  REAL(rstd),SAVE :: AAM_mass, AAM_mass_old, AAM_vel, AAM_vel_old, &
16       AAM_velp, AAM_velp_old, AAM_velm, AAM_velm_old, &
17       AAM_mass_source(3), AAM_vel_source(3) ! read/written only IF is_master
18  REAL(rstd),SAVE :: AAM_vel_plus_source(3), AAM_vel_minus_source(3)
19  REAL(rstd),SAVE :: mtot0,ztot0,etot0,angtot0,stot0,rmsvtot0
20  !$OMP THREADPRIVATE(check_type, mtot0,ztot0,etot0,angtot0,stot0,rmsvtot0)
21 
22  PUBLIC :: init_check_conserve, check_conserve_detailed, check_conserve
23CONTAINS 
24
25!---------------------------------------------------------------------
26
27  SUBROUTINE init_check_conserve
28    USE getin_mod
29    USE omp_para, ONLY : is_master
30    CHARACTER(LEN=255) :: check_type_str
31    CALL allocate_field(f_pk,field_t,type_real,llm)
32    CALL allocate_field(f_p,field_t,type_real,llm+1)
33    CALL allocate_field(f_pks,field_t,type_real)
34    CALL allocate_field(f_rhodz,field_t,type_real,llm)
35    CALL allocate_field(f_vort,field_z,type_real,llm)
36   
37    check_type_str='basic'
38    CALL getin("check_conservation",check_type_str)
39    SELECT CASE(TRIM(check_type_str))
40    CASE('basic')
41       check_type=check_basic
42    CASE('detailed')
43       check_type=check_detailed
44    CASE DEFAULT
45       IF(is_master) PRINT*,'Bad selector <', TRIM(check_type_str), &
46            '> for variable check_conservation : options are <basic>, <detailed>'
47       STOP
48    END SELECT
49  END SUBROUTINE init_check_conserve
50
51!--------------------------------- Basic check --------------------------------
52
53  SUBROUTINE check_conserve(f_ps,f_dps,f_ue,f_theta_rhodz,f_phis,it) 
54  USE compute_vorticity_mod
55  USE caldyn_gcm_mod
56  USE exner_mod 
57  USE omp_para, ONLY : is_master
58  USE grid_param
59    TYPE(t_field),POINTER :: f_ps(:)
60    TYPE(t_field),POINTER :: f_dps(:)
61    TYPE(t_field),POINTER :: f_ue(:)
62    TYPE(t_field),POINTER :: f_theta_rhodz(:)
63    TYPE(t_field),POINTER :: f_phis(:)
64    INTEGER, INTENT(IN) :: it
65
66    REAL(rstd),POINTER :: p(:,:),rhodz(:,:) 
67    INTEGER :: ind
68    REAL(rstd) :: mtot, angtot, rmsdpdt
69    REAL(rstd) :: etot, stot, ang_mass, ang_vel, ang_velp, ang_velm, rmsvtot, ztot
70
71    IF(grid_type == grid_unst) RETURN ! FIXME
72
73    CALL transfert_request(f_ue,req_e1_vect)
74    CALL pression(f_ps,f_p)
75
76    DO ind=1,ndomain 
77      IF (.NOT. assigned_domain(ind)) CYCLE
78      CALL swap_dimensions(ind)
79      CALL swap_geometry(ind)
80      p=f_p(ind) 
81      rhodz=f_rhodz(ind)
82      CALL compute_rhodz(p,rhodz) 
83    END DO
84
85    CALL vorticity(f_ue,f_vort)
86    CALL check_mass_conserve(f_ps,f_dps,mtot,rmsdpdt)
87    CALL check_PV(ztot) 
88    CALL exner(f_ps,f_p,f_pks,f_pk)
89    CALL check_energy(f_ue,f_theta_rhodz,f_phis, etot, stot, ang_mass, ang_vel, ang_velp, ang_velm, rmsvtot) 
90
91    IF (is_master) THEN ! is_master = is_omp_master && is_mpi_master
92       ! AAM_mass and AAM_vel must be read/written only IF is_master
93       AAM_mass = ang_mass
94       AAM_vel = ang_vel
95       AAM_velp = ang_velp
96       AAM_velm = ang_velm
97       angtot  = ang_mass + ang_vel
98       IF ( it == itau0  ) THEN
99          ztot0 = ztot
100          mtot0 = mtot
101          etot0 = etot 
102          angtot0  = angtot
103          stot0 = stot 
104          AAM_mass_old=AAM_mass
105          AAM_vel_old=AAM_vel
106          AAM_velp_old=AAM_velp
107          AAM_velm_old=AAM_velm
108          AAM_mass_source=0.
109          AAM_vel_source=0.
110          AAM_vel_plus_source=0.
111          AAM_vel_minus_source=0.
112       END IF
113       rmsvtot=SQRT(rmsvtot/mtot) 
114       ztot=ztot/ztot0-1. ; mtot=mtot/mtot0-1. 
115       etot=etot/etot0-1. ; angtot=angtot/angtot0-1. ; stot=stot/stot0-1. 
116       rmsdpdt= daysec*1.e-2*sqrt(rmsdpdt/ncell_glo) 
117       
118       OPEN(134,file="checkconsicosa.txt",position='append')
119       WRITE(134,4000)mtot,rmsdpdt,etot,ztot,stot,rmsvtot,angtot
120       WRITE(134,*)mtot,rmsdpdt,etot,ztot,stot,rmsvtot,angtot 
121       WRITE(134,*)"=================================================="
122       WRITE(*,4000)mtot,rmsdpdt,etot,ztot,stot,rmsvtot,angtot
123       
1244000   FORMAT(10x,'masse',5x,'rmsdpdt',5x,'energie',5x,'enstrophie'  &
125            ,5x,'entropie',5x,'rmsv',5x,'mt.ang',/,'GLOB  '          &
126            ,e10.3,e13.6,5e13.3/)     
127       CLOSE(134)
128
129       IF(check_type == check_detailed) THEN
130          WRITE(*,'(A,6E14.6)') 'AAM_mass : time,old,new,dissip,dyn,phys', dt*it, AAM_mass_old, AAM_mass, &
131               AAM_mass_source(AAM_dissip), AAM_mass_source(AAM_dyn), AAM_mass_source(AAM_phys)
132          WRITE(*,'(A,6E14.6)') 'AAM_vel  : time,old,new,dissip,dyn,phys', dt*it, AAM_vel_old, AAM_vel, &
133               AAM_vel_source(AAM_dissip), AAM_vel_source(AAM_dyn), AAM_vel_source(AAM_phys)
134          WRITE(*,'(A,6E14.6)') 'AAM_vel+ : time,old,new,dissip,dyn,phys', dt*it, AAM_velp_old, AAM_velp, &
135               AAM_vel_plus_source(AAM_dissip), AAM_vel_plus_source(AAM_dyn), AAM_vel_plus_source(AAM_phys)
136          WRITE(*,'(A,6E14.6)') 'AAM_vel- : time,old,new,dissip,dyn,phys', dt*it, AAM_velm_old, AAM_velm, &
137               AAM_vel_minus_source(AAM_dissip), AAM_vel_minus_source(AAM_dyn), AAM_vel_minus_source(AAM_phys)
138          WRITE(*,'(A,6E14.6)') 'AAM_dyn budget mass + vel:', AAM_mass_source(AAM_dyn) + AAM_vel_source(AAM_dyn)
139          AAM_mass_old=AAM_mass
140          AAM_vel_old=AAM_vel
141          AAM_velp_old=AAM_velp
142          AAM_velm_old=AAM_velm
143          AAM_mass_source=0.
144          AAM_vel_source=0.
145          AAM_vel_minus_source=0.
146          AAM_vel_plus_source=0.
147       END IF
148    END IF
149
150  END SUBROUTINE check_conserve
151
152!------------------------ Detailed check (Lauritzen et al., 2014) -----------------------------
153
154  SUBROUTINE check_conserve_detailed(it,tag, f_ps,f_dps,f_ue,f_theta_rhodz,f_phis) 
155    USE caldyn_gcm_mod
156    USE exner_mod 
157    USE omp_para, ONLY : is_master
158    INTEGER, INTENT(IN) :: tag
159    TYPE(t_field),POINTER :: f_ps(:)
160    TYPE(t_field),POINTER :: f_dps(:)
161    TYPE(t_field),POINTER :: f_ue(:)
162    TYPE(t_field),POINTER :: f_theta_rhodz(:)
163    TYPE(t_field),POINTER :: f_phis(:)
164    INTEGER, INTENT(IN) ::it
165
166    REAL(rstd),POINTER :: p(:,:),rhodz(:,:) 
167    INTEGER::ind
168    REAL(rstd) :: mtot, ztot, rmsdpdt, etot,stot,rmsv, ang_mass, ang_vel, ang_velp, ang_velm
169   
170    IF(check_type == check_detailed) THEN
171
172       CALL transfert_request(f_ue,req_e1_vect)
173       CALL pression(f_ps,f_p)
174       DO ind=1,ndomain 
175          IF (.NOT. assigned_domain(ind)) CYCLE
176          CALL swap_dimensions(ind)
177          CALL swap_geometry(ind)
178          p=f_p(ind) 
179          rhodz=f_rhodz(ind)
180          CALL compute_rhodz(p,rhodz) 
181       END DO
182       CALL exner(f_ps,f_p,f_pks,f_pk)
183       CALL check_energy(f_ue,f_theta_rhodz,f_phis, etot, stot, ang_mass, ang_vel, ang_velp, ang_velm, rmsv) 
184       
185       IF (is_master) THEN
186          ! XXX=mass,vel
187          ! AAM_XXX = value of total AAM_XXX at last check
188          ! ang_XXX = value of total AAM_XXX now
189          ! AAM_XXX_source(tag) = source of AAA_XXX due to tag=dissip,dyn,phys
190          AAM_mass_source(tag) = AAM_mass_source(tag) + ang_mass - AAM_mass
191          AAM_vel_source(tag) = AAM_vel_source(tag) + ang_vel - AAM_vel
192          AAM_vel_plus_source(tag) = AAM_vel_plus_source(tag) + ang_velp - AAM_velp
193          AAM_vel_minus_source(tag) = AAM_vel_minus_source(tag) + ang_velm - AAM_velm
194          !if ((ang_vel - AAM_vel) .gt. 0.) then
195          !  AAM_vel_plus_source(tag) = AAM_vel_plus_source(tag) + ang_vel - AAM_vel
196          !else
197          !  AAM_vel_minus_source(tag) = AAM_vel_minus_source(tag) + ang_vel - AAM_vel
198          !endif
199          AAM_mass = ang_mass
200          AAM_vel = ang_vel
201          AAM_velp = ang_velp
202          AAM_velm = ang_velm
203       END IF
204    END IF
205  END SUBROUTINE check_conserve_detailed
206 
207!---------------------------------------------------------------------
208
209  SUBROUTINE global_sum(loc_sum, glob_sum)
210    USE mpi_mod
211    USE mpipara
212    USE transfert_omp_mod
213    REAL(rstd), INTENT(IN) :: loc_sum
214    REAL(rstd), INTENT(OUT) :: glob_sum
215    REAL(rstd) :: sum
216
217    CALL reduce_sum_omp(loc_sum, sum)
218    IF (using_mpi) THEN
219!$OMP MASTER   
220      CALL MPI_REDUCE(sum, glob_sum, 1, MPI_REAL8, MPI_SUM, 0, comm_icosa, ierr)
221!$OMP END MASTER
222    ELSE
223      glob_sum=loc_sum
224    ENDIF
225  END SUBROUTINE global_sum
226
227  SUBROUTINE check_mass_conserve(f_ps,f_dps,mtot,rmsdpdt)
228  USE mpi_mod
229  USE mpipara
230  USE transfert_omp_mod
231  USE omp_para
232  IMPLICIT NONE
233    TYPE(t_field),POINTER :: f_ps(:)
234    TYPE(t_field),POINTER :: f_dps(:)
235    REAL(rstd),POINTER :: ps(:),dps(:) 
236    REAL(rstd), INTENT(OUT) :: mtot, rmsdpdt
237
238    INTEGER :: ind,i,j,ij 
239    REAL :: mloc, rmsloc
240    REAL :: mloc_mpi, rmsloc_mpi
241
242    mloc=0.0; rmsloc=0.0
243    DO ind=1,ndomain
244      IF (.NOT. assigned_domain(ind) .OR. .NOT. is_omp_level_master) CYCLE
245      CALL swap_dimensions(ind)
246      CALL swap_geometry(ind)
247      dps=f_dps(ind) 
248      ps=f_ps(ind)
249      DO j=jj_begin,jj_end
250        DO i=ii_begin,ii_end
251          ij=(j-1)*iim+i
252          IF (domain(ind)%own(i,j)) THEN
253             mloc=mloc+ps(ij)*Ai(ij)
254             rmsloc=rmsloc+dps(ij)*dps(ij)
255          ENDIF
256        ENDDO
257      ENDDO
258    ENDDO
259   
260    CALL global_sum(mloc, mtot)
261    CALL global_sum(rmsloc, rmsdpdt)
262  END SUBROUTINE check_mass_conserve
263
264!---------------------------------------------------------------------
265
266  SUBROUTINE check_energy(f_ue,f_theta_rhodz,f_phis, etot, &
267                      stot, AAM_mass_tot, AAM_vel_tot, AAM_velp_tot, AAM_velm_tot, rmsvtot) 
268    TYPE(t_field), POINTER :: f_ue(:)
269    TYPE(t_field), POINTER :: f_theta_rhodz(:)
270    TYPE(t_field), POINTER :: f_phis(:)
271    REAL(rstd),INTENT(OUT) :: etot, stot, AAM_mass_tot, AAM_vel_tot, AAM_velp_tot, AAM_velm_tot, rmsvtot
272    REAL(rstd), POINTER :: ue(:,:)
273    REAL(rstd), POINTER :: p(:,:) 
274    REAL(rstd), POINTER :: theta_rhodz(:,:,:) 
275    REAL(rstd), POINTER :: pk(:,:) 
276    REAL(rstd), POINTER :: phis(:) 
277    REAL(rstd), POINTER :: rhodz(:,:) 
278    REAL(rstd) :: e, s, AAM_mass, AAM_vel, AAM_velp, AAM_velm, rmsv
279    INTEGER :: ind
280
281    e = 0 ; s = 0 ; AAM_mass = 0 ; AAM_vel=0 ; rmsv = 0
282    AAM_velp = 0 ; AAM_velm = 0
283
284    DO ind=1,ndomain 
285      IF (.NOT. assigned_domain(ind)) CYCLE
286      CALL swap_dimensions(ind)
287      CALL swap_geometry(ind)
288      ue=f_ue(ind) 
289      p=f_p(ind)
290      rhodz=f_rhodz(ind) 
291      theta_rhodz=f_theta_rhodz(ind) 
292      pk=f_pk(ind) 
293      phis=f_phis(ind) 
294      CALL compute_energy(ind,ue,p,rhodz,theta_rhodz(:,:,1),pk,phis, &
295           e, s, AAM_mass, AAM_vel, AAM_velp, AAM_velm, rmsv)
296    END DO
297
298    CALL global_sum(e, etot)
299    CALL global_sum(s, stot)
300    CALL global_sum(rmsv, rmsvtot)
301    CALL global_sum(AAM_mass, AAM_mass_tot)
302    CALL global_sum(AAM_vel, AAM_vel_tot)
303    CALL global_sum(AAM_velp, AAM_velp_tot)
304    CALL global_sum(AAM_velm, AAM_velm_tot)
305  END SUBROUTINE check_energy
306
307  SUBROUTINE compute_energy(ind,u,p,rhodz,theta_rhodz,pk,phis, e, s, AAM_mass, AAM_vel, AAM_velp, AAM_velm, rmsv)
308    USE disvert_mod
309    USE wind_mod
310    USE omp_para
311    INTEGER,INTENT(IN)::ind 
312    REAL(rstd),INTENT(IN) :: u(3*iim*jjm,llm)
313    REAL(rstd),INTENT(IN) :: p(iim*jjm,llm+1)
314    REAL(rstd),INTENT(IN) :: rhodz(iim*jjm,llm)
315    REAL(rstd),INTENT(IN) :: theta_rhodz(iim*jjm,llm)
316    REAL(rstd),INTENT(IN) :: pk(iim*jjm,llm)
317    REAL(rstd),INTENT(IN) :: phis(iim*jjm)
318    REAL(rstd),INTENT(INOUT) :: e, s, AAM_mass, AAM_vel, AAM_velp, AAM_velm, rmsv
319   
320    REAL(rstd) :: ucenter(iim*jjm,llm,3)
321    REAL(rstd) :: ulon(iim*jjm,llm)
322    REAL(rstd) :: ulat(iim*jjm,llm)
323   
324    REAL(rstd) :: mass_ij, theta_ij, KE_ij, rad,radomeg,lat
325    INTEGER :: i,j,ij,l
326   
327    CALL compute_wind_centered(u,ucenter)
328    CALL compute_wind_centered_lonlat_compound(ucenter,ulon,ulat)
329    rad = radius 
330    radomeg = rad*omega
331   
332    DO l = ll_begin,ll_end
333       DO j=jj_begin,jj_end
334          DO i=ii_begin,ii_end
335             ij=(j-1)*iim+i
336             IF (domain(ind)%own(i,j)) THEN
337                lat = lat_i(ij) 
338                mass_ij = rhodz(ij,l)*Ai(ij) 
339                theta_ij = theta_rhodz(ij,l)/rhodz(ij,l)
340                KE_ij = 1/(4*Ai(ij))*(le(ij+u_right)*de(ij+u_right)*u(ij+u_right,l)**2 +   &
341                     le(ij+u_rup)*de(ij+u_rup)*u(ij+u_rup,l)**2 +           &
342                     le(ij+u_lup)*de(ij+u_lup)*u(ij+u_lup,l)**2 +           &
343                     le(ij+u_left)*de(ij+u_left)*u(ij+u_left,l)**2 +        &
344                     le(ij+u_ldown)*de(ij+u_ldown)*u(ij+u_ldown,l)**2 +     &
345                     le(ij+u_rdown)*de(ij+u_rdown)*u(ij+u_rdown,l)**2 ) 
346                rmsv = rmsv + 2*mass_ij*KE_ij
347                s    = s + Ai(ij)*theta_rhodz(ij,l)
348                e    = e + mass_ij*(phis(ij)+theta_ij*pk(ij,l)+KE_ij)
349                AAM_mass = AAM_mass + rad*cos(lat)*mass_ij*radomeg*cos(lat)
350                AAM_vel  = AAM_vel  + rad*cos(lat)*mass_ij*ulon(ij,l)
351                if (ulon(ij,l) > 0.) then
352                  AAM_velp  = AAM_velp  + rad*cos(lat)*mass_ij*ulon(ij,l)
353                else
354                  AAM_velm  = AAM_velm  + rad*cos(lat)*mass_ij*ulon(ij,l)
355                endif
356             END IF
357          END DO
358       END DO
359    END DO
360   
361  END SUBROUTINE compute_energy
362
363!---------------------------------------------------------------------
364 
365  SUBROUTINE check_PV(ztot)
366    REAL(rstd),INTENT(OUT) :: ztot
367    REAL(rstd), POINTER :: vort(:,:)
368    REAL(rstd), POINTER :: rhodz(:,:) 
369    INTEGER :: ind
370    REAL(rstd) :: z,z_mpi
371   
372    z=0
373    DO ind=1,ndomain 
374       IF (.NOT. assigned_domain(ind)) CYCLE
375       CALL swap_dimensions(ind)
376       CALL swap_geometry(ind)
377       vort=f_vort(ind)
378       rhodz=f_rhodz(ind) 
379       CALL compute_PV(vort,rhodz,z) 
380    ENDDO
381    CALL global_sum(z, ztot)
382  END SUBROUTINE check_PV 
383
384  SUBROUTINE compute_PV(vort,rhodz,z) 
385  USE disvert_mod
386  USE omp_para
387    REAL(rstd),INTENT(IN) :: vort(2*iim*jjm,llm)
388    REAL(rstd),INTENT(IN) :: rhodz(iim*jjm,llm) 
389    REAL(rstd),INTENT(INOUT) :: z
390    REAL(rstd)::qv1,qv2 
391    REAL(rstd)::hv1,hv2 
392    INTEGER :: i,j,ij,l,ij2
393
394    hv1 = 0.0 ; hv2 = 0.0 
395   
396    DO l = ll_begin,ll_end
397      DO j=jj_begin+1,jj_end-1
398        DO i=ii_begin+1,ii_end-1
399          ij=(j-1)*iim+i
400          hv1 =  Riv2(ij,vup)        * rhodz(ij,l)           &
401            + Riv2(ij+t_rup,vldown) * rhodz(ij+t_rup,l)     &
402            + Riv2(ij+t_lup,vrdown) * rhodz(ij+t_lup,l)
403   
404          qv1 = ( vort(ij+z_up,l)+fv(ij+z_up) )/hv1
405         
406          hv2  =  Riv2(ij,vdown)     * rhodz(ij,l)          &
407            + Riv2(ij+t_ldown,vrup) * rhodz(ij+t_ldown,l)  &
408            + Riv2(ij+t_rdown,vlup) * rhodz(ij+t_rdown,l)
409                     
410          qv2 =( vort(ij+z_down,l)+fv(ij+z_down) )/hv2
411
412          z = z + (qv1*qv1*hv1 + qv2*qv2*hv2) 
413
414        ENDDO
415      ENDDO
416     
417    ENDDO
418
419  END SUBROUTINE compute_PV
420!---------------------------------------------------------------------
421
422   SUBROUTINE compute_rhodz(p,rhodz) 
423     REAL(rstd),INTENT(IN) :: p(iim*jjm,llm+1)
424     REAL(rstd),INTENT(OUT):: rhodz(iim*jjm,llm)
425     REAL(rstd) ::mass(iim*jjm,llm)
426     INTEGER :: i,j,ij,l 
427       
428     DO l = 1, llm
429      DO j=jj_begin,jj_end
430       DO i=ii_begin,ii_end
431         ij=(j-1)*iim+i
432         mass(ij,l) = ( p(ij,l) - p(ij,l+1) ) * Ai(ij)/g
433         rhodz(ij,l) = mass(ij,l) / Ai(ij)
434       ENDDO
435      ENDDO
436     ENDDO
437
438   END SUBROUTINE compute_rhodz
439!====================================================================
440
441
442 END MODULE check_conserve_mod
Note: See TracBrowser for help on using the repository browser.