source: codes/icosagcm/branches/SATURN_DYNAMICO/LMDZ.COMMON/libf/dyn3dpar/initialize_physics.F90

SUBROUTINE initialize_unstructured_physics(nbp, nlayer, communicator, nb_proc, distrib, &
                                           punjours, pdayref,time0,ptimestep,                  &
                                           nb_vertex, lat, lon, area, bounds_lon, bounds_lat, &
                                           prad,pg,pr,pcpp, preff,ap,bp )
USE mod_phys_lmdz_para
USE mod_grid_phy_lmdz
USE dimphy
USE comgeomphy, only :   initcomgeomphy, &
                         nvertex,        &
                         airephy, & ! physics grid area (m2)
                         rlond, & ! longitudes
                         rlatd,  & ! latitudes
                         rbounds_lon,    &
                         rbounds_lat
USE infotrac, only : nqtot ! number of advected tracers
USE planete_mod, only: ini_planete_mod
USE xios_output_mod

IMPLICIT NONE

                                            
    INTEGER,INTENT(in) :: nbp     ! nb point for the current mpi process
    INTEGER,INTENT(in) :: nlayer  ! number of atmospheric layers
    INTEGER,INTENT(in) :: communicator ! current MPI communicataor
    INTEGER,INTENT(in) :: nb_proc      ! nb processor in the current communicator
    INTEGER,INTENT(in) :: distrib(0:nb_proc-1)  ! nb point for alll mpi_process
    REAL,INTENT(in)    :: prad ! radius of the planet (m)
    REAL,INTENT(in)    :: pg ! gravitational acceleration (m/s2)
    REAL,INTENT(in)    :: pr ! ! reduced gas constant R/mu
    REAL,INTENT(in)    :: pcpp ! specific heat Cp
    REAL,INTENT(in)    :: punjours ! length (in s) of a standard day
    INTEGER            :: nb_vertex
    REAL,INTENT(in)    :: lat(nbp) ! latitudes of the physics grid
    REAL,INTENT(in)    :: lon(nbp) ! longitudes of the physics grid
    REAL,INTENT(in)    :: area(nbp) ! area (m2)
    REAL,INTENT(in)    :: bounds_lon(nbp,nb_vertex) ! longitude boundaries of cell
    REAL,INTENT(in)    :: bounds_lat(nbp,nb_vertex) ! latitude boundaries of cell
    INTEGER,INTENT(in) :: pdayref ! reference day of for the simulation
    INTEGER,INTENT(in) :: time0 ! initialtime (s)
    REAL,INTENT(in)    :: ptimestep ! physics time step (s)
    REAL,INTENT(in)    :: preff      ! reference surface pressure (Pa)
    REAL,INTENT(in)    :: ap(nlayer+1) ! hybrid coordinate at interfaces
    REAL,INTENT(in)    :: bp(nlayer+1) ! hybrid coordinate at interfaces

    INTEGER :: offset
    REAL,SAVE,ALLOCATABLE    :: shared_lat(:) ! latitudes of the physics grid
    REAL,SAVE,ALLOCATABLE    :: shared_lon(:) ! longitudes of the physics grid
    REAL,SAVE,ALLOCATABLE    :: shared_area(:) ! area (m2)
    REAL,SAVE,ALLOCATABLE    :: shared_bounds_lon(:,:) ! area (m2)
    REAL,SAVE,ALLOCATABLE    :: shared_bounds_lat(:,:) ! area (m2)

    ALLOCATE(shared_lat(nbp),shared_lon(nbp),shared_area(nbp), shared_bounds_lat(nbp,nb_vertex), shared_bounds_lon(nbp,nb_vertex))
    shared_lat(:)=lat(:)
    shared_lon(:)=lon(:)
    shared_area(:)=area(:)
    shared_bounds_lat(:,:) = bounds_lat(:,:)
    shared_bounds_lon(:,:) = bounds_lon(:,:)
    
    CALL init_grid_phy_lmdz(nbp,1,sum(distrib),nlayer)
    CALL init_phys_lmdz_para(nbp,1,communicator,nb_proc,distrib)

    nvertex = nb_vertex
!$OMP PARALLEL
    CALL init_dimphy(klon_omp,nbp_lev)
    CALL initcomgeomphy
    
    offset=0
    airephy(1:klon_omp)=shared_area(offset+klon_omp_begin:offset+klon_omp_end)
    rlond(1:klon_omp)=shared_lon(offset+klon_omp_begin:offset+klon_omp_end)
    rlatd(1:klon_omp)=shared_lat(offset+klon_omp_begin:offset+klon_omp_end)
    rbounds_lon(1:klon_omp,:)=shared_bounds_lon(offset+klon_omp_begin:offset+klon_omp_end,:)
    rbounds_lat(1:klon_omp,:)=shared_bounds_lat(offset+klon_omp_begin:offset+klon_omp_end,:)

! copy over preff , ap() and bp() 
    CALL ini_planete_mod(nlayer,preff,ap,bp)

! copy some fundamental parameters to physics 
! and do some initializations 
    CALL inifis(klon_omp,nlayer,nqtot,pdayref,punjours,ptimestep, &
                rlatd,rlond,airephy,prad,pg,pr,pcpp)
                
    CALL initialize_xios_output(time0)        
!$OMP END PARALLEL

END SUBROUTINE initialize_unstructured_physics