source: codes/icosagcm/branches/SATURN_DYNAMICO/LMDZ.COMMON/libf/phystd/iniphysiq.F90 @ 242

subroutine iniphysiq(nlayer, punjours, pdayref,ptimestep,          &
                     plat,plon,parea,                                    &
                     prad,pg,pr,pcpp,                                    &
                     preff,ap,bp)

use dimphy, only : klev ! number of atmospheric levels
use mod_grid_phy_lmdz, only : klon_glo ! number of atmospheric columns
                                       ! (on full grid)
use mod_phys_lmdz_para, only : klon_omp, & ! number of columns (on local omp grid)
                               klon_omp_begin, & ! start index of local omp subgrid
                               klon_omp_end, & ! end index of local omp subgrid
                               klon_mpi_begin, & ! start indes of columns (on local mpi grid)
                               klon_mpi
use comgeomphy, only : airephy, & ! physics grid area (m2)
                       rlond, & ! longitudes
                       rlatd ! latitudes
use infotrac, only : nqtot ! number of advected tracers
use planete_mod, only: ini_planete_mod

implicit none

real,intent(in) :: prad ! radius of the planet (m)
real,intent(in) :: pg ! gravitational acceleration (m/s2)
real,intent(in) :: pr ! ! reduced gas constant R/mu
real,intent(in) :: pcpp ! specific heat Cp
real,intent(in) :: punjours ! length (in s) of a standard day
integer,intent(in) :: nlayer ! number of atmospheric layers
real,intent(in) :: plat(klon_mpi) ! latitudes of the physics grid
real,intent(in) :: plon(klon_mpi) ! longitudes of the physics grid
real,intent(in) :: parea(klon_mpi) ! area (m2)
integer,intent(in) :: pdayref ! reference day of for the simulation
real,intent(in) :: ptimestep ! physics time step (s)
real,intent(in) :: preff      ! reference surface pressure (Pa)
real,intent(in) :: ap(nlayer+1) ! hybrid coordinate at interfaces
real,intent(in) :: bp(nlayer+1) ! hybrid coordinate at interfaces

integer :: offset
character(len=20) :: modname='iniphysiq'
character(len=80) :: abort_message

IF (nlayer.NE.klev) THEN
  write(*,*) 'STOP in ',trim(modname)
  write(*,*) 'Problem with dimensions :'
  write(*,*) 'nlayer     = ',nlayer
  write(*,*) 'klev   = ',klev
  abort_message = ''
  CALL abort_gcm (modname,abort_message,1)
ENDIF


!$OMP PARALLEL SHARED(parea,plon,plat)
      
offset=0
airephy(1:klon_omp)=parea(offset+klon_omp_begin:offset+klon_omp_end)
rlond(1:klon_omp)=plon(offset+klon_omp_begin:offset+klon_omp_end)
rlatd(1:klon_omp)=plat(offset+klon_omp_begin:offset+klon_omp_end)

! copy over preff , ap() and bp() 
call ini_planete_mod(nlayer,preff,ap,bp)

! copy some fundamental parameters to physics 
! and do some initializations 
call inifis(klon_omp,nlayer,nqtot,pdayref,punjours,ptimestep, &
            rlatd,rlond,airephy,prad,pg,pr,pcpp)

!$OMP END PARALLEL


end subroutine iniphysiq